Pular para o conteúdo principal

Pesquisa

Calls PL/AC Dashboard - lógica de cálculo de KPI

O Calls PL/AC Dashboard exibe KPIs na parte central do relatório e na Detailed Calls Execution Table.

kpipcac.jpg

Planned Calls

  • Baseado em planos de atividade aprovados.

  • Todos os filtros ativos afetam os cálculos.

Exibe o número total de visitas planejadas para o período de relatório selecionado. Representa o plano de atividades usado para avaliar o desempenho da execução.

Fórmula DAX

CALCULATE(
    SUM(crm_task_plan_v2_csv[plan_taskcount]),
    crm_task_plan_v2_csv[plan_name] = "task"
)

Lógica de cálculo

Calcula o número total de visitas planejadas a partir da tabela de planejamento de atividades onde o tipo de plano é task.

Total

  • Somente visitas concluídas são incluídas.

  • Somente tarefas principais (key_task_main = 1) são contadas.

  • Todos os filtros ativos afetam os cálculos.

Exibe o número total de visitas concluídas. Representa a atividade real em campo concluída durante o período de relatório selecionado.

Fórmula DAX

CALCULATE(
    DISTINCTCOUNT(crm_task_fact_v2_csv[key_task_id]),
    crm_task_fact_v2_csv[key_task_isfinish] = 1,
    crm_task_fact_v2_csv[key_task_main] = 1
)

Lógica de cálculo

Calcula o número único de visitas principais concluídas.

By Plan

  • Somente visitas concluídas são incluídas.

  • Somente visitas vinculadas a planos de atividade são contadas.

  • Todos os filtros ativos afetam os cálculos.

Exibe o número de visitas concluídas que foram planejadas. Mede quantas atividades planejadas foram executadas com sucesso.

Fórmula DAX

VAR FilteredKeys =
    SELECTCOLUMNS(
        FILTER(crm_task_plan_v2_csv, plan_name = "task"),
        "key_task_plan", crm_task_plan_v2_csv[key_task_plan]
    )
RETURN
CALCULATE(
    DISTINCTCOUNT(crm_task_fact_v2_csv[key_task_id]),
    TREATAS(FilteredKeys, crm_task_fact_v2_csv[key_task_plan]),
    crm_task_fact_v2_csv[key_task_isfinish] = 1
)

Lógica de cálculo

Calcula visitas concluídas vinculadas a atividades planejadas.
A medida usa TREATAS para corresponder visitas planejadas aos registros de visitas concluídas.

Out of Plan

  • Valores maiores que zero indicam execução fora do plano de atividades aprovado.

  • Todos os filtros ativos afetam os cálculos.

Exibe o número de visitas concluídas que não foram incluídas no plano de atividades. Ajuda a identificar atividade em campo não planejada.

Fórmula DAX

[Total] - [By Plan]

Lógica de cálculo

Calcula a diferença entre o total de visitas concluídas e as visitas planejadas concluídas.

Completed %

  • Valores acima de 100% indicam atividade acima do plano.

  • Valores abaixo de 100% indicam desempenho abaixo do esperado.

Exibe o cumprimento geral do plano. Mede a porcentagem de visitas planejadas que foram concluídas.

Fórmula DAX

DIVIDE([Total], [Planned calls])

Lógica de cálculo

Calcula a razão entre visitas concluídas e visitas planejadas.

Exemplo

Planned Calls = 1,000

Completed Calls = 900

Resultado:
90%

By Plan %

  • Exclui visitas não planejadas.

  • Fornece uma medida direta de aderência ao plano.

Exibe o desempenho de execução dentro do plano de atividades aprovado. Mede a eficácia com que as atividades planejadas foram concluídas.

Fórmula DAX

DIVIDE([By Plan], [Planned calls])

Lógica de cálculo

Calcula a proporção de visitas planejadas que foram concluídas conforme planejado.

VE (Visit Equivalent)

  • Diferentes tipos de atividade contribuem com pesos diferentes.

  • Usado para avaliação padronizada do desempenho de atividades.

Exibe o número ponderado de visitas concluídas. Fornece uma medida padronizada para comparar diferentes tipos de atividade. Diferentes tipos de visita podem ter diferentes importâncias de negócio e, portanto, diferentes pesos.

Fórmula DAX

VAR UniqueTasks =
    ADDCOLUMNS(
        SUMMARIZE(
            FILTER(crm_task_fact_v2_csv, key_task_isfinish = 1),
            key_task_id,
            key_tasktype_id
        ),
        "PromoCount",
        LOOKUPVALUE(
            crm_tasktype_csv[promocount],
            crm_tasktype_csv[tasktype_id],
            crm_task_fact_v2_csv[key_tasktype_id]
        )
    )
RETURN
SUMX(UniqueTasks, [PromoCount])

Lógica de cálculo

Calcula uma contagem ponderada de visitas usando o coeficiente promocional atribuído a cada tipo de visita.

Fact VE %

  • Reflete o cumprimento do plano usando valores ponderados de atividade.

  • Fornece uma medida de desempenho mais precisa do que simples contagens de visitas.

Exibe o cumprimento ponderado do plano. Mede a execução do plano considerando o valor de negócio de diferentes tipos de atividade.

Fórmula DAX

DIVIDE([VE (Visit Equivalent)], [Planned calls])

Lógica de cálculo

Calcula a razão entre Visit Equivalent e visitas planejadas.