Skip to main content

Search

CLM презентациясына шолу — KPI есептеу логикасы

KPI indicators of the CLM Presentation Overview dashboard

CLM презентациясына шолу тақтасы пайдаланушыларға қоңыраулар кезінде CLM презентацияларының қаншалықты белсенді қолданылатынын және презентация мазмұнын қарауға қанша уақыт жұмсалатынын бағалауға көмектесетін негізгі KPI көрсеткіштерін көрсетеді.

Ескерту: Тақта тек CLM презентацияларының қалай пайдаланылатынын: қаралымдар санын және қарау уақытын өлшейді. Ол дәрігер туралы, мысалы, жүрек соғу жиілігі немесе слайдтарға реакциясы сияқты ешқандай дерек жинамайды.

Total view

Бизнес сипаттамасы
Таңдалған есепті кезеңдегі CLM презентациялары қаралымдарының жалпы санын көрсетеді.

Мысалда мәні 616.

Есептеу логикасы
KPI бірегей CLM тапсырмаларын санайтын CLM Fact өлшеміне негізделген.

DAX формуласы

CLM Fact =
DISTINCTCOUNT(crm_clm_fact_csv[clm_task_id])

Есептеу логикасы
CLM презентациясының белсенділігі тіркелген CLM тапсырмаларының қайталанбайтын санын есептейді.

Total time

Бизнес сипаттамасы
Таңдалған есепті кезеңде CLM презентацияларын қарауға жұмсалған жалпы уақытты көрсетеді.

Мысалда мәні 03d 10h 04m 45s.

DAX формуласы

CLM Totl time =
VAR TotalTime = SUM(crm_clm_fact_csv[clm_numofsec])
VAR Days = INT(TotalTime / 86400)
VAR Hours = INT(MOD(TotalTime, 86400) / 3600)
VAR Minutes = INT(MOD(TotalTime, 3600) / 60)
VAR Seconds = MOD(TotalTime, 60)

RETURN
FORMAT(Days, "00") & "d " &
FORMAT(Hours, "00") & "h " &
FORMAT(Minutes, "00") & "m " &
FORMAT(Seconds, "00") & "s"

Есептеу логикасы
crm_clm_fact_csv[clm_numofsec] өрісіндегі секундтардың жалпы санын қосып, нәтижені мына пішімге түрлендіреді:

DDd HHh MMm SSs

AVG time (CLM)

Бизнес сипаттамасы
Бір CLM презентациясын қараудың орташа уақытын көрсетеді.

Мысалда мәні 00h 07m 59s.

DAX формуласы

CLM AVG Presentation Time =
VAR PresentationDurations =
    ADDCOLUMNS(
        SUMMARIZE(
            crm_clm_fact_csv,
            crm_clm_fact_csv[clm_task_id],
            crm_clm_fact_csv[clm_presentation_id]
        ),
        "PresentationDuration",
            CALCULATE(SUM(crm_clm_fact_csv[clm_numofsec]))
    )

VAR AvgSeconds = AVERAGEX(PresentationDurations, [PresentationDuration])

VAR TotalMinutes = DIVIDE(AvgSeconds, 60)
VAR Hours = INT(DIVIDE(TotalMinutes, 60))
VAR Minutes = INT(MOD(TotalMinutes, 60))
VAR Seconds = INT(MOD(AvgSeconds, 60))

RETURN
    IF(
        NOT ISBLANK(AvgSeconds),
        FORMAT(Hours, "00") & "h " &
        FORMAT(Minutes, "00") & "m " &
        FORMAT(Seconds, "00") & "s",
        BLANK()
    )

Есептеу логикасы
Алдымен өлшем деректерді CLM тапсырмасы және CLM презентациясы бойынша топтайды. Содан кейін әр тапсырма-презентация жұбы үшін презентацияның жалпы ұзақтығын есептеп, орташа ұзақтықты мына пішімде қайтарады:

HHh MMm SSs

AVG time (Slide)

Бизнес сипаттамасы
Бір CLM слайдын қараудың орташа уақытын көрсетеді.

Мысалда мәні 00h 00m 51s.

DAX формуласы

CLM AVG Slide Time =
VAR AvgSeconds =
    AVERAGEX(
        VALUES(crm_clm_fact_csv[clm_slide_id]),
        CALCULATE(
            AVERAGE(crm_clm_fact_csv[clm_numofsec])
        )
    )

VAR TotalMinutes = DIVIDE(AvgSeconds, 60)
VAR Hours = INT(DIVIDE(TotalMinutes, 60))
VAR Minutes = INT(MOD(TotalMinutes, 60))
VAR Seconds = INT(MOD(AvgSeconds, 60))

RETURN
    IF(
        NOT ISBLANK(AvgSeconds),
        FORMAT(Hours, "00") & "h " &
        FORMAT(Minutes, "00") & "m " &
        FORMAT(Seconds, "00") & "s",
        BLANK()
    )

Есептеу логикасы
Әрбір бірегей CLM слайды үшін секундтардың орташа санын есептеп, нәтижені мына пішімге түрлендіреді:

HHh MMm SSs

CLM Fact task

Бизнес сипаттамасы
CLM белсенділігін талдауға негіз ретінде пайдалануға болатын аяқталған тапсырмалардың санын көрсетеді.

DAX формуласы

CLM Fact task =
CALCULATE(
    DISTINCTCOUNT(crm_task_fact_v2_csv[key_task_id]),
    'crm_task_fact_v2_csv'[key_task_isfinish] = 1
)

Есептеу логикасы
key_task_isfinish = 1 болатын аяқталған тапсырмалардың қайталанбайтын санын есептейді.

CLM Fact

Бизнес сипаттамасы
CLM презентациясының белсенділігі тіркелген тапсырмалардың санын көрсетеді.

DAX формуласы

CLM Fact =
DISTINCTCOUNT(crm_clm_fact_csv[clm_task_id])

Есептеу логикасы
CLM fact кестесіндегі CLM тапсырма идентификаторларының қайталанбайтын санын есептейді.

CLM %

Бизнес сипаттамасы
CLM презентациясының белсенділігін қамтыған аяқталған тапсырмалардың үлесін көрсетеді.

Мысал диаграммасында мәні 34.32%.

DAX формуласы

CLM % =
[CLM Fact] / [CLM Fact task]

Есептеу логикасы
CLM белсенділігі бар тапсырмалар санын аяқталған тапсырмалардың жалпы санына бөледі.

Мәннің жоғары болуы аяқталған қоңыраулар кезінде CLM презентацияларының белсендірек пайдаланылатынын білдіреді.