Przejdź do głównej zawartości

Szukaj

Pharmacy Calls Dashboard - logika obliczania KPI

pharmacykpi.jpg

Pharmacy Base

Uwzględniane są tylko organizacje sklasyfikowane jako Point of sale.

Wszystkie aktywne filtry wpływają na obliczenia.

Wyświetla całkowitą liczbę aptek objętych wybranym zakresem raportowania. Reprezentuje docelowy zbiór aptek używany do analizy pokrycia i penetracji.

Formuła DAX

CALCULATE(
    DISTINCTCOUNT(crm_owner_v2_csv[key_cleint_id]),
    crm_company_dictionary_v2_csv[Sales Point] = "Point of sale"
)

Logika obliczania

Oblicza unikalną liczbę aptek, czyli punktów sprzedaży, przypisanych do wybranego zakresu raportowania.

Covered Pharmacy

Uwzględniane są tylko zakończone wizyty.

Wielokrotne wizyty w tej samej aptece są liczone raz.

Uwzględniane są tylko organizacje sklasyfikowane jako Point of sale.

Wyświetla liczbę aptek odwiedzonych w wybranym okresie raportowania. Mierzy pokrycie aptek osiągnięte dzięki działaniom terenowym.

Formuła DAX

CALCULATE(
    DISTINCTCOUNT(crm_task_fact_v2_csv[key_cleint_id]),
    crm_company_dictionary_v2_csv[Sales Point] = "Point of sale",
    crm_task_fact_v2_csv[key_task_isfinish] = 1
)

Logika obliczania

Oblicza unikalną liczbę aptek, w których zarejestrowano co najmniej jedną zakończoną wizytę.

Pharmacies with Availability

Dostępność jest potwierdzona, gdy control_float1 > 0.

Wyniki zależą od wybranych marek i filtrów.

Wyświetla liczbę aptek, w których podczas wizyt potwierdzono dostępność produktu. Mierzy obecność produktu w objętych aptekach.

Formuła DAX

VAR ClientsWithAvail =
    CALCULATETABLE(
        VALUES(crm_task_fact_v2_csv[key_cleint_id]),
        crm_company_dictionary_v2_csv[Sales Point] = "Point of sale",
        KEEPFILTERS(crm_companypreparation2_csv[control_float1] > 0)
    )
RETURN
CALCULATE(
    DISTINCTCOUNT(crm_owner_v2_csv[key_cleint_id]),
    TREATAS(ClientsWithAvail, crm_owner_v2_csv[key_cleint_id])
)

Logika obliczania

Oblicza unikalną liczbę aptek, w których stan produktu jest większy niż zero.

Penetration

Obliczane tylko dla objętych aptek.

Przeliczane dynamicznie po zastosowaniu filtrów.

Wyświetla procent objętych aptek, w których wybrany produkt lub marka jest dostępna. Mierzy, jak szeroko produkt jest reprezentowany w odwiedzonych aptekach.

Formuła DAX

DIVIDE([Pharmacy with avail], [Pharmacy visited])

Logika obliczania

Oblicza stosunek aptek z potwierdzoną dostępnością do odwiedzonych aptek.

Availability Checks

Wyświetla całkowitą liczbę wykonanych kontroli dostępności. Mierzy realizację działań audytu aptek.

Formuła DAX

COUNTROWS(
    FILTER(
        crm_companypreparation2_csv,
        NOT(ISBLANK(crm_companypreparation2_csv[control_flag2]))
    )
)

Logika obliczania

Zlicza wszystkie rekordy, w których wprowadzono informacje o dostępności.

Availability Checks with Availability

Wyświetla liczbę kontroli dostępności, w których potwierdzono obecność zapasu. Pomaga oceniać rzeczywistą dostępność produktu w aptekach.

Formuła DAX

VAR AvailableCount =
    COUNTROWS(
        FILTER(
            crm_companypreparation2_csv,
            crm_companypreparation2_csv[control_flag2] = 1
        )
    )
RETURN AvailableCount

Logika obliczania

Zlicza wszystkie rekordy, w których dostępność została jednoznacznie potwierdzona.

In Stock

Wyświetla całkowitą ilość zapasu zarejestrowaną podczas kontroli aptek. Zapewnia widoczność poziomów zapasów produktów w aptekach.

Formuła DAX

SUM(crm_companypreparation2_csv[control_float1])

Logika obliczania

Oblicza sumę wszystkich zarejestrowanych ilości zapasu.

Orders

Wyświetla całkowitą ilość zamówioną podczas wizyt w aptekach. Pomaga ocenić popyt i aktywność zamówień.

Formuła DAX

SUM(crm_companypreparation2_csv[control_int1])

Logika obliczania

Oblicza całkowitą zamówioną ilość zarejestrowaną podczas audytów aptek.

SKU

Wyświetla liczbę unikalnych SKU zidentyfikowanych podczas wizyt w aptekach. Mierzy asortyment produktów reprezentowany w aptekach.

Formuła DAX

DISTINCTCOUNT(crm_companypreparation2_csv[control_prep_id])

Logika obliczania

Zlicza unikalne produkty zarejestrowane podczas kontroli aptek.

Brand

Wyświetla liczbę unikalnych marek dostępnych w aptekach. Mierzy obecność marek i szerokość reprezentacji produktów.

Formuła DAX

CALCULATE(
    DISTINCTCOUNT(crm_sku_dictionary_csv[Brand]),
    FILTER(
        ALLSELECTED(crm_sku_dictionary_csv),
        [Control check brand] > 0
    )
)

Logika obliczania

Zlicza unikalne marki, dla których podczas audytów aptek zidentyfikowano co najmniej jeden produkt.

Control Check Brand

Techniczna flaga używana do określenia, czy marka jest obecna w bieżącym kontekście filtrów.

Formuła DAX

INT(NOT ISEMPTY(crm_companypreparation2_csv))

Logika obliczania

Zwraca:

  • 1, jeśli istnieje co najmniej jeden rekord produktu
  • 0, jeśli nie istnieją rekordy produktów

Używane wewnętrznie w obliczeniach Brand.