Skip to main content

Search

SMS Dashboard KPI Calculation Logic

smskpi.jpg

 

Жоспарланған

Таңдалған есеп беру кезеңінде жіберілуі жоспарланған SMS хабарламаларының жалпы санын көрсетеді.

DAX формуласы

SMS Planned =
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]), 
    'Distribution'[Communication_channel] = "sms"
)

Есептеу логикасы

Бұл өлшем байланыс арнасы sms болып табылатын барлық тарату жазбаларын есептейді. Ол таңдалған кезең мен сүзгілерге сәйкес жоспарланған SMS хабарламаларының жалпы санын білдіреді.

Жіберілген

Жіберу процесіне енген SMS хабарламаларының санын көрсетеді.

DAX формуласы

SMS Sent =
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]), 
    FILTER(
        'Distribution Status',
        'Distribution Status'[Distribution_Sending_Status] IN {
            "DELIVERED", "BOUNCED", "DECLINED", "DEFERRED", "EXPIRED",
            "FAILED", "OLD", "REJECTED", "UNDELIVERABLE", "UNDELIVERED",
            "UNKNOWN", "ENQUEUED", "QUEUED", "SENT", "VISITED", "READ", "SEEN"
        }
        && RELATED('Distribution'[Communication_channel]) = "sms"
    )
)

Есептеу логикасы

Бұл өлшем хабарлама жіберу процесіне енгенін көрсететін статустары бар SMS хабарламаларын есептейді. Оған сәтті өңделген хабарламалармен қатар жеткізілмеген статустары бар хабарламалар да кіреді.

Жіберілген %

Жоспарланған SMS хабарламаларының қанша пайызы жіберілгенін көрсетеді.

DAX формуласы

SMS Sent % =
[SMS Sent] / [SMS Planned]

Есептеу логикасы

Бұл өлшем жіберілген SMS хабарламаларының санын жоспарланған SMS хабарламаларының санына бөледі.

Жеткізілген

Қабылдаушыларға сәтті жеткізілген SMS хабарламаларының санын көрсетеді.

DAX формуласы

SMS Delivered =
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]), 
    FILTER(
        'Distribution Status',
        'Distribution Status'[Distribution_Sending_Status] IN {
            "DELIVERED", "READ", "VISITED", "SEEN"
        }
        && RELATED('Distribution'[Communication_channel]) = "sms"
    )
)

Есептеу логикасы

Бұл өлшем жеткізуге қатысты статустары бар SMS хабарламаларын есептейді. READ, VISITED және SEEN сияқты статустар сәтті жеткізуден кейін ғана орын алатын әрекеттер болғандықтан қосылады.

Жеткізілген %

Жіберілген SMS хабарламаларының қанша пайызы сәтті жеткізілгенін көрсетеді.

DAX формуласы

SMS Delivered % =
[SMS Delivered] / [SMS Sent]

Есептеу логикасы

Бұл өлшем жеткізілген SMS хабарламаларының санын жіберілген SMS хабарламаларының санына бөледі.

Оқылған

Қабылдаушылар оқыған немесе көрген SMS хабарламаларының санын көрсетеді.

DAX формуласы

SMS Read =
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]), 
    FILTER(
        'Distribution Status',
        'Distribution Status'[Distribution_Sending_Status] IN {
            "READ", "VISITED", "SEEN"
        }
        && RELATED('Distribution'[Communication_channel]) = "sms"
    )
)

Есептеу логикасы

Бұл өлшем қабылдаушының оқу немесе қарау әрекетін көрсететін статустары бар SMS хабарламаларын есептейді.

Қаралған

Қабылдаушылар сілтемеге кірген SMS хабарламаларының санын көрсетеді.

DAX формуласы

SMS Visited =
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]), 
    FILTER(
        'Distribution Status',
        'Distribution Status'[Distribution_Sending_Status] IN { "VISITED" }
        && RELATED('Distribution'[Communication_channel]) = "sms"
    )
)

