Pular para o conteúdo principal

Pesquisa

Visão geral da apresentação CLM — Lógica de cálculo dos KPIs

clmkpi.jpg

O dashboard Visão geral da apresentação CLM exibe indicadores-chave de KPI que ajudam os usuários a avaliar com que intensidade as apresentações CLM são usadas durante as visitas e quanto tempo é gasto na visualização do conteúdo da apresentação.

Total de visualizações

Descrição de negócio
Exibe o número total de visualizações de apresentações CLM no período de relatório selecionado.

No exemplo, o valor é 616.

Lógica de cálculo
O KPI é baseado na medida CLM Fact, que conta tarefas CLM únicas.

Fórmula DAX

CLM Fact =
DISTINCTCOUNT(crm_clm_fact_csv[clm_task_id])

Lógica de cálculo
Calcula o número distinto de tarefas CLM nas quais a atividade de apresentação CLM foi registrada.

Tempo total

Descrição de negócio
Exibe o tempo total gasto na visualização de apresentações CLM durante o período de relatório selecionado.

No exemplo, o valor é 03d 10h 04m 45s.

Fórmula DAX

CLM Totl time =
VAR TotalTime = SUM(crm_clm_fact_csv[clm_numofsec])
VAR Days = INT(TotalTime / 86400)
VAR Hours = INT(MOD(TotalTime, 86400) / 3600)
VAR Minutes = INT(MOD(TotalTime, 3600) / 60)
VAR Seconds = MOD(TotalTime, 60)

RETURN
FORMAT(Days, "00") & "d " &
FORMAT(Hours, "00") & "h " &
FORMAT(Minutes, "00") & "m " &
FORMAT(Seconds, "00") & "s"

Lógica de cálculo
Soma o número total de segundos de crm_clm_fact_csv[clm_numofsec] e converte o resultado para o formato:

DDd HHh MMm SSs

Tempo médio (CLM)

Descrição de negócio
Exibe o tempo médio de visualização de uma apresentação CLM.

No exemplo, o valor é 00h 07m 59s.

Fórmula DAX

CLM AVG Presentation Time =
VAR PresentationDurations =
    ADDCOLUMNS(
        SUMMARIZE(
            crm_clm_fact_csv,
            crm_clm_fact_csv[clm_task_id],
            crm_clm_fact_csv[clm_presentation_id]
        ),
        "PresentationDuration",
            CALCULATE(SUM(crm_clm_fact_csv[clm_numofsec]))
    )

VAR AvgSeconds = AVERAGEX(PresentationDurations, [PresentationDuration])

VAR TotalMinutes = DIVIDE(AvgSeconds, 60)
VAR Hours = INT(DIVIDE(TotalMinutes, 60))
VAR Minutes = INT(MOD(TotalMinutes, 60))
VAR Seconds = INT(MOD(AvgSeconds, 60))

RETURN
    IF(
        NOT ISBLANK(AvgSeconds),
        FORMAT(Hours, "00") & "h " &
        FORMAT(Minutes, "00") & "m " &
        FORMAT(Seconds, "00") & "s",
        BLANK()
    )

Lógica de cálculo
Primeiro, a medida agrupa os dados por tarefa CLM e apresentação CLM. Em seguida, calcula a duração total da apresentação para cada combinação tarefa-apresentação e retorna a duração média no formato:

HHh MMm SSs

Tempo médio (Slide)

Descrição de negócio
Exibe o tempo médio de visualização de um slide CLM.

No exemplo, o valor é 00h 00m 51s.

Fórmula DAX

CLM AVG Slide Time =
VAR AvgSeconds =
    AVERAGEX(
        VALUES(crm_clm_fact_csv[clm_slide_id]),
        CALCULATE(
            AVERAGE(crm_clm_fact_csv[clm_numofsec])
        )
    )

VAR TotalMinutes = DIVIDE(AvgSeconds, 60)
VAR Hours = INT(DIVIDE(TotalMinutes, 60))
VAR Minutes = INT(MOD(TotalMinutes, 60))
VAR Seconds = INT(MOD(AvgSeconds, 60))

RETURN
    IF(
        NOT ISBLANK(AvgSeconds),
        FORMAT(Hours, "00") & "h " &
        FORMAT(Minutes, "00") & "m " &
        FORMAT(Seconds, "00") & "s",
        BLANK()
    )

Lógica de cálculo
Calcula o número médio de segundos para cada slide CLM único e converte o resultado para o formato:

HHh MMm SSs

CLM Fact task

Descrição de negócio
Exibe o número de tarefas concluídas que podem ser usadas como base para a análise da atividade CLM.

Fórmula DAX

CLM Fact task =
CALCULATE(
    DISTINCTCOUNT(crm_task_fact_v2_csv[key_task_id]),
    'crm_task_fact_v2_csv'[key_task_isfinish] = 1
)

Lógica de cálculo
Conta o número distinto de tarefas concluídas em que key_task_isfinish = 1.

CLM Fact

Descrição de negócio
Exibe o número de tarefas nas quais a atividade de apresentação CLM foi registrada.

Fórmula DAX

CLM Fact =
DISTINCTCOUNT(crm_clm_fact_csv[clm_task_id])

Lógica de cálculo
Conta o número distinto de IDs de tarefas CLM da tabela de fatos CLM.

CLM %

Descrição de negócio
Exibe a participação das tarefas concluídas que incluíram atividade de apresentação CLM.

No gráfico de exemplo, o valor é 34.32%.

Fórmula DAX

CLM % =
[CLM Fact] / [CLM Fact task]

Lógica de cálculo
Divide o número de tarefas com atividade CLM pelo número total de tarefas concluídas.

Um valor mais alto significa que as apresentações CLM são usadas de forma mais ativa durante visitas concluídas.