Asosuy kontentga o’tish

Qidirish

SMS Dashboard KPI Calculation Logic

smskpi.jpg

 

Rejalashtirilgan

Tanlangan hisobot davrida yuborilishi rejalashtirilgan SMS xabarlarining umumiy sonini ko‘rsatadi.

DAX formulasi

SMS Planned =
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]), 
    'Distribution'[Communication_channel] = "sms"
)

Hisoblash mantiqi

Ushbu o‘lchov aloqa kanali sms bo‘lgan barcha taqsimot yozuvlarini hisoblaydi. Bu tanlangan davr va filtrlar uchun rejalashtirilgan SMS xabarlari umumiy sonini ifodalaydi.

Yuborilgan

Yuborish jarayoniga kirgan SMS xabarlari sonini ko‘rsatadi.

DAX formulasi

SMS Sent =
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]), 
    FILTER(
        'Distribution Status',
        'Distribution Status'[Distribution_Sending_Status] IN {
            "DELIVERED", "BOUNCED", "DECLINED", "DEFERRED", "EXPIRED",
            "FAILED", "OLD", "REJECTED", "UNDELIVERABLE", "UNDELIVERED",
            "UNKNOWN", "ENQUEUED", "QUEUED", "SENT", "VISITED", "READ", "SEEN"
        }
        && RELATED('Distribution'[Communication_channel]) = "sms"
    )
)

Hisoblash mantiqi

Ushbu o‘lchov xabar yuborish jarayoniga kirganligini ko‘rsatadigan statusga ega SMS xabarlarini hisoblaydi. Unda muvaffaqiyatli ishlangan xabarlar ham, yetkazilmagan xabarlarning statuslari ham mavjud.

Yuborilgan %

Rejalashtirilgan SMS xabarlarining yuborilgan foizini ko‘rsatadi.

DAX formulasi

SMS Sent % =
[SMS Sent] / [SMS Planned]

Hisoblash mantiqi

Ushbu o‘lchov yuborilgan SMS xabarlari sonini rejalashtirilgan SMS xabarlari soniga bo‘ladi.

Yetkazilgan

Qabul qiluvchilarga muvaffaqiyatli yetkazilgan SMS xabarlar sonini ko‘rsatadi.

DAX formulasi

SMS Delivered =
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]), 
    FILTER(
        'Distribution Status',
        'Distribution Status'[Distribution_Sending_Status] IN {
            "DELIVERED", "READ", "VISITED", "SEEN"
        }
        && RELATED('Distribution'[Communication_channel]) = "sms"
    )
)

Hisoblash mantiqi

Ushbu o‘lchov yetkazilish bilan bog‘liq statusga ega SMS xabarlarini hisoblaydi. READ, VISITED va SEEN kabi statuslar faqat muvaffaqiyatli yetkazilgandan keyin yuzaga kelishi mumkinligi sababli hisobga olinadi.

Yetkazilgan %

Yuborilgan SMS xabarlaridan muvaffaqiyatli yetkazilganlar foizini ko‘rsatadi.

DAX formulasi

SMS Delivered % =
[SMS Delivered] / [SMS Sent]

Hisoblash mantiqi

Ushbu o‘lchov yetkazilgan SMS xabarlari sonini yuborilgan SMS xabarlari soniga bo‘ladi.

O‘qilgan

Qabul qiluvchilar tomonidan o‘qilgan yoki ko‘rilgan SMS xabarlar sonini ko‘rsatadi.

DAX formulasi

SMS Read =
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]), 
    FILTER(
        'Distribution Status',
        'Distribution Status'[Distribution_Sending_Status] IN {
            "READ", "VISITED", "SEEN"
        }
        && RELATED('Distribution'[Communication_channel]) = "sms"
    )
)

Hisoblash mantiqi

Ushbu o‘lchov qabul qiluvchilar tomonidan o‘qilgan yoki ko‘rilganligini ko‘rsatadigan statusga ega SMS xabarlarini hisoblaydi.

Tashrif buyurilgan