Есептеу логикасы

Бұл өлшем VISITED статусындағы SMS хабарламаларын есептейді. Ол қанша SMS байланысы сілтеме арқылы әрекет тудырғанын көрсетеді.

Қаралған %

Жеткізілген SMS хабарламаларының қанша пайызы сілтемеге кірумен аяқталғанын көрсетеді.

DAX формуласы

SMS Visited % =
[SMS Visited] / [SMS Delivered]

Есептеу логикасы

Бұл өлшем сілтемеге кірген SMS хабарламаларының санын жеткізілген SMS хабарламаларының санына бөледі.

Жазылымнан шыққан

SMS байланыстарынан жазылымнан шыққан қабылдаушылар санын көрсетеді.

DAX формуласы

SMS Unsubscribed =
CALCULATE(
    COUNT('Unsubscribed'[ID_Unsubscribed]), 
    'Distribution'[Communication_channel] = "sms"
)

Есептеу логикасы

Бұл өлшем sms байланыс арнасы бойынша жазылымнан шығу жазбаларын есептейді.

Жазылымнан шыққан %

Жеткізілген SMS хабарламаларының қанша пайызы жазылымнан шығу әрекетімен аяқталғанын көрсетеді.

DAX формуласы

SMS Unsubscribed % =
[SMS Unsubscribed] / [SMS Delivered]

Есептеу логикасы

Бұл өлшем жазылымнан шыққан SMS жазбаларының санын жеткізілген SMS хабарламаларының санына бөледі.

Жеткізілмеген

Жіберілген, бірақ жеткізілмеген SMS хабарламаларының санын көрсетеді.

DAX формуласы

SMS Undelivered =
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]), 
    FILTER(
        'Distribution Status',
        'Distribution Status'[Distribution_Sending_Status] IN {
            "UNDELIVERED", "UNDELIVERABLE",
            "RESENDING_SMS_UNDELIVERED",
            "RESENDING_SMS_UNDELIVERABLE",
            "EXPIRED", "OLD", "BOUNCED",
            "DEFERRED", "UNKNOWN"
        }
        && RELATED('Distribution'[Communication_channel]) = "sms"
    )
)

Есептеу логикасы

Бұл өлшем жеткізу сәтсіз болғанын көрсететін статустары бар SMS хабарламаларын есептейді.

Жеткізілмеген %

Жіберілген SMS хабарламаларының қанша пайызы жеткізілмегенін көрсетеді.

DAX формуласы

SMS Undelivered % =
[SMS Undelivered] / [SMS Sent]

Есептеу логикасы

Бұл өлшем жеткізілмеген SMS хабарламаларының санын жіберілген SMS хабарламаларының санына бөледі.

Жіберілмеген

Жоспарланған, бірақ жіберілмеген SMS хабарламаларының санын көрсетеді.

DAX формуласы

SMS Unsent =
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]), 
    FILTER(
        'Distribution Status',
        'Distribution Status'[Distribution_Sending_Status] IN {
            "DUPLICATE", "INVALID_EMAIL", "EMPTY_RECIPIENT",
            "EMPTY_CONTENT", "MESSAGE_LIMIT", "EXCLUDED",
            "UNSUBSCRIBED", "FAILED", "DECLINED", "UNVERIFIED"
        }
        && RELATED('Distribution'[Communication_channel]) = "sms"
    )
)

Есептеу логикасы

Бұл өлшем шектеулер, қайталанатын жазбалар, қабылдаушы деректерінің жоқтығы, өңдеудің сәтсіздігі немесе басқа жіберу мәселелері салдарынан жіберілмеген жоспарланған SMS хабарламаларын есептейді.

Жіберілмеген %

Жоспарланған SMS хабарламаларының қанша пайызы жіберілмегенін көрсетеді.

DAX формуласы

