Przejdź do głównej zawartości

Szukaj

SMS Dashboard KPI Calculation Logic

smskpi.jpg

 

Zaplanowane

Pokazuje łączną liczbę wiadomości SMS zaplanowanych do wysłania w wybranym okresie raportowania.

Formuła DAX

SMS Planned =
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]), 
    'Distribution'[Communication_channel] = "sms"
)

Logika obliczeń

Miara zlicza wszystkie rekordy dystrybucji, w których kanał komunikacji to sms. Reprezentuje łączną liczbę zaplanowanych wiadomości SMS dla wybranego okresu i filtrów.

Wysłane

Pokazuje liczbę wiadomości SMS, które rozpoczęły proces wysyłki.

Formuła DAX

SMS Sent =
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]), 
    FILTER(
        'Distribution Status',
        'Distribution Status'[Distribution_Sending_Status] IN {
            "DELIVERED", "BOUNCED", "DECLINED", "DEFERRED", "EXPIRED",
            "FAILED", "OLD", "REJECTED", "UNDELIVERABLE", "UNDELIVERED",
            "UNKNOWN", "ENQUEUED", "QUEUED", "SENT", "VISITED", "READ", "SEEN"
        }
        && RELATED('Distribution'[Communication_channel]) = "sms"
    )
)

Logika obliczeń

Miara zlicza wiadomości SMS o statusach wskazujących, że wiadomość rozpoczęła proces wysyłki. Uwzględnia zarówno wiadomości przetworzone pomyślnie, jak i z nieudanymi statusami dostarczenia.

Wysłane %

Pokazuje procent zaplanowanych wiadomości SMS, które zostały wysłane.

Formuła DAX

SMS Sent % =
[SMS Sent] / [SMS Planned]

Logika obliczeń

Miara dzieli liczbę wysłanych wiadomości SMS przez liczbę zaplanowanych wiadomości SMS.

Dostarczone

Pokazuje liczbę wiadomości SMS pomyślnie dostarczonych odbiorcom.

Formuła DAX

SMS Delivered =
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]), 
    FILTER(
        'Distribution Status',
        'Distribution Status'[Distribution_Sending_Status] IN {
            "DELIVERED", "READ", "VISITED", "SEEN"
        }
        && RELATED('Distribution'[Communication_channel]) = "sms"
    )
)

Logika obliczeń

Miara zlicza wiadomości SMS o statusach związanych z dostarczeniem. Statusy takie jak READ, VISITED oraz SEEN są uwzględnione, ponieważ te działania mogą wystąpić tylko po pomyślnym dostarczeniu.

Dostarczone %

Pokazuje procent wysłanych wiadomości SMS, które zostały pomyślnie dostarczone.

Formuła DAX

SMS Delivered % =
[SMS Delivered] / [SMS Sent]

Logika obliczeń

Miara dzieli liczbę dostarczonych wiadomości SMS przez liczbę wysłanych wiadomości SMS.

Przeczytane

Pokazuje liczbę wiadomości SMS przeczytanych lub zobaczonych przez odbiorców.

Formuła DAX

SMS Read =
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]), 
    FILTER(
        'Distribution Status',
        'Distribution Status'[Distribution_Sending_Status] IN {
            "READ", "VISITED", "SEEN"
        }
        && RELATED('Distribution'[Communication_channel]) = "sms"
    )
)

Logika obliczeń

Miara zlicza wiadomości SMS o statusach wskazujących na aktywność odbiorcy polegającą na czytaniu lub przeglądaniu.

Odwiedzone

Pokazuje liczbę wiadomości SMS, w których odbiorcy odwiedzili link.

Formuła DAX

SMS Visited =
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]), 
    FILTER(
        'Distribution Status',
        'Distribution Status'[Distribution_Sending_Status] IN { "VISITED" }
        && RELATED('Distribution'[Communication_channel]) = "sms"
    )
)

Logika obliczeń

Miara zlicza wiadomości SMS o statusie VISITED. Pokazuje, ile komunikatów SMS wygenerowało interakcję z linkiem.

Odwiedzone %

Pokazuje procent dostarczonych wiadomości SMS, które skutkowały odwiedziną linku.

Formuła DAX

SMS Visited % =
[SMS Visited] / [SMS Delivered]

Logika obliczeń

Miara dzieli liczbę wiadomości SMS z odwiedzinami linku przez liczbę dostarczonych wiadomości SMS.

Wypisani

Pokazuje liczbę odbiorców, którzy wypisali się z komunikacji SMS.

Formuła DAX

SMS Unsubscribed =
CALCULATE(
    COUNT('Unsubscribed'[ID_Unsubscribed]), 
    'Distribution'[Communication_channel] = "sms"
)

Logika obliczeń

Miara zlicza rekordy wypisania dla kanału komunikacji sms.

Wypisani %

Pokazuje procent dostarczonych wiadomości SMS, które skutkowały wypisaniem się.

Formuła DAX

