Saltar al contenido principal

Búsqueda

Resumen de la presentación CLM — Lógica de cálculo de KPI

clmkpi.jpg

El dashboard Resumen de la presentación CLM muestra indicadores KPI clave que ayudan a los usuarios a evaluar qué tan activamente se utilizan las presentaciones CLM durante las visitas y cuánto tiempo se dedica a visualizar el contenido de la presentación.

Total de visualizaciones

Descripción de negocio
Muestra el número total de visualizaciones de presentaciones CLM para el período de informe seleccionado.

En el ejemplo, el valor es 616.

Lógica de cálculo
El KPI se basa en la medida CLM Fact, que cuenta tareas CLM únicas.

Fórmula DAX

CLM Fact =
DISTINCTCOUNT(crm_clm_fact_csv[clm_task_id])

Lógica de cálculo
Calcula el número distinto de tareas CLM en las que se registró actividad de presentación CLM.

Tiempo total

Descripción de negocio
Muestra el tiempo total dedicado a visualizar presentaciones CLM durante el período de informe seleccionado.

En el ejemplo, el valor es 03d 10h 04m 45s.

Fórmula DAX

CLM Totl time =
VAR TotalTime = SUM(crm_clm_fact_csv[clm_numofsec])
VAR Days = INT(TotalTime / 86400)
VAR Hours = INT(MOD(TotalTime, 86400) / 3600)
VAR Minutes = INT(MOD(TotalTime, 3600) / 60)
VAR Seconds = MOD(TotalTime, 60)

RETURN
FORMAT(Days, "00") & "d " &
FORMAT(Hours, "00") & "h " &
FORMAT(Minutes, "00") & "m " &
FORMAT(Seconds, "00") & "s"

Lógica de cálculo
Suma el número total de segundos de crm_clm_fact_csv[clm_numofsec] y convierte el resultado al formato:

DDd HHh MMm SSs

Tiempo promedio (CLM)

Descripción de negocio
Muestra el tiempo promedio de visualización de una presentación CLM.

En el ejemplo, el valor es 00h 07m 59s.

Fórmula DAX

CLM AVG Presentation Time =
VAR PresentationDurations =
    ADDCOLUMNS(
        SUMMARIZE(
            crm_clm_fact_csv,
            crm_clm_fact_csv[clm_task_id],
            crm_clm_fact_csv[clm_presentation_id]
        ),
        "PresentationDuration",
            CALCULATE(SUM(crm_clm_fact_csv[clm_numofsec]))
    )

VAR AvgSeconds = AVERAGEX(PresentationDurations, [PresentationDuration])

VAR TotalMinutes = DIVIDE(AvgSeconds, 60)
VAR Hours = INT(DIVIDE(TotalMinutes, 60))
VAR Minutes = INT(MOD(TotalMinutes, 60))
VAR Seconds = INT(MOD(AvgSeconds, 60))

RETURN
    IF(
        NOT ISBLANK(AvgSeconds),
        FORMAT(Hours, "00") & "h " &
        FORMAT(Minutes, "00") & "m " &
        FORMAT(Seconds, "00") & "s",
        BLANK()
    )

Lógica de cálculo
Primero, la medida agrupa los datos por tarea CLM y presentación CLM. Luego calcula la duración total de la presentación para cada combinación tarea-presentación y devuelve la duración promedio en el formato:

HHh MMm SSs

Tiempo promedio (diapositiva)

Descripción de negocio
Muestra el tiempo promedio de visualización de una diapositiva CLM.

En el ejemplo, el valor es 00h 00m 51s.

Fórmula DAX

CLM AVG Slide Time =
VAR AvgSeconds =
    AVERAGEX(
        VALUES(crm_clm_fact_csv[clm_slide_id]),
        CALCULATE(
            AVERAGE(crm_clm_fact_csv[clm_numofsec])
        )
    )

VAR TotalMinutes = DIVIDE(AvgSeconds, 60)
VAR Hours = INT(DIVIDE(TotalMinutes, 60))
VAR Minutes = INT(MOD(TotalMinutes, 60))
VAR Seconds = INT(MOD(AvgSeconds, 60))

RETURN
    IF(
        NOT ISBLANK(AvgSeconds),
        FORMAT(Hours, "00") & "h " &
        FORMAT(Minutes, "00") & "m " &
        FORMAT(Seconds, "00") & "s",
        BLANK()
    )

Lógica de cálculo
Calcula el número promedio de segundos para cada diapositiva CLM única y convierte el resultado al formato:

HHh MMm SSs

CLM Fact task

Descripción de negocio
Muestra el número de tareas completadas que pueden utilizarse como base para el análisis de la actividad CLM.

Fórmula DAX

CLM Fact task =
CALCULATE(
    DISTINCTCOUNT(crm_task_fact_v2_csv[key_task_id]),
    'crm_task_fact_v2_csv'[key_task_isfinish] = 1
)

Lógica de cálculo
Cuenta el número distinto de tareas completadas donde key_task_isfinish = 1.

CLM Fact

Descripción de negocio
Muestra el número de tareas en las que se registró actividad de presentación CLM.

Fórmula DAX

CLM Fact =
DISTINCTCOUNT(crm_clm_fact_csv[clm_task_id])

Lógica de cálculo
Cuenta el número distinto de ID de tareas CLM de la tabla de hechos CLM.

CLM %

Descripción de negocio
Muestra la proporción de tareas completadas que incluyeron actividad de presentación CLM.

En el gráfico de ejemplo, el valor es 34.32%.

Fórmula DAX

CLM % =
[CLM Fact] / [CLM Fact task]

Lógica de cálculo
Divide el número de tareas con actividad CLM entre el número total de tareas completadas.

Un valor más alto significa que las presentaciones CLM se utilizan más activamente durante las visitas completadas.