Asosuy kontentga o’tish

Qidirish

CLM taqdimoti bo‘yicha umumiy ko‘rinish — KPI hisoblash mantig‘i

clmkpi.jpg

CLM taqdimoti bo‘yicha umumiy ko‘rinish dashboardi foydalanuvchilarga CLM taqdimotlari tashriflar davomida qanchalik faol ishlatilishini va taqdimot kontentini ko‘rishga qancha vaqt sarflanishini baholashga yordam beradigan asosiy KPI ko‘rsatkichlarini ko‘rsatadi.

Jami ko‘rishlar

Biznes tavsif
Tanlangan hisobot davri uchun CLM taqdimotlari ko‘rishlarining umumiy sonini ko‘rsatadi.

Misolda qiymat — 616.

Hisoblash mantig‘i
KPI noyob CLM vazifalarini hisoblaydigan CLM Fact o‘lchoviga asoslanadi.

DAX formulasi

CLM Fact =
DISTINCTCOUNT(crm_clm_fact_csv[clm_task_id])

Hisoblash mantig‘i
CLM taqdimot faolligi qayd etilgan noyob CLM vazifalari sonini hisoblaydi.

Jami vaqt

Biznes tavsif
Tanlangan hisobot davrida CLM taqdimotlarini ko‘rishga sarflangan jami vaqtni ko‘rsatadi.

Misolda qiymat — 03d 10h 04m 45s.

DAX formulasi

CLM Totl time =
VAR TotalTime = SUM(crm_clm_fact_csv[clm_numofsec])
VAR Days = INT(TotalTime / 86400)
VAR Hours = INT(MOD(TotalTime, 86400) / 3600)
VAR Minutes = INT(MOD(TotalTime, 3600) / 60)
VAR Seconds = MOD(TotalTime, 60)

RETURN
FORMAT(Days, "00") & "d " &
FORMAT(Hours, "00") & "h " &
FORMAT(Minutes, "00") & "m " &
FORMAT(Seconds, "00") & "s"

Hisoblash mantig‘i
crm_clm_fact_csv[clm_numofsec] maydonidagi jami sekundlar sonini qo‘shadi va natijani quyidagi formatga o‘zgartiradi:

DDd HHh MMm SSs

O‘rtacha vaqt (CLM)

Biznes tavsif
Bitta CLM taqdimotini ko‘rishning o‘rtacha vaqtini ko‘rsatadi.

Misolda qiymat — 00h 07m 59s.

DAX formulasi

CLM AVG Presentation Time =
VAR PresentationDurations =
    ADDCOLUMNS(
        SUMMARIZE(
            crm_clm_fact_csv,
            crm_clm_fact_csv[clm_task_id],
            crm_clm_fact_csv[clm_presentation_id]
        ),
        "PresentationDuration",
            CALCULATE(SUM(crm_clm_fact_csv[clm_numofsec]))
    )

VAR AvgSeconds = AVERAGEX(PresentationDurations, [PresentationDuration])

VAR TotalMinutes = DIVIDE(AvgSeconds, 60)
VAR Hours = INT(DIVIDE(TotalMinutes, 60))
VAR Minutes = INT(MOD(TotalMinutes, 60))
VAR Seconds = INT(MOD(AvgSeconds, 60))

RETURN
    IF(
        NOT ISBLANK(AvgSeconds),
        FORMAT(Hours, "00") & "h " &
        FORMAT(Minutes, "00") & "m " &
        FORMAT(Seconds, "00") & "s",
        BLANK()
    )

Hisoblash mantig‘i
Avval o‘lchov ma’lumotlarni CLM vazifasi va CLM taqdimoti bo‘yicha guruhlaydi. Keyin har bir vazifa-taqdimot kombinatsiyasi uchun taqdimotni ko‘rishning jami davomiyligini hisoblaydi va o‘rtacha davomiylikni quyidagi formatda qaytaradi:

HHh MMm SSs

O‘rtacha vaqt (slayd)

Biznes tavsif
Bitta CLM slaydini ko‘rishning o‘rtacha vaqtini ko‘rsatadi.

Misolda qiymat — 00h 00m 51s.

DAX formulasi

CLM AVG Slide Time =
VAR AvgSeconds =
    AVERAGEX(
        VALUES(crm_clm_fact_csv[clm_slide_id]),
        CALCULATE(
            AVERAGE(crm_clm_fact_csv[clm_numofsec])
        )
    )

VAR TotalMinutes = DIVIDE(AvgSeconds, 60)
VAR Hours = INT(DIVIDE(TotalMinutes, 60))
VAR Minutes = INT(MOD(TotalMinutes, 60))
VAR Seconds = INT(MOD(AvgSeconds, 60))

RETURN
    IF(
        NOT ISBLANK(AvgSeconds),
        FORMAT(Hours, "00") & "h " &
        FORMAT(Minutes, "00") & "m " &
        FORMAT(Seconds, "00") & "s",
        BLANK()
    )

Hisoblash mantig‘i
Har bir noyob CLM slaydi uchun o‘rtacha sekundlar sonini hisoblaydi va natijani quyidagi formatga o‘zgartiradi:

HHh MMm SSs

CLM Fact task

Biznes tavsif
CLM faolligini tahlil qilish uchun asos sifatida ishlatilishi mumkin bo‘lgan yakunlangan vazifalar sonini ko‘rsatadi.

DAX formulasi

CLM Fact task =
CALCULATE(
    DISTINCTCOUNT(crm_task_fact_v2_csv[key_task_id]),
    'crm_task_fact_v2_csv'[key_task_isfinish] = 1
)

Hisoblash mantig‘i
key_task_isfinish = 1 bo‘lgan yakunlangan noyob vazifalar sonini hisoblaydi.

CLM Fact

Biznes tavsif
CLM taqdimot faolligi qayd etilgan vazifalar sonini ko‘rsatadi.

DAX formulasi

CLM Fact =
DISTINCTCOUNT(crm_clm_fact_csv[clm_task_id])

Hisoblash mantig‘i
CLM fakt jadvalidagi noyob CLM vazifa ID’lari sonini hisoblaydi.

CLM %

Biznes tavsif
CLM taqdimot faolligini o‘z ichiga olgan yakunlangan vazifalar ulushini ko‘rsatadi.

Misol diagrammada qiymat — 34.32%.

DAX formulasi

CLM % =
[CLM Fact] / [CLM Fact task]

Hisoblash mantig‘i
CLM faolligi mavjud vazifalar sonini yakunlangan vazifalarning umumiy soniga bo‘ladi.

Yuqori qiymat CLM taqdimotlari yakunlangan tashriflar davomida faolroq ishlatilishini bildiradi.