Ana içeriğe geç

Ara

Pharmacy Calls Dashboard - KPI Hesaplama Mantığı

pharmacykpi.jpg

Pharmacy Base

Yalnızca Point of sale olarak sınıflandırılan kuruluşlar dahil edilir.

Tüm aktif filtreler hesaplamaları etkiler.

Seçilen raporlama kapsamına dahil edilen toplam eczane sayısını gösterir. Kapsam ve penetrasyon analizi için kullanılan hedef eczane evrenini temsil eder.

DAX Formülü

CALCULATE(
    DISTINCTCOUNT(crm_owner_v2_csv[key_cleint_id]),
    crm_company_dictionary_v2_csv[Sales Point] = "Point of sale"
)

Hesaplama Mantığı

Seçilen raporlama kapsamına atanmış eczanelerin, yani satış noktalarının, benzersiz sayısını hesaplar.

Covered Pharmacy

Yalnızca tamamlanan ziyaretler dahil edilir.

Aynı eczaneye yapılan birden fazla ziyaret bir kez sayılır.

Yalnızca Point of sale olarak sınıflandırılan kuruluşlar dahil edilir.

Seçilen raporlama döneminde ziyaret edilen eczane sayısını gösterir. Saha aktiviteleriyle elde edilen eczane kapsamını ölçer.

DAX Formülü

CALCULATE(
    DISTINCTCOUNT(crm_task_fact_v2_csv[key_cleint_id]),
    crm_company_dictionary_v2_csv[Sales Point] = "Point of sale",
    crm_task_fact_v2_csv[key_task_isfinish] = 1
)

Hesaplama Mantığı

En az bir tamamlanmış ziyaretin kaydedildiği eczanelerin benzersiz sayısını hesaplar.

Pharmacies with Availability

Bulunabilirlik control_float1 > 0 olduğunda doğrulanır.

Sonuçlar seçilen markalara ve filtrelere bağlıdır.

Ziyaretler sırasında ürün bulunabilirliği doğrulanan eczane sayısını gösterir. Kapsanan eczanelerde ürün varlığını ölçer.

DAX Formülü

VAR ClientsWithAvail =
    CALCULATETABLE(
        VALUES(crm_task_fact_v2_csv[key_cleint_id]),
        crm_company_dictionary_v2_csv[Sales Point] = "Point of sale",
        KEEPFILTERS(crm_companypreparation2_csv[control_float1] > 0)
    )
RETURN
CALCULATE(
    DISTINCTCOUNT(crm_owner_v2_csv[key_cleint_id]),
    TREATAS(ClientsWithAvail, crm_owner_v2_csv[key_cleint_id])
)

Hesaplama Mantığı

Ürün stoğunun sıfırdan büyük olduğu eczanelerin benzersiz sayısını hesaplar.

Penetration

Yalnızca kapsanan eczaneler için hesaplanır.

Filtreler uygulandığında dinamik olarak yeniden hesaplanır.

Seçilen ürünün veya markanın mevcut olduğu kapsanan eczanelerin yüzdesini gösterir. Ürünün ziyaret edilen eczaneler içinde ne kadar yaygın temsil edildiğini ölçer.

DAX Formülü

DIVIDE([Pharmacy with avail], [Pharmacy visited])

Hesaplama Mantığı

Doğrulanmış bulunabilirliğe sahip eczanelerin ziyaret edilen eczanelere oranını hesaplar.

Availability Checks

Gerçekleştirilen toplam bulunabilirlik kontrolü sayısını gösterir. Eczane denetim aktivitelerinin yürütülmesini ölçer.

DAX Formülü

COUNTROWS(
    FILTER(
        crm_companypreparation2_csv,
        NOT(ISBLANK(crm_companypreparation2_csv[control_flag2]))
    )
)

Hesaplama Mantığı

Bulunabilirlik bilgisinin girildiği tüm kayıtları sayar.

Availability Checks with Availability

Stok varlığının doğrulandığı bulunabilirlik kontrollerinin sayısını gösterir. Eczanelerdeki gerçek ürün bulunabilirliğini değerlendirmeye yardımcı olur.

DAX Formülü

VAR AvailableCount =
    COUNTROWS(
        FILTER(
            crm_companypreparation2_csv,
            crm_companypreparation2_csv[control_flag2] = 1
        )
    )
RETURN AvailableCount

Hesaplama Mantığı

Bulunabilirliğin açıkça doğrulandığı tüm kayıtları sayar.

In Stock

Eczane kontrolleri sırasında kaydedilen toplam stok miktarını gösterir. Eczanelerdeki ürün envanteri seviyelerine görünürlük sağlar.

DAX Formülü

SUM(crm_companypreparation2_csv[control_float1])

Hesaplama Mantığı

Kaydedilen tüm stok miktarlarının toplamını hesaplar.

Orders

Eczane ziyaretleri sırasında sipariş edilen toplam miktarı gösterir. Talep ve sipariş aktivitesini değerlendirmeye yardımcı olur.

DAX Formülü

SUM(crm_companypreparation2_csv[control_int1])

Hesaplama Mantığı

Eczane denetimleri sırasında kaydedilen toplam sipariş miktarını hesaplar.

SKU

Eczane ziyaretleri sırasında tanımlanan benzersiz SKU sayısını gösterir. Eczanelerde temsil edilen ürün çeşitliliğini ölçer.

DAX Formülü

DISTINCTCOUNT(crm_companypreparation2_csv[control_prep_id])

Hesaplama Mantığı

Eczane kontrolleri sırasında kaydedilen benzersiz ürünleri sayar.

Brand

Eczanelerde mevcut olan benzersiz marka sayısını gösterir. Marka varlığını ve ürün temsilinin genişliğini ölçer.

DAX Formülü

CALCULATE(
    DISTINCTCOUNT(crm_sku_dictionary_csv[Brand]),
    FILTER(
        ALLSELECTED(crm_sku_dictionary_csv),
        [Control check brand] > 0
    )
)

Hesaplama Mantığı

Eczane denetimleri sırasında en az bir ürünü tanımlanan benzersiz markaları sayar.

Control Check Brand

Bir markanın mevcut filtre bağlamında bulunup bulunmadığını belirlemek için kullanılan teknik bayrak.

DAX Formülü

INT(NOT ISEMPTY(crm_companypreparation2_csv))

Hesaplama Mantığı

Şunları döndürür:

  • en az bir ürün kaydı varsa 1
  • ürün kaydı yoksa 0

Brand hesaplamalarında dahili olarak kullanılır.