Перейти до основного контенту

Пошук

Calls PL/AC Dashboard - логіка розрахунку KPI

Calls PL/AC Dashboard відображає KPI в центральній частині звіту та в Detailed Calls Execution Table.

kpipcac.jpg

Planned Calls

  • Базується на затверджених планах активності.

  • Усі активні фільтри впливають на розрахунки.

Відображає загальну кількість запланованих візитів за вибраний звітний період. Представляє план активності, який використовується для оцінки ефективності виконання.

DAX-формула

CALCULATE(
    SUM(crm_task_plan_v2_csv[plan_taskcount]),
    crm_task_plan_v2_csv[plan_name] = "task"
)

Логіка розрахунку

Розраховує загальну кількість запланованих візитів із таблиці планування активностей, де тип плану — task.

Total

  • Включаються лише завершені візити.

  • Враховуються лише основні задачі (key_task_main = 1).

  • Усі активні фільтри впливають на розрахунки.

Відображає загальну кількість завершених візитів. Представляє фактичну польову активність, виконану протягом вибраного звітного періоду.

DAX-формула

CALCULATE(
    DISTINCTCOUNT(crm_task_fact_v2_csv[key_task_id]),
    crm_task_fact_v2_csv[key_task_isfinish] = 1,
    crm_task_fact_v2_csv[key_task_main] = 1
)

Логіка розрахунку

Розраховує унікальну кількість завершених основних візитів.

By Plan

  • Включаються лише завершені візити.

  • Враховуються лише візити, пов’язані з планами активності.

  • Усі активні фільтри впливають на розрахунки.

Відображає кількість завершених візитів, які були заплановані. Вимірює, скільки запланованих активностей було успішно виконано.

DAX-формула

VAR FilteredKeys =
    SELECTCOLUMNS(
        FILTER(crm_task_plan_v2_csv, plan_name = "task"),
        "key_task_plan", crm_task_plan_v2_csv[key_task_plan]
    )
RETURN
CALCULATE(
    DISTINCTCOUNT(crm_task_fact_v2_csv[key_task_id]),
    TREATAS(FilteredKeys, crm_task_fact_v2_csv[key_task_plan]),
    crm_task_fact_v2_csv[key_task_isfinish] = 1
)

Логіка розрахунку

Розраховує завершені візити, пов’язані із запланованими активностями.
Міра використовує TREATAS, щоб зіставити заплановані візити із записами завершених візитів.

Out of Plan

  • Значення більше нуля вказують на виконання поза затвердженим планом активності.

  • Усі активні фільтри впливають на розрахунки.

Відображає кількість завершених візитів, які не були включені до плану активності. Допомагає виявити незаплановану польову активність.

DAX-формула

[Total] - [By Plan]

Логіка розрахунку

Розраховує різницю між загальною кількістю завершених візитів і завершеними плановими візитами.

Completed %

  • Значення вище 100% вказують на активність, що перевищує план.

  • Значення нижче 100% вказують на недовиконання.

Відображає загальне виконання плану. Вимірює відсоток запланованих візитів, які були завершені.

DAX-формула

DIVIDE([Total], [Planned calls])

Логіка розрахунку

Розраховує співвідношення завершених візитів до запланованих візитів.

Приклад

Planned Calls = 1,000

Completed Calls = 900

Результат:
90%

By Plan %

  • Виключає незаплановані візити.

  • Надає прямий показник дотримання плану.

Відображає ефективність виконання в межах затвердженого плану активності. Вимірює, наскільки ефективно були завершені заплановані активності.

DAX-формула

DIVIDE([By Plan], [Planned calls])

Логіка розрахунку

Розраховує частку запланованих візитів, які були завершені відповідно до плану.

VE (Visit Equivalent)

  • Різні типи активностей мають різну вагу.

  • Використовується для стандартизованої оцінки ефективності активності.

Відображає зважену кількість завершених візитів. Надає стандартизований показник для порівняння різних типів активностей. Різні типи візитів можуть мати різну бізнес-важливість і, відповідно, різну вагу.

DAX-формула

VAR UniqueTasks =
    ADDCOLUMNS(
        SUMMARIZE(
            FILTER(crm_task_fact_v2_csv, key_task_isfinish = 1),
            key_task_id,
            key_tasktype_id
        ),
        "PromoCount",
        LOOKUPVALUE(
            crm_tasktype_csv[promocount],
            crm_tasktype_csv[tasktype_id],
            crm_task_fact_v2_csv[key_tasktype_id]
        )
    )
RETURN
SUMX(UniqueTasks, [PromoCount])

Логіка розрахунку

Розраховує зважену кількість візитів, використовуючи промо-коефіцієнт, призначений кожному типу візиту.

Fact VE %

  • Відображає виконання плану з використанням зважених значень активності.

  • Надає точніший показник ефективності, ніж простий підрахунок візитів.

Відображає зважене виконання плану. Вимірює виконання плану з урахуванням бізнес-цінності різних типів активності.

DAX-формула

DIVIDE([VE (Visit Equivalent)], [Planned calls])

Логіка розрахунку

Розраховує співвідношення Visit Equivalent до запланованих візитів.