Qabul qiluvchilar havolaga tashrif buyurgan SMS xabarlar sonini ko‘rsatadi.

DAX formulasi

SMS Visited =
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]), 
    FILTER(
        'Distribution Status',
        'Distribution Status'[Distribution_Sending_Status] IN { "VISITED" }
        && RELATED('Distribution'[Communication_channel]) = "sms"
    )
)

Hisoblash mantiqi

Ushbu o‘lchov VISITED statusiga ega SMS xabarlarini hisoblaydi. Bu SMS aloqalaridan qanchasi havola bilan o‘zaro aloqada bo‘lganini ko‘rsatadi.

Tashrif buyurilgan %

Yetkazilgan SMS xabarlaridan havolaga tashrif buyurilganlar foizini ko‘rsatadi.

DAX formulasi

SMS Visited % =
[SMS Visited] / [SMS Delivered]

Hisoblash mantiqi

Ushbu o‘lchov havolaga tashrif buyurilgan SMS xabarlari sonini yetkazilgan SMS xabarlari soniga bo‘ladi.

Obunani bekor qilganlar

SMS aloqalaridan obunani bekor qilgan qabul qiluvchilar sonini ko‘rsatadi.

DAX formulasi

SMS Unsubscribed =
CALCULATE(
    COUNT('Unsubscribed'[ID_Unsubscribed]), 
    'Distribution'[Communication_channel] = "sms"
)

Hisoblash mantiqi

Ushbu o‘lchov sms aloqa kanali uchun obunani bekor qilish yozuvlarini hisoblaydi.

Obunani bekor qilganlar %

Yetkazilgan SMS xabarlaridan obunani bekor qilish natijasida foizni ko‘rsatadi.

DAX formulasi

SMS Unsubscribed % =
[SMS Unsubscribed] / [SMS Delivered]

Hisoblash mantiqi

Ushbu o‘lchov obunani bekor qilgan SMS yozuvlari sonini yetkazilgan SMS xabarlari soniga bo‘ladi.

Yetkazilmagan

Yuborilgan, ammo yetkazilmagan SMS xabarlar sonini ko‘rsatadi.

DAX formulasi

SMS Undelivered =
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]), 
    FILTER(
        'Distribution Status',
        'Distribution Status'[Distribution_Sending_Status] IN {
            "UNDELIVERED", "UNDELIVERABLE",
            "RESENDING_SMS_UNDELIVERED",
            "RESENDING_SMS_UNDELIVERABLE",
            "EXPIRED", "OLD", "BOUNCED",
            "DEFERRED", "UNKNOWN"
        }
        && RELATED('Distribution'[Communication_channel]) = "sms"
    )
)

Hisoblash mantiqi

Ushbu o‘lchov yetkazilmaganligini ko‘rsatadigan statusga ega SMS xabarlarini hisoblaydi.

Yetkazilmagan %

Yuborilgan SMS xabarlarining yetkazilmagan foizini ko‘rsatadi.

DAX formulasi

SMS Undelivered % =
[SMS Undelivered] / [SMS Sent]

Hisoblash mantiqi

Ushbu o‘lchov yetkazilmagan SMS xabarlari sonini yuborilgan SMS xabarlari soniga bo‘ladi.

Yuborilmagan

Rejalashtirilgan, ammo yuborilmagan SMS xabarlar sonini ko‘rsatadi.

DAX formulasi

SMS Unsent =
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]), 
    FILTER(
        'Distribution Status',
        'Distribution Status'[Distribution_Sending_Status] IN {
            "DUPLICATE", "INVALID_EMAIL", "EMPTY_RECIPIENT",
            "EMPTY_CONTENT", "MESSAGE_LIMIT", "EXCLUDED",
            "UNSUBSCRIBED", "FAILED", "DECLINED", "UNVERIFIED"
        }
        && RELATED('Distribution'[Communication_channel]) = "sms"
    )
)

Hisoblash mantiqi

Ushbu o‘lchov cheklovlar, takroriy yozuvlar, qabul qiluvchi ma'lumotlari yo‘qligi, ishlov berishdagi xatoliklar yoki boshqa yuborish muammolari sababli yuborilmagan rejalashtirilgan SMS xabarlarini hisoblaydi.

