Pular para o conteúdo principal

Pesquisa

Visão geral da apresentação CLM — lógica de cálculo dos KPIs

KPI indicators of the CLM Presentation Overview dashboard

O painel CLM Presentation Overview exibe os principais indicadores de KPI que ajudam os usuários a avaliar o nível de utilização das apresentações CLM durante as visitas e quanto tempo é gasto visualizando o conteúdo das apresentações.

Observação: o painel mede apenas como as apresentações CLM são utilizadas: o número de visualizações e o tempo de visualização. Ele não coleta dados sobre o médico, como frequência cardíaca ou reações aos slides.

Total de visualizações

Descrição comercial
Exibe o número total de visualizações das apresentações CLM no período de relatório selecionado.

No exemplo, o valor é 616.

Lógica de cálculo
O KPI é baseado na medida Fato CLM, que conta tarefas CLM exclusivas.

Fórmula DAX

CLM Fact =
DISTINCTCOUNT(crm_clm_fact_csv[clm_task_id])

Lógica de cálculo
Calcula o número distinto de tarefas CLM nas quais foi registrada atividade de apresentação CLM.

Tempo total

Descrição comercial
Exibe o tempo total gasto visualizando apresentações CLM durante o período de relatório selecionado.

No exemplo, o valor é 03d 10h 04m 45s.

Fórmula DAX

CLM Totl time =
VAR TotalTime = SUM(crm_clm_fact_csv[clm_numofsec])
VAR Days = INT(TotalTime / 86400)
VAR Hours = INT(MOD(TotalTime, 86400) / 3600)
VAR Minutes = INT(MOD(TotalTime, 3600) / 60)
VAR Seconds = MOD(TotalTime, 60)

RETURN
FORMAT(Days, "00") & "d " &
FORMAT(Hours, "00") & "h " &
FORMAT(Minutes, "00") & "m " &
FORMAT(Seconds, "00") & "s"

Lógica de cálculo
Soma o número total de segundos de crm_clm_fact_csv[clm_numofsec] e converte o resultado para o formato:

DDd HHh MMm SSs

Tempo médio (CLM)

Descrição comercial
Exibe o tempo médio de visualização de uma apresentação CLM.

No exemplo, o valor é 00h 07m 59s.

Fórmula DAX

CLM AVG Presentation Time =
VAR PresentationDurations =
    ADDCOLUMNS(
        SUMMARIZE(
            crm_clm_fact_csv,
            crm_clm_fact_csv[clm_task_id],
            crm_clm_fact_csv[clm_presentation_id]
        ),
        "PresentationDuration",
            CALCULATE(SUM(crm_clm_fact_csv[clm_numofsec]))
    )

VAR AvgSeconds = AVERAGEX(PresentationDurations, [PresentationDuration])

VAR TotalMinutes = DIVIDE(AvgSeconds, 60)
VAR Hours = INT(DIVIDE(TotalMinutes, 60))
VAR Minutes = INT(MOD(TotalMinutes, 60))
VAR Seconds = INT(MOD(AvgSeconds, 60))

RETURN
    IF(
        NOT ISBLANK(AvgSeconds),
        FORMAT(Hours, "00") & "h " &
        FORMAT(Minutes, "00") & "m " &
        FORMAT(Seconds, "00") & "s",
        BLANK()
    )

Lógica de cálculo
Primeiro, a medida agrupa os dados por tarefa CLM e apresentação CLM. Em seguida, calcula a duração total da apresentação para cada combinação de tarefa e apresentação e retorna a duração média no formato:

HHh MMm SSs

Tempo médio (slide)

Descrição comercial
Exibe o tempo médio de visualização de um slide CLM.

No exemplo, o valor é 00h 00m 51s.

Fórmula DAX

CLM AVG Slide Time =
VAR AvgSeconds =
    AVERAGEX(
        VALUES(crm_clm_fact_csv[clm_slide_id]),
        CALCULATE(
            AVERAGE(crm_clm_fact_csv[clm_numofsec])
        )
    )

VAR TotalMinutes = DIVIDE(AvgSeconds, 60)
VAR Hours = INT(DIVIDE(TotalMinutes, 60))
VAR Minutes = INT(MOD(TotalMinutes, 60))
VAR Seconds = INT(MOD(AvgSeconds, 60))

RETURN
    IF(
        NOT ISBLANK(AvgSeconds),
        FORMAT(Hours, "00") & "h " &
        FORMAT(Minutes, "00") & "m " &
        FORMAT(Seconds, "00") & "s",
        BLANK()
    )

Lógica de cálculo
Calcula o número médio de segundos para cada slide CLM exclusivo e converte o resultado para o formato:

HHh MMm SSs

Tarefa de fato CLM

Descrição comercial
Exibe o número de tarefas concluídas que podem ser usadas como base para a análise da atividade CLM.

Fórmula DAX

CLM Fact task =
CALCULATE(
    DISTINCTCOUNT(crm_task_fact_v2_csv[key_task_id]),
    'crm_task_fact_v2_csv'[key_task_isfinish] = 1
)

Lógica de cálculo
Conta o número distinto de tarefas concluídas em que key_task_isfinish = 1.

Fato CLM

Descrição comercial
Exibe o número de tarefas nas quais foi registrada atividade de apresentação CLM.

Fórmula DAX

CLM Fact =
DISTINCTCOUNT(crm_clm_fact_csv[clm_task_id])

Lógica de cálculo
Conta o número distinto de IDs de tarefas CLM da tabela de fatos CLM.

% CLM

Descrição comercial
Exibe a proporção de tarefas concluídas que incluíram atividade de apresentação CLM.

No gráfico de exemplo, o valor é 34,32%.

Fórmula DAX

CLM % =
[CLM Fact] / [CLM Fact task]

Lógica de cálculo
Divide o número de tarefas com atividade CLM pelo número total de tarefas concluídas.

Um valor mais alto significa que as apresentações CLM são utilizadas de forma mais ativa durante as visitas concluídas.