Dashboard Przegląd prezentacji CLM wyświetla kluczowe wskaźniki KPI, które pomagają użytkownikom ocenić, jak aktywnie prezentacje CLM są używane podczas wizyt oraz ile czasu poświęca się na oglądanie treści prezentacji.

• Łączna liczba wyświetleń
• Łączny czas
• Średni czas (CLM)
• Średni czas (slajd)
• CLM Fact task
• CLM Fact
• CLM %

Łączna liczba wyświetleń

Opis biznesowy
Wyświetla łączną liczbę wyświetleń prezentacji CLM w wybranym okresie raportowania.

W przykładzie wartość wynosi 616.

Logika obliczania
KPI opiera się na mierze CLM Fact, która zlicza unikalne zadania CLM.

Formuła DAX

CLM Fact =
DISTINCTCOUNT(crm_clm_fact_csv[clm_task_id])

Logika obliczania
Oblicza liczbę unikalnych zadań CLM, dla których zarejestrowano aktywność prezentacji CLM.

Łączny czas

Opis biznesowy
Wyświetla łączny czas poświęcony na oglądanie prezentacji CLM w wybranym okresie raportowania.

W przykładzie wartość wynosi 03d 10h 04m 45s.

Formuła DAX

CLM Totl time =
VAR TotalTime = SUM(crm_clm_fact_csv[clm_numofsec])
VAR Days = INT(TotalTime / 86400)
VAR Hours = INT(MOD(TotalTime, 86400) / 3600)
VAR Minutes = INT(MOD(TotalTime, 3600) / 60)
VAR Seconds = MOD(TotalTime, 60)

RETURN
FORMAT(Days, "00") & "d " &
FORMAT(Hours, "00") & "h " &
FORMAT(Minutes, "00") & "m " &
FORMAT(Seconds, "00") & "s"

Logika obliczania
Sumuje całkowitą liczbę sekund z pola crm_clm_fact_csv[clm_numofsec] i konwertuje wynik do formatu:

DDd HHh MMm SSs

Średni czas (CLM)

Opis biznesowy
Wyświetla średni czas oglądania jednej prezentacji CLM.

W przykładzie wartość wynosi 00h 07m 59s.

Formuła DAX

CLM AVG Presentation Time =
VAR PresentationDurations =
    ADDCOLUMNS(
        SUMMARIZE(
            crm_clm_fact_csv,
            crm_clm_fact_csv[clm_task_id],
            crm_clm_fact_csv[clm_presentation_id]
        ),
        "PresentationDuration",
            CALCULATE(SUM(crm_clm_fact_csv[clm_numofsec]))
    )

VAR AvgSeconds = AVERAGEX(PresentationDurations, [PresentationDuration])

VAR TotalMinutes = DIVIDE(AvgSeconds, 60)
VAR Hours = INT(DIVIDE(TotalMinutes, 60))
VAR Minutes = INT(MOD(TotalMinutes, 60))
VAR Seconds = INT(MOD(AvgSeconds, 60))

RETURN
    IF(
        NOT ISBLANK(AvgSeconds),
        FORMAT(Hours, "00") & "h " &
        FORMAT(Minutes, "00") & "m " &
        FORMAT(Seconds, "00") & "s",
        BLANK()
    )

Logika obliczania
Najpierw miara grupuje dane według zadania CLM i prezentacji CLM. Następnie oblicza całkowity czas trwania prezentacji dla każdej kombinacji zadanie-prezentacja i zwraca średni czas trwania w formacie:

HHh MMm SSs

Średni czas (slajd)

Opis biznesowy
Wyświetla średni czas oglądania jednego slajdu CLM.

W przykładzie wartość wynosi 00h 00m 51s.

Formuła DAX

CLM AVG Slide Time =
VAR AvgSeconds =
    AVERAGEX(
        VALUES(crm_clm_fact_csv[clm_slide_id]),
        CALCULATE(
            AVERAGE(crm_clm_fact_csv[clm_numofsec])
        )
    )

VAR TotalMinutes = DIVIDE(AvgSeconds, 60)
VAR Hours = INT(DIVIDE(TotalMinutes, 60))
VAR Minutes = INT(MOD(TotalMinutes, 60))
VAR Seconds = INT(MOD(AvgSeconds, 60))

RETURN
    IF(
        NOT ISBLANK(AvgSeconds),
        FORMAT(Hours, "00") & "h " &
        FORMAT(Minutes, "00") & "m " &
        FORMAT(Seconds, "00") & "s",
        BLANK()
    )

Logika obliczania
Oblicza średnią liczbę sekund dla każdego unikalnego slajdu CLM i konwertuje wynik do formatu:

HHh MMm SSs

CLM Fact task

Opis biznesowy
Wyświetla liczbę zakończonych zadań, które mogą być użyte jako podstawa do analizy aktywności CLM.

Formuła DAX

CLM Fact task =
CALCULATE(
    DISTINCTCOUNT(crm_task_fact_v2_csv[key_task_id]),
    'crm_task_fact_v2_csv'[key_task_isfinish] = 1
)

Logika obliczania
Zlicza unikalną liczbę zakończonych zadań, gdzie key_task_isfinish = 1.

CLM Fact

Opis biznesowy
Wyświetla liczbę zadań, w których zarejestrowano aktywność prezentacji CLM.

Formuła DAX

CLM Fact =
DISTINCTCOUNT(crm_clm_fact_csv[clm_task_id])

Logika obliczania
Zlicza unikalną liczbę identyfikatorów zadań CLM z tabeli faktów CLM.

CLM %

Opis biznesowy
Wyświetla udział zakończonych zadań, które obejmowały aktywność prezentacji CLM.

W przykładowym wykresie wartość wynosi 34.32%.

Formuła DAX

CLM % =
[CLM Fact] / [CLM Fact task]

Logika obliczania
Dzieli liczbę zadań z aktywnością CLM przez łączną liczbę zakończonych zadań.

Wyższa wartość oznacza, że prezentacje CLM są aktywniej używane podczas zakończonych wizyt.