SMS Unsent % =
[SMS Unsent] / [SMS Planned]

Есептеу логикасы

Бұл өлшем жіберілмеген SMS хабарламаларының санын жоспарланған SMS хабарламаларының санына бөледі.

SMS жеткізілген динамикасы

Таңдалған динамикалық кезеңдегі жеткізілген SMS хабарламаларының санын уақыт бойынша көрсетеді.

DAX формуласы

SMS Delivered Dynamic =
VAR N = [DaysToShow SMS]
VAR MaxDate =
    CALCULATE (
        MAX ( 'Distribution Status'[Send_DateOnly] ),
        ALL ( 'Distribution Status' )
    )
VAR Mode = SELECTEDVALUE(PeriodMode[Mode], "Day")
VAR StartDate_Day = MaxDate - (N - 1)
VAR StartDate_Month =
    DATE(
        YEAR ( EOMONTH ( MaxDate, -N + 1 ) ),
        MONTH( EOMONTH ( MaxDate, -N + 1 ) ),
        1
    )
VAR StartDate = IF(Mode = "Month", StartDate_Month, StartDate_Day)
RETURN
CALCULATE (
    COUNT ( 'Distribution Status'[ID_Distribution] ),
    FILTER (
        ALL ( 'Distribution Status'[Send_DateOnly] ),
        'Distribution Status'[Send_DateOnly] >= StartDate
            && 'Distribution Status'[Send_DateOnly] <= MaxDate
    ),
    KEEPFILTERS (
        'Distribution Status'[Distribution_Sending_Status] IN {
            "DELIVERED", "READ", "VISITED", "SEEN"
        }
    ),
    KEEPFILTERS ( 'Distribution'[Communication_channel] = "sms" ),
    REMOVEFILTERS ( 'Calendar' ),
    REMOVEFILTERS ( 'PeriodsFilter' )
)

Есептеу логикасы

Бұл өлшем таңдалған динамикалық кезең үшін жеткізілген SMS хабарламаларының санын есептейді. Ол көрсетілген күндер санын DaysToShow SMS және таңдалған кезең режимін, мысалы, Күн немесе Ай, пайдалана отырып, көрсетілген күн аралығын анықтайды.

SMS оқылған динамикасы

Таңдалған динамикалық кезеңдегі оқылған SMS хабарламаларының санын уақыт бойынша көрсетеді.

DAX формуласы

SMS Read Dynamic =
VAR N = [DaysToShow SMS]
VAR MaxDate =
    CALCULATE (
        MAX ( 'Distribution Status'[Send_DateOnly] ),
        ALL ( 'Distribution Status' )
    )
VAR Mode = SELECTEDVALUE(PeriodMode[Mode], "Day")
VAR StartDate_Day = MaxDate - (N - 1)
VAR StartDate_Month =
    DATE(
        YEAR ( EOMONTH ( MaxDate, -N + 1 ) ),
        MONTH( EOMONTH ( MaxDate, -N + 1 ) ),
        1
    )
VAR StartDate = IF(Mode = "Month", StartDate_Month, StartDate_Day)
RETURN
CALCULATE (
    COUNT ( 'Distribution Status'[ID_Distribution] ),
    FILTER (
        ALL ( 'Distribution Status'[Send_DateOnly] ),
        'Distribution Status'[Send_DateOnly] >= StartDate
            && 'Distribution Status'[Send_DateOnly] <= MaxDate
    ),
    KEEPFILTERS (
        'Distribution Status'[Distribution_Sending_Status] IN {
            "READ", "VISITED", "SEEN"
        }
    ),
    KEEPFILTERS ( 'Distribution'[Communication_channel] = "sms" ),
    REMOVEFILTERS ( 'Calendar' ),
    REMOVEFILTERS ( 'PeriodsFilter' )
)

Есептеу логикасы