Yuborilmagan %

Rejalashtirilgan SMS xabarlarining yuborilmagan foizini ko‘rsatadi.

DAX formulasi

SMS Unsent % =
[SMS Unsent] / [SMS Planned]

Hisoblash mantiqi

Ushbu o‘lchov yuborilmagan SMS xabarlari sonini rejalashtirilgan SMS xabarlari soniga bo‘ladi.

SMS Yetkazilgan Dinamik

Tanlangan dinamik davr davomida yetkazilgan SMS xabarlari sonini ko‘rsatadi.

DAX formulasi

SMS Delivered Dynamic =
VAR N = [DaysToShow SMS]
VAR MaxDate =
    CALCULATE (
        MAX ( 'Distribution Status'[Send_DateOnly] ),
        ALL ( 'Distribution Status' )
    )
VAR Mode = SELECTEDVALUE(PeriodMode[Mode], "Day")
VAR StartDate_Day = MaxDate - (N - 1)
VAR StartDate_Month =
    DATE(
        YEAR ( EOMONTH ( MaxDate, -N + 1 ) ),
        MONTH( EOMONTH ( MaxDate, -N + 1 ) ),
        1
    )
VAR StartDate = IF(Mode = "Month", StartDate_Month, StartDate_Day)
RETURN
CALCULATE (
    COUNT ( 'Distribution Status'[ID_Distribution] ),
    FILTER (
        ALL ( 'Distribution Status'[Send_DateOnly] ),
        'Distribution Status'[Send_DateOnly] >= StartDate
            && 'Distribution Status'[Send_DateOnly] <= MaxDate
    ),
    KEEPFILTERS (
        'Distribution Status'[Distribution_Sending_Status] IN {
            "DELIVERED", "READ", "VISITED", "SEEN"
        }
    ),
    KEEPFILTERS ( 'Distribution'[Communication_channel] = "sms" ),
    REMOVEFILTERS ( 'Calendar' ),
    REMOVEFILTERS ( 'PeriodsFilter' )
)

Hisoblash mantiqi

Ushbu o‘lchov tanlangan dinamik davr uchun yetkazilgan SMS xabarlari sonini hisoblaydi. U ko‘rsatilgan sana oralig‘ini belgilash uchun DaysToShow SMS va tanlangan davr rejimini, masalan, Kun yoki Oy dan foydalanadi.

SMS O‘qilgan Dinamik

Tanlangan dinamik davr davomida o‘qilgan SMS xabarlari sonini ko‘rsatadi.

DAX formulasi

SMS Read Dynamic =
VAR N = [DaysToShow SMS]
VAR MaxDate =
    CALCULATE (
        MAX ( 'Distribution Status'[Send_DateOnly] ),
        ALL ( 'Distribution Status' )
    )
VAR Mode = SELECTEDVALUE(PeriodMode[Mode], "Day")
VAR StartDate_Day = MaxDate - (N - 1)
VAR StartDate_Month =
    DATE(
        YEAR ( EOMONTH ( MaxDate, -N + 1 ) ),
        MONTH( EOMONTH ( MaxDate, -N + 1 ) ),
        1
    )
VAR StartDate = IF(Mode = "Month", StartDate_Month, StartDate_Day)
RETURN
CALCULATE (
    COUNT ( 'Distribution Status'[ID_Distribution] ),
    FILTER (
        ALL ( 'Distribution Status'[Send_DateOnly] ),
        'Distribution Status'[Send_DateOnly] >= StartDate
            && 'Distribution Status'[Send_DateOnly] <= MaxDate
    ),
    KEEPFILTERS (
        'Distribution Status'[Distribution_Sending_Status] IN {
            "READ", "VISITED", "SEEN"
        }
    ),
    KEEPFILTERS ( 'Distribution'[Communication_channel] = "sms" ),
    REMOVEFILTERS ( 'Calendar' ),
    REMOVEFILTERS ( 'PeriodsFilter' )
)

