Viber бақылау тақтасының KPI есептеу логикасы – Proxima Research Qazaqstan

Viber бақылау тақтасы Viber коммуникациясының өнімділігі үшін KPI карточкаларын, диаграммаларды және егжей-тегжейлі кестелік көрсеткіштерді көрсетеді.

Жоспарланған
Жіберілді
Жіберілген %
Viber жеткізілді
Viber жеткізілген %
Viber оқылды
Viber оқылған %
Viber қаралды
Viber қаралған %
Жазылымнан бас тартқан
Жазылымнан бас тарту %
Жеткізілмеген
Жеткізілмеген %
Жіберілмеген
Жіберілмеген %
Viber жеткізілген динамикасы
Viber оқылған динамикасы
Viber жеткізілмеген динамикасы
Viber қаралған динамикасы

Viber жоспарланған

Таңдалған есеп беру кезеңінде жіберу үшін жоспарланған Viber хабарламаларының жалпы санын көрсетеді.

DAX формуласы

Viber Planned =
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]), 
    'Distribution'[Communication_channel] = "viber"
)

Есептеу логикасы

Өлшем коммуникация арнасы viber болған барлық тарату жазбаларын есептейді.

Бұл таңдалған есеп беру кезеңі мен сүзгілерге сәйкес жоспарланған Viber хабарламаларының жалпы санын көрсетеді.

Viber жіберілді

Жіберу процесіне енген, соңғы жеткізу нәтижесіне қарамастан, Viber хабарламаларының санын көрсетеді.

DAX формуласы

Viber Sent =
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]), 
    FILTER(
        'Distribution Status',
        'Distribution Status'[Distribution_Sending_Status] IN {
            "DELIVERED", "BOUNCED", "DECLINED", "DEFERRED", "EXPIRED",
            "FAILED", "OLD", "REJECTED", "UNDELIVERABLE", "UNDELIVERED",
            "UNKNOWN", "ENQUEUED", "QUEUED", "SENT", "VISITED", "READ", "SEEN"
        }
        && RELATED('Distribution'[Communication_channel]) = "viber"
    )
)

Есептеу логикасы

Өлшем хабарламаның жіберу процесіне енгенін көрсететін жіберу статустары бар Viber хабарламаларын есептейді.

Оған сәтті жеткізілген, оқылған, қаралған немесе көрілген хабарламалар, сондай-ақ сәтсіз жеткізу статустары бар хабарламалар (мысалы, секірген, сәтсіз болған, қабылданбаған, жеткізілмейтін немесе белгісіз) кіреді.

Viber жіберілген %

Жоспарланған Viber хабарламаларының қанша пайызы жіберілгенін көрсетеді.

DAX формуласы

Viber Sent % =
[Viber Sent] / [Viber Planned]

Есептеу логикасы

Өлшем жоспарланған Viber хабарламаларының жіберілген үлесін есептейді.

KPI карточкасының мысалында 1,149,942 хабарлама 1,616,922 жоспарланған хабарламаның ішінде жіберілген, бұл 71.12% тең.

Viber жеткізілді

Қабылдаушыларға сәтті жеткізілген Viber хабарламаларының санын көрсетеді.

DAX формуласы

Viber Delivered =
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]), 
    FILTER(
        'Distribution Status',
        'Distribution Status'[Distribution_Sending_Status] IN {
            "DELIVERED", "READ", "VISITED", "SEEN"
        }
        && RELATED('Distribution'[Communication_channel]) = "viber"
    )
)

Есептеу логикасы

Өлшем қабылдаушыларға сәтті жеткізілген Viber хабарламаларын есептейді.

Статустары READ, VISITED және SEEN хабарламалар да қосылады, өйткені бұл әрекеттер сәтті жеткізуден кейін ғана болуы мүмкін.

Viber жеткізілген %

Жіберілген Viber хабарламаларының қанша пайызы сәтті жеткізілгенін көрсетеді.