Бұл өлшем таңдалған динамикалық кезең ішінде қабылдаушылар оқыған SMS хабарламаларының санын есептейді. Ол Хабарламаны жеткізу және қатысу тенденциялары графигінде қолданылады.

SMS жеткізілмеген динамикасы

Таңдалған динамикалық кезеңдегі жеткізілмеген SMS хабарламаларының санын уақыт бойынша көрсетеді.

DAX формуласы

SMS Undelivred Dynamic =
VAR N = [DaysToShow SMS]
VAR MaxDate =
    CALCULATE (
        MAX ( 'Distribution Status'[Send_DateOnly] ),
        ALL ( 'Distribution Status' )
    )
VAR Mode = SELECTEDVALUE(PeriodMode[Mode], "Day")
VAR StartDate =
    SWITCH (
        TRUE(),
        Mode = "Day", MaxDate - (N - 1),
        Mode = "Month", EOMONTH(MaxDate, -N + 1) + 1,
        MaxDate - N
    )
RETURN
CALCULATE (
    COUNT ( 'Distribution Status'[ID_Distribution] ),
    FILTER (
        ALL ( 'Distribution Status'[Send_DateOnly] ),
        'Distribution Status'[Send_DateOnly] >= StartDate
            && 'Distribution Status'[Send_DateOnly] <= MaxDate
    ),
    KEEPFILTERS (
        'Distribution Status'[Distribution_Sending_Status] IN {
            "UNDELIVERED", "UNDELIVERABLE",
            "RESENDING_SMS_UNDELIVERED",
            "RESENDING_SMS_UNDELIVERABLE",
            "EXPIRED", "OLD", "BOUNCED",
            "DEFERRED", "UNKNOWN"
        }
    ),
    KEEPFILTERS ( 'Distribution'[Communication_channel] = "sms" ),
    REMOVEFILTERS ( 'Calendar' ),
    REMOVEFILTERS ( 'PeriodsFilter' )
)

Есептеу логикасы

Бұл өлшем таңдалған динамикалық кезең ішінде жеткізілмеген SMS хабарламаларының санын есептейді. Ол жеткізу сәтсіздігінің уақыт бойынша динамикасын көрсету үшін қолданылады.

SMS қаралған динамикасы

Таңдалған динамикалық кезеңдегі сілтемеге кірген SMS хабарламаларының санын уақыт бойынша көрсетеді.

DAX формуласы

SMS Visited Dynamic =
VAR N = [DaysToShow SMS]
VAR MaxDate =
    CALCULATE (
        MAX ( 'Distribution Status'[Send_DateOnly] ),
        ALL ( 'Distribution Status' )
    )
VAR Mode = SELECTEDVALUE(PeriodMode[Mode], "Day")
VAR StartDate =
    SWITCH (
        TRUE(),
        Mode = "Day", MaxDate - (N - 1),
        Mode = "Month", EOMONTH(MaxDate, -N + 1) + 1,
        MaxDate - N
    )
RETURN
CALCULATE (
    COUNT ( 'Distribution Status'[ID_Distribution] ),
    FILTER (
        ALL ( 'Distribution Status'[Send_DateOnly] ),
        'Distribution Status'[Send_DateOnly] >= StartDate
            && 'Distribution Status'[Send_DateOnly] <= MaxDate
    ),
    KEEPFILTERS (
        'Distribution Status'[Distribution_Sending_Status] IN { "VISITED" }
    ),
    KEEPFILTERS ( 'Distribution'[Communication_channel] = "sms" ),
    REMOVEFILTERS ( 'Calendar' ),
    REMOVEFILTERS ( 'PeriodsFilter' )
)

Есептеу логикасы

Бұл өлшем таңдалған динамикалық кезең ішінде қабылдаушылар сілтемеге кірген SMS хабарламаларының санын есептейді. Ол уақыт бойынша SMS сілтеме қарау белсенділігін көрсету үшін тренд графигінде қолданылады.