Saltar al contenido principal

Búsqueda

Pharmacy Calls Dashboard - lógica de cálculo de KPI

pharmacykpi.jpg

Pharmacy Base

Solo se incluyen organizaciones clasificadas como Point of sale.

Todos los filtros activos afectan los cálculos.

Muestra el número total de farmacias incluidas en el alcance de reporte seleccionado. Representa el universo objetivo de farmacias utilizado para el análisis de cobertura y penetración.

Fórmula DAX

CALCULATE(
    DISTINCTCOUNT(crm_owner_v2_csv[key_cleint_id]),
    crm_company_dictionary_v2_csv[Sales Point] = "Point of sale"
)

Lógica de cálculo

Calcula el número único de farmacias, es decir, puntos de venta, asignadas al alcance de reporte seleccionado.

Covered Pharmacy

Solo se incluyen visitas completadas.

Varias visitas a la misma farmacia se cuentan una sola vez.

Solo se incluyen organizaciones clasificadas como Point of sale.

Muestra el número de farmacias visitadas durante el período de reporte seleccionado. Mide la cobertura de farmacias lograda mediante actividades en campo.

Fórmula DAX

CALCULATE(
    DISTINCTCOUNT(crm_task_fact_v2_csv[key_cleint_id]),
    crm_company_dictionary_v2_csv[Sales Point] = "Point of sale",
    crm_task_fact_v2_csv[key_task_isfinish] = 1
)

Lógica de cálculo

Calcula el número único de farmacias donde se registró al menos una visita completada.

Pharmacies with Availability

La disponibilidad se confirma cuando control_float1 > 0.

Los resultados dependen de las marcas y filtros seleccionados.

Muestra el número de farmacias donde la disponibilidad del producto fue confirmada durante las visitas. Mide la presencia del producto en las farmacias cubiertas.

Fórmula DAX

VAR ClientsWithAvail =
    CALCULATETABLE(
        VALUES(crm_task_fact_v2_csv[key_cleint_id]),
        crm_company_dictionary_v2_csv[Sales Point] = "Point of sale",
        KEEPFILTERS(crm_companypreparation2_csv[control_float1] > 0)
    )
RETURN
CALCULATE(
    DISTINCTCOUNT(crm_owner_v2_csv[key_cleint_id]),
    TREATAS(ClientsWithAvail, crm_owner_v2_csv[key_cleint_id])
)

Lógica de cálculo

Calcula el número único de farmacias donde el stock del producto es mayor que cero.

Penetration

Se calcula solo para farmacias cubiertas.

Se recalcula dinámicamente cuando se aplican filtros.

Muestra el porcentaje de farmacias cubiertas donde el producto o la marca seleccionada está disponible. Mide qué tan ampliamente está representado el producto dentro de las farmacias visitadas.

Fórmula DAX

DIVIDE([Pharmacy with avail], [Pharmacy visited])

Lógica de cálculo

Calcula la proporción de farmacias con disponibilidad confirmada respecto a las farmacias visitadas.

Availability Checks

Muestra el número total de verificaciones de disponibilidad realizadas. Mide la ejecución de actividades de auditoría en farmacias.

Fórmula DAX

COUNTROWS(
    FILTER(
        crm_companypreparation2_csv,
        NOT(ISBLANK(crm_companypreparation2_csv[control_flag2]))
    )
)

Lógica de cálculo

Cuenta todos los registros donde se ingresó información de disponibilidad.

Availability Checks with Availability

Muestra el número de verificaciones de disponibilidad donde se confirmó la presencia de stock. Ayuda a evaluar la disponibilidad real del producto en farmacias.

Fórmula DAX

VAR AvailableCount =
    COUNTROWS(
        FILTER(
            crm_companypreparation2_csv,
            crm_companypreparation2_csv[control_flag2] = 1
        )
    )
RETURN AvailableCount

Lógica de cálculo

Cuenta todos los registros donde la disponibilidad fue confirmada explícitamente.

In Stock

Muestra la cantidad total de stock registrada durante las verificaciones en farmacias. Proporciona visibilidad sobre los niveles de inventario de productos en farmacias.

Fórmula DAX

SUM(crm_companypreparation2_csv[control_float1])

Lógica de cálculo

Calcula la suma de todas las cantidades de stock registradas.

Orders

Muestra la cantidad total pedida durante las visitas a farmacias. Ayuda a evaluar la demanda y la actividad de pedidos.

Fórmula DAX

SUM(crm_companypreparation2_csv[control_int1])

Lógica de cálculo

Calcula la cantidad total pedida registrada durante las auditorías en farmacias.

SKU

Muestra el número de SKU únicos identificados durante las visitas a farmacias. Mide el surtido de productos representado en farmacias.

Fórmula DAX

DISTINCTCOUNT(crm_companypreparation2_csv[control_prep_id])

Lógica de cálculo

Cuenta los productos únicos registrados durante las verificaciones en farmacias.

Brand

Muestra el número de marcas únicas disponibles en farmacias. Mide la presencia de marcas y la amplitud de representación de productos.

Fórmula DAX

CALCULATE(
    DISTINCTCOUNT(crm_sku_dictionary_csv[Brand]),
    FILTER(
        ALLSELECTED(crm_sku_dictionary_csv),
        [Control check brand] > 0
    )
)

Lógica de cálculo

Cuenta las marcas únicas para las cuales se identificó al menos un producto durante las auditorías en farmacias.

Control Check Brand

Indicador técnico utilizado para determinar si una marca está presente en el contexto de filtro actual.

Fórmula DAX

INT(NOT ISEMPTY(crm_companypreparation2_csv))

Lógica de cálculo

Devuelve:

  • 1 si existe al menos un registro de producto
  • 0 si no existen registros de productos

Se utiliza internamente en los cálculos de Brand.