DAX формуласы

Viber Delivered % =
[Viber Delivered] / [Viber Sent]

Есептеу логикасы

Өлшем жіберілген Viber хабарламаларының жеткізілген үлесін есептейді.

KPI карточкасының мысалында 914,006 хабарлама 1,149,942 жіберілген хабарламаның ішінде жеткізілген, бұл 79.48% тең.

Viber оқылды

Қабылдаушылар оқыған немесе көрген жеткізілген Viber хабарламаларының санын көрсетеді.

DAX формуласы

Viber Read =
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]), 
    FILTER(
        'Distribution Status',
        'Distribution Status'[Distribution_Sending_Status] IN {
            "READ", "VISITED", "SEEN"
        }
        && RELATED('Distribution'[Communication_channel]) = "viber"
    )
)

Есептеу логикасы

Өлшем қабылдаушылар оқыған Viber хабарламаларын есептейді.

Статустары VISITED және SEEN хабарламалар да қосылады, себебі олар хабарлама оқылған немесе көрілгеннен кейінгі қабылдаушының әрекетін көрсетеді.

Viber оқылған %

Жеткізілген Viber хабарламаларының қанша пайызы қабылдаушылар тарапынан оқылғанын көрсетеді.

DAX формуласы

Viber Read % =
[Viber Read] / [Viber Delivered]

Есептеу логикасы

Өлшем жеткізілген Viber хабарламаларының оқылған үлесін есептейді.

KPI карточкасының мысалында 613,848 хабарлама 914,006 жеткізілген хабарламаның ішінде оқылған, бұл 67.16% тең.

Viber қаралды

Қабылдаушы сілтемеге кірген Viber хабарламаларының санын көрсетеді.

DAX формуласы

Viber Visited =
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]), 
    FILTER(
        'Distribution Status',
        'Distribution Status'[Distribution_Sending_Status] IN { "VISITED" }
        && RELATED('Distribution'[Communication_channel]) = "viber"
    )
)

Есептеу логикасы

Өлшем қабылдаушылар хабарламадан сілтемеге кірген Viber хабарламаларын есептейді.

Бұл Viber коммуникацияларының сілтеме өзара әрекетін қанша рет тудырғанын көрсетеді.

Viber қаралған %

Оқылған Viber хабарламаларының қанша пайызы сілтемеге кіргенін көрсетеді.

DAX формуласы

Viber Visited % =
[Viber Visited] / [Viber Read]

Есептеу логикасы

Өлшем оқылған Viber хабарламаларының сілтемеге кірген үлесін есептейді.

KPI карточкасының мысалында 12,047 хабарлама 613,848 оқылған хабарламаның ішінде сілтемеге кірген, бұл 1.96% тең.

Viber жазылымнан бас тартқан

Viber коммуникацияларынан жазылымнан бас тартқан қабылдаушылардың санын көрсетеді.

DAX формуласы

Viber Unsubscribed =
CALCULATE(
    COUNT('Unsubscribed'[ID_Unsubscribed]), 
    'Distribution'[Communication_channel] = "viber"
)

Есептеу логикасы

Өлшем viber коммуникация арнасы бойынша жазылымнан бас тарту жазбаларын есептейді.

Бұл таңдалған есеп беру кезеңінде Viber коммуникацияларынан жазылымнан бас тартқан қабылдаушылардың санын көрсетеді.

Viber жазылымнан бас тарту %

Жеткізілген Viber хабарламаларының қанша пайызы жазылымнан бас тарту әрекетімен аяқталғанын көрсетеді.

DAX формуласы

Viber Unsubscribe % =
[Viber Unsubscribed] / [Viber Delivered]

Есептеу логикасы

Өлшем жеткізілген Viber хабарламаларының жазылымнан бас тарту әрекетімен аяқталған үлесін есептейді.

KPI карточкасының мысалында 556 жазылымнан бас тарту жазбалары көрсетілген. KPI карточкасында көрсетілген пайыз 0.06%.