SMS Unsubscribed % =
[SMS Unsubscribed] / [SMS Delivered]

Logika obliczeń

Miara dzieli liczbę rekordów wypisania z SMS przez liczbę dostarczonych wiadomości SMS.

Niedostarczone

Pokazuje liczbę wysłanych wiadomości SMS, które nie zostały dostarczone.

Formuła DAX

SMS Undelivered =
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]), 
    FILTER(
        'Distribution Status',
        'Distribution Status'[Distribution_Sending_Status] IN {
            "UNDELIVERED", "UNDELIVERABLE",
            "RESENDING_SMS_UNDELIVERED",
            "RESENDING_SMS_UNDELIVERABLE",
            "EXPIRED", "OLD", "BOUNCED",
            "DEFERRED", "UNKNOWN"
        }
        && RELATED('Distribution'[Communication_channel]) = "sms"
    )
)

Logika obliczeń

Miara zlicza wiadomości SMS o statusach wskazujących na niepowodzenie dostarczenia.

Niedostarczone %

Pokazuje procent wysłanych wiadomości SMS, które nie zostały dostarczone.

Formuła DAX

SMS Undelivered % =
[SMS Undelivered] / [SMS Sent]

Logika obliczeń

Miara dzieli liczbę niedostarczonych wiadomości SMS przez liczbę wysłanych wiadomości SMS.

Niewysłane

Pokazuje liczbę zaplanowanych wiadomości SMS, które nie zostały wysłane.

Formuła DAX

SMS Unsent =
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]), 
    FILTER(
        'Distribution Status',
        'Distribution Status'[Distribution_Sending_Status] IN {
            "DUPLICATE", "INVALID_EMAIL", "EMPTY_RECIPIENT",
            "EMPTY_CONTENT", "MESSAGE_LIMIT", "EXCLUDED",
            "UNSUBSCRIBED", "FAILED", "DECLINED", "UNVERIFIED"
        }
        && RELATED('Distribution'[Communication_channel]) = "sms"
    )
)

Logika obliczeń

Miara zlicza zaplanowane wiadomości SMS, które nie zostały wysłane z powodu ograniczeń, duplikatów, brakujących danych odbiorcy, błędów przetwarzania lub innych problemów z wysyłką.

Niewysłane %

Pokazuje procent zaplanowanych wiadomości SMS, które nie zostały wysłane.

Formuła DAX

SMS Unsent % =
[SMS Unsent] / [SMS Planned]

Logika obliczeń

Miara dzieli liczbę niewysłanych wiadomości SMS przez liczbę zaplanowanych wiadomości SMS.

Dynamiczne dostarczenie SMS

Pokazuje liczbę dostarczonych wiadomości SMS w czasie dla wybranego okresu dynamicznego.

Formuła DAX

SMS Delivered Dynamic =
VAR N = [DaysToShow SMS]
VAR MaxDate =
    CALCULATE (
        MAX ( 'Distribution Status'[Send_DateOnly] ),
        ALL ( 'Distribution Status' )
    )
VAR Mode = SELECTEDVALUE(PeriodMode[Mode], "Day")
VAR StartDate_Day = MaxDate - (N - 1)
VAR StartDate_Month =
    DATE(
        YEAR ( EOMONTH ( MaxDate, -N + 1 ) ),
        MONTH( EOMONTH ( MaxDate, -N + 1 ) ),
        1
    )
VAR StartDate = IF(Mode = "Month", StartDate_Month, StartDate_Day)
RETURN
CALCULATE (
    COUNT ( 'Distribution Status'[ID_Distribution] ),
    FILTER (
        ALL ( 'Distribution Status'[Send_DateOnly] ),
        'Distribution Status'[Send_DateOnly] >= StartDate
            && 'Distribution Status'[Send_DateOnly] <= MaxDate
    ),
    KEEPFILTERS (
        'Distribution Status'[Distribution_Sending_Status] IN {
            "DELIVERED", "READ", "VISITED", "SEEN"
        }
    ),
    KEEPFILTERS ( 'Distribution'[Communication_channel] = "sms" ),
    REMOVEFILTERS ( 'Calendar' ),
    REMOVEFILTERS ( 'PeriodsFilter' )
)

Logika obliczeń

Miara oblicza liczbę dostarczonych wiadomości SMS dla wybranego okresu dynamicznego. Wykorzystuje DaysToShow SMS oraz wybrany tryb okresu, taki jak Dzień lub Miesiąc, aby określić wyświetlany zakres dat.

Dynamiczne przeczytanie SMS

Pokazuje liczbę przeczytanych wiadomości SMS w czasie dla wybranego okresu dynamicznego.

Formuła DAX

SMS Read Dynamic =
VAR N = [DaysToShow SMS]
VAR MaxDate =
    CALCULATE (
        MAX ( 'Distribution Status'[Send_DateOnly] ),
        ALL ( 'Distribution Status' )
    )
