Інформаційна панель «Огляд презентацій CLM» відображає ключові показники KPI, які допомагають користувачам оцінити, наскільки активно презентації CLM використовуються під час візитів і скільки часу витрачається на перегляд вмісту презентацій.

• Total view
• Total time
• AVG time (CLM)
• AVG time (Slide)
• CLM Fact task
• CLM Fact
• CLM %

Total view

Опис для бізнесу
Відображає загальну кількість переглядів презентацій CLM за вибраний звітний період.

У прикладі значення становить 616.

Логіка розрахунку
KPI базується на показнику CLM Fact, який підраховує унікальні завдання CLM.

Формула DAX

CLM Fact =
DISTINCTCOUNT(crm_clm_fact_csv[clm_task_id])

Логіка розрахунку
Обчислює кількість унікальних завдань CLM, для яких було зафіксовано активність презентації CLM.

Total time

Опис для бізнесу
Відображає загальний час, витрачений на перегляд презентацій CLM за вибраний звітний період.

У прикладі значення становить 03d 10h 04m 45s.

Формула DAX

CLM Totl time =
VAR TotalTime = SUM(crm_clm_fact_csv[clm_numofsec])
VAR Days = INT(TotalTime / 86400)
VAR Hours = INT(MOD(TotalTime, 86400) / 3600)
VAR Minutes = INT(MOD(TotalTime, 3600) / 60)
VAR Seconds = MOD(TotalTime, 60)

RETURN
FORMAT(Days, "00") & "d " &
FORMAT(Hours, "00") & "h " &
FORMAT(Minutes, "00") & "m " &
FORMAT(Seconds, "00") & "s"

Логіка розрахунку
Підсумовує загальну кількість секунд із crm_clm_fact_csv[clm_numofsec] і перетворює результат у формат:

DDd HHh MMm SSs

AVG time (CLM)

Опис для бізнесу
Відображає середній час перегляду однієї презентації CLM.

У прикладі значення становить 00h 07m 59s.

Формула DAX

CLM AVG Presentation Time =
VAR PresentationDurations =
    ADDCOLUMNS(
        SUMMARIZE(
            crm_clm_fact_csv,
            crm_clm_fact_csv[clm_task_id],
            crm_clm_fact_csv[clm_presentation_id]
        ),
        "PresentationDuration",
            CALCULATE(SUM(crm_clm_fact_csv[clm_numofsec]))
    )

VAR AvgSeconds = AVERAGEX(PresentationDurations, [PresentationDuration])

VAR TotalMinutes = DIVIDE(AvgSeconds, 60)
VAR Hours = INT(DIVIDE(TotalMinutes, 60))
VAR Minutes = INT(MOD(TotalMinutes, 60))
VAR Seconds = INT(MOD(AvgSeconds, 60))

RETURN
    IF(
        NOT ISBLANK(AvgSeconds),
        FORMAT(Hours, "00") & "h " &
        FORMAT(Minutes, "00") & "m " &
        FORMAT(Seconds, "00") & "s",
        BLANK()
    )

Логіка розрахунку
Спочатку показник групує дані за завданням CLM і презентацією CLM. Потім він обчислює загальну тривалість презентації для кожної комбінації завдання та презентації й повертає середню тривалість у форматі:

HHh MMm SSs

AVG time (Slide)

Опис для бізнесу
Відображає середній час перегляду одного слайда CLM.

У прикладі значення становить 00h 00m 51s.

Формула DAX

CLM AVG Slide Time =
VAR AvgSeconds =
    AVERAGEX(
        VALUES(crm_clm_fact_csv[clm_slide_id]),
        CALCULATE(
            AVERAGE(crm_clm_fact_csv[clm_numofsec])
        )
    )

VAR TotalMinutes = DIVIDE(AvgSeconds, 60)
VAR Hours = INT(DIVIDE(TotalMinutes, 60))
VAR Minutes = INT(MOD(TotalMinutes, 60))
VAR Seconds = INT(MOD(AvgSeconds, 60))

RETURN
    IF(
        NOT ISBLANK(AvgSeconds),
        FORMAT(Hours, "00") & "h " &
        FORMAT(Minutes, "00") & "m " &
        FORMAT(Seconds, "00") & "s",
        BLANK()
    )

Логіка розрахунку
Обчислює середню кількість секунд для кожного унікального слайда CLM і перетворює результат у формат:

HHh MMm SSs

CLM Fact task

Опис для бізнесу
Відображає кількість завершених завдань, які можна використовувати як основу для аналізу активності CLM.

Формула DAX

CLM Fact task =
CALCULATE(
    DISTINCTCOUNT(crm_task_fact_v2_csv[key_task_id]),
    'crm_task_fact_v2_csv'[key_task_isfinish] = 1
)

Логіка розрахунку
Підраховує кількість унікальних завершених завдань, для яких key_task_isfinish = 1.

CLM Fact

Опис для бізнесу
Відображає кількість завдань, для яких було зафіксовано активність презентації CLM.

Формула DAX

CLM Fact =
DISTINCTCOUNT(crm_clm_fact_csv[clm_task_id])

Логіка розрахунку
Підраховує кількість унікальних ідентифікаторів завдань CLM із таблиці фактів CLM.

CLM %

Опис для бізнесу
Відображає частку завершених завдань, які включали активність презентації CLM.

У прикладі на діаграмі значення становить 34.32%.

Формула DAX

CLM % =
[CLM Fact] / [CLM Fact task]

Логіка розрахунку
Ділить кількість завдань з активністю CLM на загальну кількість завершених завдань.

Вище значення означає, що презентації CLM активніше використовуються під час завершених візитів.