Перейти к основному контенту

Поиск

Обзор CLM-презентации — Логика расчета KPI

clmkpi.jpg

Дашборд Обзор CLM-презентации отображает ключевые KPI-показатели, которые помогают пользователям оценить, насколько активно CLM-презентации используются во время визитов и сколько времени тратится на просмотр презентационного контента.

Общее количество просмотров

Бизнес-описание
Отображает общее количество просмотров CLM-презентаций за выбранный отчетный период.

В примере значение — 616.

Логика расчета
KPI основан на мере CLM Fact, которая считает уникальные CLM-задачи.

DAX-формула

CLM Fact =
DISTINCTCOUNT(crm_clm_fact_csv[clm_task_id])

Логика расчета
Рассчитывает уникальное количество CLM-задач, в которых была зарегистрирована активность CLM-презентации.

Общее время

Бизнес-описание
Отображает общее время, затраченное на просмотр CLM-презентаций за выбранный отчетный период.

В примере значение — 03d 10h 04m 45s.

DAX-формула

CLM Totl time =
VAR TotalTime = SUM(crm_clm_fact_csv[clm_numofsec])
VAR Days = INT(TotalTime / 86400)
VAR Hours = INT(MOD(TotalTime, 86400) / 3600)
VAR Minutes = INT(MOD(TotalTime, 3600) / 60)
VAR Seconds = MOD(TotalTime, 60)

RETURN
FORMAT(Days, "00") & "d " &
FORMAT(Hours, "00") & "h " &
FORMAT(Minutes, "00") & "m " &
FORMAT(Seconds, "00") & "s"

Логика расчета
Суммирует общее количество секунд из crm_clm_fact_csv[clm_numofsec] и преобразует результат в формат:

DDd HHh MMm SSs

Среднее время (CLM)

Бизнес-описание
Отображает среднее время просмотра одной CLM-презентации.

В примере значение — 00h 07m 59s.

DAX-формула

CLM AVG Presentation Time =
VAR PresentationDurations =
    ADDCOLUMNS(
        SUMMARIZE(
            crm_clm_fact_csv,
            crm_clm_fact_csv[clm_task_id],
            crm_clm_fact_csv[clm_presentation_id]
        ),
        "PresentationDuration",
            CALCULATE(SUM(crm_clm_fact_csv[clm_numofsec]))
    )

VAR AvgSeconds = AVERAGEX(PresentationDurations, [PresentationDuration])

VAR TotalMinutes = DIVIDE(AvgSeconds, 60)
VAR Hours = INT(DIVIDE(TotalMinutes, 60))
VAR Minutes = INT(MOD(TotalMinutes, 60))
VAR Seconds = INT(MOD(AvgSeconds, 60))

RETURN
    IF(
        NOT ISBLANK(AvgSeconds),
        FORMAT(Hours, "00") & "h " &
        FORMAT(Minutes, "00") & "m " &
        FORMAT(Seconds, "00") & "s",
        BLANK()
    )

Логика расчета
Сначала мера группирует данные по CLM-задаче и CLM-презентации. Затем она рассчитывает общую длительность презентации для каждой комбинации задача-презентация и возвращает среднюю длительность в формате:

HHh MMm SSs

Среднее время (слайд)

Бизнес-описание
Отображает среднее время просмотра одного CLM-слайда.

В примере значение — 00h 00m 51s.

DAX-формула

CLM AVG Slide Time =
VAR AvgSeconds =
    AVERAGEX(
        VALUES(crm_clm_fact_csv[clm_slide_id]),
        CALCULATE(
            AVERAGE(crm_clm_fact_csv[clm_numofsec])
        )
    )

VAR TotalMinutes = DIVIDE(AvgSeconds, 60)
VAR Hours = INT(DIVIDE(TotalMinutes, 60))
VAR Minutes = INT(MOD(TotalMinutes, 60))
VAR Seconds = INT(MOD(AvgSeconds, 60))

RETURN
    IF(
        NOT ISBLANK(AvgSeconds),
        FORMAT(Hours, "00") & "h " &
        FORMAT(Minutes, "00") & "m " &
        FORMAT(Seconds, "00") & "s",
        BLANK()
    )

Логика расчета
Рассчитывает среднее количество секунд для каждого уникального CLM-слайда и преобразует результат в формат:

HHh MMm SSs

CLM Fact task

Бизнес-описание
Отображает количество завершенных задач, которые могут использоваться как база для анализа CLM-активности.

DAX-формула

CLM Fact task =
CALCULATE(
    DISTINCTCOUNT(crm_task_fact_v2_csv[key_task_id]),
    'crm_task_fact_v2_csv'[key_task_isfinish] = 1
)

Логика расчета
Считает уникальное количество завершенных задач, где key_task_isfinish = 1.

CLM Fact

Бизнес-описание
Отображает количество задач, в которых была зарегистрирована активность CLM-презентации.

DAX-формула

CLM Fact =
DISTINCTCOUNT(crm_clm_fact_csv[clm_task_id])

Логика расчета
Считает уникальное количество ID CLM-задач из таблицы фактов CLM.

CLM %

Бизнес-описание
Отображает долю завершенных задач, которые включали активность CLM-презентации.

На диаграмме в примере значение — 34.32%.

DAX-формула

CLM % =
[CLM Fact] / [CLM Fact task]

Логика расчета
Делит количество задач с CLM-активностью на общее количество завершенных задач.

Более высокое значение означает, что CLM-презентации активнее используются во время завершенных визитов.