CLM Presentation Overview panosu, kullanıcıların görüşmeler sırasında CLM sunumlarının ne kadar aktif kullanıldığını ve sunum içeriğini görüntülemek için ne kadar zaman harcandığını değerlendirmesine yardımcı olan temel KPI göstergelerini görüntüler.

• Total view
• Total time
• AVG time (CLM)
• AVG time (Slide)
• CLM Fact task
• CLM Fact
• CLM %

Total view

İş Açıklaması
Seçilen raporlama dönemi için toplam CLM sunumu görüntüleme sayısını görüntüler.

Örnekte değer 616'dır.

Hesaplama Mantığı
KPI, benzersiz CLM görevlerini sayan CLM Fact ölçüsünü temel alır.

DAX Formülü

CLM Fact =
DISTINCTCOUNT(crm_clm_fact_csv[clm_task_id])

Hesaplama Mantığı
CLM sunum etkinliğinin kaydedildiği farklı CLM görevlerinin sayısını hesaplar.

Total time

İş Açıklaması
Seçilen raporlama döneminde CLM sunumlarını görüntülemek için harcanan toplam süreyi görüntüler.

Örnekte değer 03d 10h 04m 45s'dir.

DAX Formülü

CLM Totl time =
VAR TotalTime = SUM(crm_clm_fact_csv[clm_numofsec])
VAR Days = INT(TotalTime / 86400)
VAR Hours = INT(MOD(TotalTime, 86400) / 3600)
VAR Minutes = INT(MOD(TotalTime, 3600) / 60)
VAR Seconds = MOD(TotalTime, 60)

RETURN
FORMAT(Days, "00") & "d " &
FORMAT(Hours, "00") & "h " &
FORMAT(Minutes, "00") & "m " &
FORMAT(Seconds, "00") & "s"

Hesaplama Mantığı
crm_clm_fact_csv[clm_numofsec] alanındaki toplam saniye sayısını toplar ve sonucu şu formata dönüştürür:

DDd HHh MMm SSs

AVG time (CLM)

İş Açıklaması
Bir CLM sunumunun ortalama görüntüleme süresini görüntüler.

Örnekte değer 00h 07m 59s'dur.

DAX Formülü

CLM AVG Presentation Time =
VAR PresentationDurations =
    ADDCOLUMNS(
        SUMMARIZE(
            crm_clm_fact_csv,
            crm_clm_fact_csv[clm_task_id],
            crm_clm_fact_csv[clm_presentation_id]
        ),
        "PresentationDuration",
            CALCULATE(SUM(crm_clm_fact_csv[clm_numofsec]))
    )

VAR AvgSeconds = AVERAGEX(PresentationDurations, [PresentationDuration])

VAR TotalMinutes = DIVIDE(AvgSeconds, 60)
VAR Hours = INT(DIVIDE(TotalMinutes, 60))
VAR Minutes = INT(MOD(TotalMinutes, 60))
VAR Seconds = INT(MOD(AvgSeconds, 60))

RETURN
    IF(
        NOT ISBLANK(AvgSeconds),
        FORMAT(Hours, "00") & "h " &
        FORMAT(Minutes, "00") & "m " &
        FORMAT(Seconds, "00") & "s",
        BLANK()
    )

Hesaplama Mantığı
Öncelikle ölçü, verileri CLM görevi ve CLM sunumuna göre gruplandırır. Ardından her görev-sunum birleşimi için toplam sunum süresini hesaplar ve ortalama süreyi şu formatta döndürür:

HHh MMm SSs

AVG time (Slide)

İş Açıklaması
Bir CLM slaydının ortalama görüntüleme süresini görüntüler.

Örnekte değer 00h 00m 51s'dir.

DAX Formülü

CLM AVG Slide Time =
VAR AvgSeconds =
    AVERAGEX(
        VALUES(crm_clm_fact_csv[clm_slide_id]),
        CALCULATE(
            AVERAGE(crm_clm_fact_csv[clm_numofsec])
        )
    )

VAR TotalMinutes = DIVIDE(AvgSeconds, 60)
VAR Hours = INT(DIVIDE(TotalMinutes, 60))
VAR Minutes = INT(MOD(TotalMinutes, 60))
VAR Seconds = INT(MOD(AvgSeconds, 60))

RETURN
    IF(
        NOT ISBLANK(AvgSeconds),
        FORMAT(Hours, "00") & "h " &
        FORMAT(Minutes, "00") & "m " &
        FORMAT(Seconds, "00") & "s",
        BLANK()
    )

Hesaplama Mantığı
Her benzersiz CLM slaydı için ortalama saniye sayısını hesaplar ve sonucu şu formata dönüştürür:

HHh MMm SSs

CLM Fact task

İş Açıklaması
CLM etkinliği analizinin temelini oluşturabilecek tamamlanmış görevlerin sayısını görüntüler.

DAX Formülü

CLM Fact task =
CALCULATE(
    DISTINCTCOUNT(crm_task_fact_v2_csv[key_task_id]),
    'crm_task_fact_v2_csv'[key_task_isfinish] = 1
)

Hesaplama Mantığı
key_task_isfinish = 1 olan tamamlanmış görevlerin farklı sayısını hesaplar.

CLM Fact

İş Açıklaması
CLM sunum etkinliğinin kaydedildiği görevlerin sayısını görüntüler.

DAX Formülü

CLM Fact =
DISTINCTCOUNT(crm_clm_fact_csv[clm_task_id])

Hesaplama Mantığı
CLM olgu tablosundaki farklı CLM görev kimliklerinin sayısını hesaplar.

CLM %

İş Açıklaması
CLM sunum etkinliği içeren tamamlanmış görevlerin oranını görüntüler.

Örnek grafikte değer 34.32%'dir.

DAX Formülü

CLM % =
[CLM Fact] / [CLM Fact task]

Hesaplama Mantığı
CLM etkinliği olan görevlerin sayısını toplam tamamlanmış görev sayısına böler.

Daha yüksek bir değer, CLM sunumlarının tamamlanmış görüşmeler sırasında daha aktif kullanıldığı anlamına gelir.