Viber жеткізілмеген

Жіберілген, бірақ жеткізілмеген және жеткізілмеу себебі көрсетілген Viber хабарламаларының санын көрсетеді.

DAX формуласы

Viber Undelivered =
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]),
    FILTER(
        'Distribution Status',
        'Distribution Status'[Distribution_Sending_Status] IN {
            "UNDELIVERED", "UNDELIVERABLE",
            "RESENDING_SMS_UNDELIVERED",
            "RESENDING_SMS_UNDELIVERABLE",
            "EXPIRED", "OLD", "BOUNCED",
            "DEFERRED", "UNKNOWN"
        }
        && RELATED('Distribution'[Communication_channel]) = "viber"
        && TRIM('Distribution Status'[Reason_Undelivered_Viber]) <> ""
        && 'Distribution Status'[Reason_Undelivered_Viber] <> "Пусто"
        && NOT ISBLANK('Distribution Status'[Reason_Undelivered_Viber])
    )
)

Есептеу логикасы

Өлшем жеткізілмеген және жеткізілмеу себебі көрсетілген жіберілген Viber хабарламаларын есептейді.

Бұл жеткізу сәтсіздіктерін талдауға және себеп бойынша тексеруді қажет ететін хабарламаларды анықтауға арналған.

Viber жеткізілмеген %

Жіберілген Viber хабарламаларының қанша пайызы жеткізілмегенін көрсетеді.

DAX формуласы

Viber Undelivered % =
[Viber Undelivered] / [Viber Sent]

Есептеу логикасы

Өлшем жіберілген Viber хабарламаларының жеткізілмеген пайызын есептейді.

Бұл пайдаланушыларға барлық жіберілген Viber коммуникациялары арасында жеткізу сәтсіздіктерінің үлесін бағалауға көмектеседі.

Viber жіберілмеген

Жіберу шектеулері, жарамсыз деректер, қайталанулар, жазылымнан бас тарту күйі немесе басқа жіберу мәселелері себепті жіберілмеген жоспарланған Viber хабарламаларының санын көрсетеді.

DAX формуласы

Viber Unsent =
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]), 
    FILTER(
        'Distribution Status',
        'Distribution Status'[Distribution_Sending_Status] IN {
            "DUPLICATE", "INVALID_EMAIL", "EMPTY_RECIPIENT",
            "EMPTY_CONTENT", "MESSAGE_LIMIT", "EXCLUDED",
            "UNSUBSCRIBED", "FAILED", "DECLINED", "UNVERIFIED"
        }
        && RELATED('Distribution'[Communication_channel]) = "viber"
    )
)

Есептеу логикасы

Өлшем жіберу шектеулері, жарамсыз немесе жоқ қабылдаушы деректері, жазылымнан бас тарту күйі, қайталанулар, сәтсіз өңдеу немесе басқа жүйелік жағдайлар себепті жіберілмеген жоспарланған Viber хабарламаларын есептейді.

Viber жіберілмеген %

Жоспарланған Viber хабарламаларының қанша пайызы жіберілмегенін көрсетеді.

DAX формуласы

Viber Unsent % =
[Viber Unsent] / [Viber Planned]

Есептеу логикасы

Өлшем жоспарланған Viber хабарламаларының жіберілмеген үлесін есептейді.

Бұл пайдаланушыларға қанша жоспарланған Viber коммуникациясының жіберу процесіне енбегенін бағалауға көмектеседі.

Viber жеткізілген динамикасы

Таңдалған динамикалық кезеңдегі жеткізілген Viber хабарламаларының санын уақыт бойынша көрсетеді.

DAX формуласы

Viber Delivered Dynamic =
VAR N = [DaysToShow Viber]
VAR MaxDate =
    CALCULATE (
        MAX ( 'Distribution Status'[Send_DateOnly] ),
        ALL ( 'Distribution Status' )
    )