Hisoblash mantiqi

Ushbu o‘lchov tanlangan dinamik davr davomida qabul qiluvchilar tomonidan o‘qilgan SMS xabarlari sonini hisoblaydi. U Xabar Yetkazilishi va Ishtirok Trendlari grafikida ishlatiladi.

SMS Yetkazilmagan Dinamik

Tanlangan dinamik davr davomida yetkazilmagan SMS xabarlari sonini ko‘rsatadi.

DAX formulasi

SMS Undelivred Dynamic =
VAR N = [DaysToShow SMS]
VAR MaxDate =
    CALCULATE (
        MAX ( 'Distribution Status'[Send_DateOnly] ),
        ALL ( 'Distribution Status' )
    )
VAR Mode = SELECTEDVALUE(PeriodMode[Mode], "Day")
VAR StartDate =
    SWITCH (
        TRUE(),
        Mode = "Day", MaxDate - (N - 1),
        Mode = "Month", EOMONTH(MaxDate, -N + 1) + 1,
        MaxDate - N
    )
RETURN
CALCULATE (
    COUNT ( 'Distribution Status'[ID_Distribution] ),
    FILTER (
        ALL ( 'Distribution Status'[Send_DateOnly] ),
        'Distribution Status'[Send_DateOnly] >= StartDate
            && 'Distribution Status'[Send_DateOnly] <= MaxDate
    ),
    KEEPFILTERS (
        'Distribution Status'[Distribution_Sending_Status] IN {
            "UNDELIVERED", "UNDELIVERABLE",
            "RESENDING_SMS_UNDELIVERED",
            "RESENDING_SMS_UNDELIVERABLE",
            "EXPIRED", "OLD", "BOUNCED",
            "DEFERRED", "UNKNOWN"
        }
    ),
    KEEPFILTERS ( 'Distribution'[Communication_channel] = "sms" ),
    REMOVEFILTERS ( 'Calendar' ),
    REMOVEFILTERS ( 'PeriodsFilter' )
)

Hisoblash mantiqi

Ushbu o‘lchov tanlangan dinamik davr davomida yetkazilmagan SMS xabarlari sonini hisoblaydi. Bu yetkazish muvaffaqiyatsizligi dinamikasini vaqt bo‘yicha ko‘rsatishda ishlatiladi.

SMS Tashrif Buyurilgan Dinamik

Tanlangan dinamik davr davomida havolaga tashrif buyurilgan SMS xabarlari sonini ko‘rsatadi.

DAX formulasi

SMS Visited Dynamic =
VAR N = [DaysToShow SMS]
VAR MaxDate =
    CALCULATE (
        MAX ( 'Distribution Status'[Send_DateOnly] ),
        ALL ( 'Distribution Status' )
    )
VAR Mode = SELECTEDVALUE(PeriodMode[Mode], "Day")
VAR StartDate =
    SWITCH (
        TRUE(),
        Mode = "Day", MaxDate - (N - 1),
        Mode = "Month", EOMONTH(MaxDate, -N + 1) + 1,
        MaxDate - N
    )
RETURN
CALCULATE (
    COUNT ( 'Distribution Status'[ID_Distribution] ),
    FILTER (
        ALL ( 'Distribution Status'[Send_DateOnly] ),
        'Distribution Status'[Send_DateOnly] >= StartDate
            && 'Distribution Status'[Send_DateOnly] <= MaxDate
    ),
    KEEPFILTERS (
        'Distribution Status'[Distribution_Sending_Status] IN { "VISITED" }
    ),
    KEEPFILTERS ( 'Distribution'[Communication_channel] = "sms" ),
    REMOVEFILTERS ( 'Calendar' ),
    REMOVEFILTERS ( 'PeriodsFilter' )
)

Hisoblash mantiqi

Ushbu o‘lchov tanlangan dinamik davr davomida qabul qiluvchilar havolaga tashrif buyurgan SMS xabarlari sonini hisoblaydi. U SMS havola tashriflari faoliyatini vaqt bo‘yicha ko‘rsatish uchun trend grafikda ishlatiladi.