Перейти к основному контенту

Поиск

Обзор презентаций CLM — логика расчёта KPI

KPI indicators of the CLM Presentation Overview dashboard

Панель Обзор презентаций CLM отображает основные KPI, которые помогают пользователям оценивать, насколько активно презентации CLM используются во время визитов и сколько времени тратится на просмотр содержимого презентаций.

Примечание: панель измеряет только использование презентаций CLM: количество просмотров и время просмотра. Она не собирает данные о враче, такие как частота сердечных сокращений или реакция на слайды.

Total view

Описание показателя
Отображает общее количество просмотров презентаций CLM за выбранный отчётный период.

В примере значение равно 616.

Логика расчёта
KPI основан на показателе CLM Fact, который подсчитывает уникальные задачи CLM.

Формула DAX

CLM Fact =
DISTINCTCOUNT(crm_clm_fact_csv[clm_task_id])

Логика расчёта
Подсчитывает уникальное количество задач CLM, для которых была зарегистрирована активность презентации CLM.

Total time

Описание показателя
Отображает общее время, затраченное на просмотр презентаций CLM за выбранный отчётный период.

В примере значение равно 03d 10h 04m 45s.

Формула DAX

CLM Totl time =
VAR TotalTime = SUM(crm_clm_fact_csv[clm_numofsec])
VAR Days = INT(TotalTime / 86400)
VAR Hours = INT(MOD(TotalTime, 86400) / 3600)
VAR Minutes = INT(MOD(TotalTime, 3600) / 60)
VAR Seconds = MOD(TotalTime, 60)

RETURN
FORMAT(Days, "00") & "d " &
FORMAT(Hours, "00") & "h " &
FORMAT(Minutes, "00") & "m " &
FORMAT(Seconds, "00") & "s"

Логика расчёта
Суммирует общее количество секунд из crm_clm_fact_csv[clm_numofsec] и преобразует результат в формат:

DDd HHh MMm SSs

AVG time (CLM)

Описание показателя
Отображает среднее время просмотра одной презентации CLM.

В примере значение равно 00h 07m 59s.

Формула DAX

CLM AVG Presentation Time =
VAR PresentationDurations =
    ADDCOLUMNS(
        SUMMARIZE(
            crm_clm_fact_csv,
            crm_clm_fact_csv[clm_task_id],
            crm_clm_fact_csv[clm_presentation_id]
        ),
        "PresentationDuration",
            CALCULATE(SUM(crm_clm_fact_csv[clm_numofsec]))
    )

VAR AvgSeconds = AVERAGEX(PresentationDurations, [PresentationDuration])

VAR TotalMinutes = DIVIDE(AvgSeconds, 60)
VAR Hours = INT(DIVIDE(TotalMinutes, 60))
VAR Minutes = INT(MOD(TotalMinutes, 60))
VAR Seconds = INT(MOD(AvgSeconds, 60))

RETURN
    IF(
        NOT ISBLANK(AvgSeconds),
        FORMAT(Hours, "00") & "h " &
        FORMAT(Minutes, "00") & "m " &
        FORMAT(Seconds, "00") & "s",
        BLANK()
    )

Логика расчёта
Сначала показатель группирует данные по задаче CLM и презентации CLM. Затем он рассчитывает общую продолжительность презентации для каждой комбинации задачи и презентации и возвращает среднюю продолжительность в формате:

HHh MMm SSs

AVG time (Slide)

Описание показателя
Отображает среднее время просмотра одного слайда CLM.

В примере значение равно 00h 00m 51s.

Формула DAX

CLM AVG Slide Time =
VAR AvgSeconds =
    AVERAGEX(
        VALUES(crm_clm_fact_csv[clm_slide_id]),
        CALCULATE(
            AVERAGE(crm_clm_fact_csv[clm_numofsec])
        )
    )

VAR TotalMinutes = DIVIDE(AvgSeconds, 60)
VAR Hours = INT(DIVIDE(TotalMinutes, 60))
VAR Minutes = INT(MOD(TotalMinutes, 60))
VAR Seconds = INT(MOD(AvgSeconds, 60))

RETURN
    IF(
        NOT ISBLANK(AvgSeconds),
        FORMAT(Hours, "00") & "h " &
        FORMAT(Minutes, "00") & "m " &
        FORMAT(Seconds, "00") & "s",
        BLANK()
    )

Логика расчёта
Рассчитывает среднее количество секунд для каждого уникального слайда CLM и преобразует результат в формат:

HHh MMm SSs

CLM Fact task

Описание показателя
Отображает количество завершённых задач, которые можно использовать в качестве основы для анализа активности CLM.

Формула DAX

CLM Fact task =
CALCULATE(
    DISTINCTCOUNT(crm_task_fact_v2_csv[key_task_id]),
    'crm_task_fact_v2_csv'[key_task_isfinish] = 1
)

Логика расчёта
Подсчитывает уникальное количество завершённых задач, для которых key_task_isfinish = 1.

CLM Fact

Описание показателя
Отображает количество задач, для которых была зарегистрирована активность презентации CLM.

Формула DAX

CLM Fact =
DISTINCTCOUNT(crm_clm_fact_csv[clm_task_id])

Логика расчёта
Подсчитывает уникальное количество идентификаторов задач CLM из таблицы фактов CLM.

CLM %

Описание показателя
Отображает долю завершённых задач, включавших активность презентации CLM.

В примере на диаграмме значение равно 34.32%.

Формула DAX

CLM % =
[CLM Fact] / [CLM Fact task]

Логика расчёта
Делит количество задач с активностью CLM на общее количество завершённых задач.

Более высокое значение означает, что презентации CLM активнее используются во время завершённых визитов.