VAR Mode = SELECTEDVALUE(PeriodMode[Mode], "Day")
VAR StartDate_Day = MaxDate - (N - 1)
VAR StartDate_Month =
    DATE(
        YEAR ( EOMONTH ( MaxDate, -N + 1 ) ),
        MONTH( EOMONTH ( MaxDate, -N + 1 ) ),
        1
    )
VAR StartDate = IF(Mode = "Month", StartDate_Month, StartDate_Day)
RETURN
CALCULATE (
    COUNT ( 'Distribution Status'[ID_Distribution] ),
    FILTER (
        ALL ( 'Distribution Status'[Send_DateOnly] ),
        'Distribution Status'[Send_DateOnly] >= StartDate
            && 'Distribution Status'[Send_DateOnly] <= MaxDate
    ),
    KEEPFILTERS (
        'Distribution Status'[Distribution_Sending_Status] IN {
            "DELIVERED", "READ", "VISITED", "SEEN"
        }
    ),
    KEEPFILTERS ( 'Distribution'[Communication_channel] = "viber" ),
    REMOVEFILTERS ( 'Calendar' ),
    REMOVEFILTERS ( 'PeriodsFilter' )
)

Есептеу логикасы

Өлшем таңдалған динамикалық кезең үшін жеткізілген Viber хабарламаларының санын есептейді.

Ол көрсетілген күндер саны DaysToShow Viber және таңдалған кезең режимін, мысалы Күн немесе Ай, пайдалана отырып, тренд диаграммасындағы көрсетілетін күн аралығын анықтайды.

Viber оқылған динамикасы

Таңдалған динамикалық кезеңдегі оқылған Viber хабарламаларының санын уақыт бойынша көрсетеді.

DAX формуласы

Viber Read Dynamic =
VAR N = [DaysToShow Viber]
VAR MaxDate =
    CALCULATE (
        MAX ( 'Distribution Status'[Send_DateOnly] ),
        ALL ( 'Distribution Status' )
    )
VAR Mode = SELECTEDVALUE(PeriodMode[Mode], "Day")
VAR StartDate_Day = MaxDate - (N - 1)
VAR StartDate_Month =
    DATE(
        YEAR ( EOMONTH ( MaxDate, -N + 1 ) ),
        MONTH( EOMONTH ( MaxDate, -N + 1 ) ),
        1
    )
VAR StartDate = IF(Mode = "Month", StartDate_Month, StartDate_Day)
RETURN
CALCULATE (
    COUNT ( 'Distribution Status'[ID_Distribution] ),
    FILTER (
        ALL ( 'Distribution Status'[Send_DateOnly] ),
        'Distribution Status'[Send_DateOnly] >= StartDate
            && 'Distribution Status'[Send_DateOnly] <= MaxDate
    ),
    KEEPFILTERS (
        'Distribution Status'[Distribution_Sending_Status] IN {
            "READ", "VISITED", "SEEN"
        }
    ),
    KEEPFILTERS ( 'Distribution'[Communication_channel] = "viber" ),
    REMOVEFILTERS ( 'Calendar' ),
    REMOVEFILTERS ( 'PeriodsFilter' )
)

Есептеу логикасы

Өлшем таңдалған динамикалық кезең үшін оқылған Viber хабарламаларының санын есептейді.

Ол Хабарлама жеткізу және қатысу трендтері диаграммасында оқылған әрекеттің уақыт бойынша қалай өзгеретінін көрсету үшін қолданылады.

Viber жеткізілмеген динамикасы

Таңдалған динамикалық кезеңдегі жеткізілмеген Viber хабарламаларының санын уақыт бойынша көрсетеді.

DAX формуласы

Viber Undelivred Dynamic =
VAR N = [DaysToShow Viber]
VAR MaxDate =
    CALCULATE (
        MAX ( 'Distribution Status'[Send_DateOnly] ),
        ALL ( 'Distribution Status' )
    )
