Перейти до основного контенту

Пошук

Огляд CLM-презентації — Логіка розрахунку KPI

clmkpi.jpg

Дашборд Огляд CLM-презентації відображає ключові KPI-показники, які допомагають користувачам оцінити, наскільки активно CLM-презентації використовуються під час візитів і скільки часу витрачається на перегляд презентаційного контенту.

Загальна кількість переглядів

Бізнес-опис
Відображає загальну кількість переглядів CLM-презентацій за вибраний звітний період.

У прикладі значення — 616.

Логіка розрахунку
KPI базується на мірі CLM Fact, яка рахує унікальні CLM-завдання.

DAX-формула

CLM Fact =
DISTINCTCOUNT(crm_clm_fact_csv[clm_task_id])

Логіка розрахунку
Розраховує унікальну кількість CLM-завдань, у яких було зареєстровано активність CLM-презентації.

Загальний час

Бізнес-опис
Відображає загальний час, витрачений на перегляд CLM-презентацій за вибраний звітний період.

У прикладі значення — 03d 10h 04m 45s.

DAX-формула

CLM Totl time =
VAR TotalTime = SUM(crm_clm_fact_csv[clm_numofsec])
VAR Days = INT(TotalTime / 86400)
VAR Hours = INT(MOD(TotalTime, 86400) / 3600)
VAR Minutes = INT(MOD(TotalTime, 3600) / 60)
VAR Seconds = MOD(TotalTime, 60)

RETURN
FORMAT(Days, "00") & "d " &
FORMAT(Hours, "00") & "h " &
FORMAT(Minutes, "00") & "m " &
FORMAT(Seconds, "00") & "s"

Логіка розрахунку
Підсумовує загальну кількість секунд із crm_clm_fact_csv[clm_numofsec] і перетворює результат у формат:

DDd HHh MMm SSs

Середній час (CLM)

Бізнес-опис
Відображає середній час перегляду однієї CLM-презентації.

У прикладі значення — 00h 07m 59s.

DAX-формула

CLM AVG Presentation Time =
VAR PresentationDurations =
    ADDCOLUMNS(
        SUMMARIZE(
            crm_clm_fact_csv,
            crm_clm_fact_csv[clm_task_id],
            crm_clm_fact_csv[clm_presentation_id]
        ),
        "PresentationDuration",
            CALCULATE(SUM(crm_clm_fact_csv[clm_numofsec]))
    )

VAR AvgSeconds = AVERAGEX(PresentationDurations, [PresentationDuration])

VAR TotalMinutes = DIVIDE(AvgSeconds, 60)
VAR Hours = INT(DIVIDE(TotalMinutes, 60))
VAR Minutes = INT(MOD(TotalMinutes, 60))
VAR Seconds = INT(MOD(AvgSeconds, 60))

RETURN
    IF(
        NOT ISBLANK(AvgSeconds),
        FORMAT(Hours, "00") & "h " &
        FORMAT(Minutes, "00") & "m " &
        FORMAT(Seconds, "00") & "s",
        BLANK()
    )

Логіка розрахунку
Спочатку міра групує дані за CLM-завданням і CLM-презентацією. Потім вона розраховує загальну тривалість презентації для кожної комбінації завдання-презентація та повертає середню тривалість у форматі:

HHh MMm SSs

Середній час (слайд)

Бізнес-опис
Відображає середній час перегляду одного CLM-слайда.

У прикладі значення — 00h 00m 51s.

DAX-формула

CLM AVG Slide Time =
VAR AvgSeconds =
    AVERAGEX(
        VALUES(crm_clm_fact_csv[clm_slide_id]),
        CALCULATE(
            AVERAGE(crm_clm_fact_csv[clm_numofsec])
        )
    )

VAR TotalMinutes = DIVIDE(AvgSeconds, 60)
VAR Hours = INT(DIVIDE(TotalMinutes, 60))
VAR Minutes = INT(MOD(TotalMinutes, 60))
VAR Seconds = INT(MOD(AvgSeconds, 60))

RETURN
    IF(
        NOT ISBLANK(AvgSeconds),
        FORMAT(Hours, "00") & "h " &
        FORMAT(Minutes, "00") & "m " &
        FORMAT(Seconds, "00") & "s",
        BLANK()
    )

Логіка розрахунку
Розраховує середню кількість секунд для кожного унікального CLM-слайда та перетворює результат у формат:

HHh MMm SSs

CLM Fact task

Бізнес-опис
Відображає кількість завершених завдань, які можуть використовуватися як база для аналізу CLM-активності.

DAX-формула

CLM Fact task =
CALCULATE(
    DISTINCTCOUNT(crm_task_fact_v2_csv[key_task_id]),
    'crm_task_fact_v2_csv'[key_task_isfinish] = 1
)

Логіка розрахунку
Рахує унікальну кількість завершених завдань, де key_task_isfinish = 1.

CLM Fact

Бізнес-опис
Відображає кількість завдань, у яких було зареєстровано активність CLM-презентації.

DAX-формула

CLM Fact =
DISTINCTCOUNT(crm_clm_fact_csv[clm_task_id])

Логіка розрахунку
Рахує унікальну кількість ID CLM-завдань із таблиці фактів CLM.

CLM %

Бізнес-опис
Відображає частку завершених завдань, які включали активність CLM-презентації.

На прикладі діаграми значення — 34.32%.

DAX-формула

CLM % =
[CLM Fact] / [CLM Fact task]

Логіка розрахунку
Ділить кількість завдань із CLM-активністю на загальну кількість завершених завдань.

Вище значення означає, що CLM-презентації активніше використовуються під час завершених візитів.