VAR Mode = SELECTEDVALUE(PeriodMode[Mode], "Day")
VAR StartDate_Day = MaxDate - (N - 1)
VAR StartDate_Month =
    DATE(
        YEAR ( EOMONTH ( MaxDate, -N + 1 ) ),
        MONTH( EOMONTH ( MaxDate, -N + 1 ) ),
        1
    )
VAR StartDate = IF(Mode = "Month", StartDate_Month, StartDate_Day)
RETURN
CALCULATE (
    COUNT ( 'Distribution Status'[ID_Distribution] ),
    FILTER (
        ALL ( 'Distribution Status'[Send_DateOnly] ),
        'Distribution Status'[Send_DateOnly] >= StartDate
            && 'Distribution Status'[Send_DateOnly] <= MaxDate
    ),
    KEEPFILTERS (
        'Distribution Status'[Distribution_Sending_Status] IN {
            "READ", "VISITED", "SEEN"
        }
    ),
    KEEPFILTERS ( 'Distribution'[Communication_channel] = "sms" ),
    REMOVEFILTERS ( 'Calendar' ),
    REMOVEFILTERS ( 'PeriodsFilter' )
)

Logika obliczeń

Miara oblicza liczbę wiadomości SMS przeczytanych przez odbiorców w wybranym okresie dynamicznym. Jest używana na wykresie Trendy dostarczania i zaangażowania wiadomości.

Dynamiczne niedostarczenie SMS

Pokazuje liczbę niedostarczonych wiadomości SMS w czasie dla wybranego okresu dynamicznego.

Formuła DAX

SMS Undelivred Dynamic =
VAR N = [DaysToShow SMS]
VAR MaxDate =
    CALCULATE (
        MAX ( 'Distribution Status'[Send_DateOnly] ),
        ALL ( 'Distribution Status' )
    )
VAR Mode = SELECTEDVALUE(PeriodMode[Mode], "Day")
VAR StartDate =
    SWITCH (
        TRUE(),
        Mode = "Day", MaxDate - (N - 1),
        Mode = "Month", EOMONTH(MaxDate, -N + 1) + 1,
        MaxDate - N
    )
RETURN
CALCULATE (
    COUNT ( 'Distribution Status'[ID_Distribution] ),
    FILTER (
        ALL ( 'Distribution Status'[Send_DateOnly] ),
        'Distribution Status'[Send_DateOnly] >= StartDate
            && 'Distribution Status'[Send_DateOnly] <= MaxDate
    ),
    KEEPFILTERS (
        'Distribution Status'[Distribution_Sending_Status] IN {
            "UNDELIVERED", "UNDELIVERABLE",
            "RESENDING_SMS_UNDELIVERED",
            "RESENDING_SMS_UNDELIVERABLE",
            "EXPIRED", "OLD", "BOUNCED",
            "DEFERRED", "UNKNOWN"
        }
    ),
    KEEPFILTERS ( 'Distribution'[Communication_channel] = "sms" ),
    REMOVEFILTERS ( 'Calendar' ),
    REMOVEFILTERS ( 'PeriodsFilter' )
)

Logika obliczeń

Miara oblicza liczbę niedostarczonych wiadomości SMS w wybranym okresie dynamicznym. Jest używana do prezentacji dynamiki niepowodzeń dostarczenia w czasie.

Dynamiczne odwiedziny SMS

Pokazuje liczbę wiadomości SMS z odwiedzinami linku w czasie dla wybranego okresu dynamicznego.

Formuła DAX

SMS Visited Dynamic =
VAR N = [DaysToShow SMS]
VAR MaxDate =
    CALCULATE (
        MAX ( 'Distribution Status'[Send_DateOnly] ),
        ALL ( 'Distribution Status' )
    )
VAR Mode = SELECTEDVALUE(PeriodMode[Mode], "Day")
VAR StartDate =
    SWITCH (
        TRUE(),
        Mode = "Day", MaxDate - (N - 1),
        Mode = "Month", EOMONTH(MaxDate, -N + 1) + 1,
        MaxDate - N
    )
RETURN
CALCULATE (
    COUNT ( 'Distribution Status'[ID_Distribution] ),
    FILTER (
        ALL ( 'Distribution Status'[Send_DateOnly] ),
        'Distribution Status'[Send_DateOnly] >= StartDate
            && 'Distribution Status'[Send_DateOnly] <= MaxDate
    ),
    KEEPFILTERS (
        'Distribution Status'[Distribution_Sending_Status] IN { "VISITED" }
    ),
    KEEPFILTERS ( 'Distribution'[Communication_channel] = "sms" ),
    REMOVEFILTERS ( 'Calendar' ),
    REMOVEFILTERS ( 'PeriodsFilter' )
)

Logika obliczeń

Miara oblicza liczbę wiadomości SMS, w których odbiorcy odwiedzili link w wybranym okresie dynamicznym. Jest używana na wykresie trendów do prezentacji aktywności odwiedzin linków SMS w czasie.