VAR Mode = SELECTEDVALUE(PeriodMode[Mode], "Day")
VAR StartDate =
    SWITCH (
        TRUE(),
        Mode = "Day", MaxDate - (N - 1),
        Mode = "Month", EOMONTH(MaxDate, -N + 1) + 1,
        MaxDate - N
    )
RETURN
CALCULATE (
    COUNT ( 'Distribution Status'[ID_Distribution] ),
    FILTER (
        ALL ( 'Distribution Status'[Send_DateOnly] ),
        'Distribution Status'[Send_DateOnly] >= StartDate
            && 'Distribution Status'[Send_DateOnly] <= MaxDate
    ),
    KEEPFILTERS (
        'Distribution Status'[Distribution_Sending_Status] IN {
            "UNDELIVERED", "UNDELIVERABLE",
            "RESENDING_SMS_UNDELIVERED",
            "RESENDING_SMS_UNDELIVERABLE",
            "EXPIRED", "OLD", "BOUNCED",
            "DEFERRED", "UNKNOWN"
        }
    ),
    KEEPFILTERS ( 'Distribution'[Communication_channel] = "viber" ),
    REMOVEFILTERS ( 'Calendar' ),
    REMOVEFILTERS ( 'PeriodsFilter' )
)

Есептеу логикасы

Өлшем таңдалған динамикалық кезең үшін жеткізілмеген Viber хабарламаларының санын есептейді.

Ол жеткізу сәтсіздіктерінің динамикасын уақыт бойынша көрсету үшін тренд диаграммасында қолданылады.

Viber қаралған динамикасы

Таңдалған динамикалық кезеңдегі сілтемеге кірген Viber хабарламаларының санын уақыт бойынша көрсетеді.

DAX формуласы

Viber Visited Dynamic =
VAR N = [DaysToShow Viber]
VAR MaxDate =
    CALCULATE (
        MAX ( 'Distribution Status'[Send_DateOnly] ),
        ALL ( 'Distribution Status' )
    )
VAR Mode = SELECTEDVALUE(PeriodMode[Mode], "Day")
VAR StartDate =
    SWITCH (
        TRUE(),
        Mode = "Day", MaxDate - (N - 1),
        Mode = "Month", EOMONTH(MaxDate, -N + 1) + 1,
        MaxDate - N
    )
RETURN
CALCULATE (
    COUNT ( 'Distribution Status'[ID_Distribution] ),
    FILTER (
        ALL ( 'Distribution Status'[Send_DateOnly] ),
        'Distribution Status'[Send_DateOnly] >= StartDate
            && 'Distribution Status'[Send_DateOnly] <= MaxDate
    ),
    KEEPFILTERS (
        'Distribution Status'[Distribution_Sending_Status] IN { "VISITED" }
    ),
    KEEPFILTERS ( 'Distribution'[Communication_channel] = "viber" ),
    REMOVEFILTERS ( 'Calendar' ),
    REMOVEFILTERS ( 'PeriodsFilter' )
)

Есептеу логикасы

Өлшем таңдалған динамикалық кезеңде қабылдаушылар сілтемеге кірген Viber хабарламаларының санын есептейді.

Ол тренд диаграммасында Viber сілтеме кірісінің белсенділігінің уақыт бойынша қалай өзгеретінін көрсету үшін қолданылады.

Search

Viber жоспарланған

Viber жіберілді

Viber жіберілген %

Viber жеткізілді

Viber жеткізілген %

Viber оқылды

Viber оқылған %

Viber қаралды

Viber қаралған %

Viber жазылымнан бас тартқан

Viber жазылымнан бас тарту %

Viber жеткізілмеген

Viber жеткізілмеген %

Viber жіберілмеген

Viber жіберілмеген %

Viber жеткізілген динамикасы

Viber оқылған динамикасы

Viber жеткізілмеген динамикасы

Viber қаралған динамикасы