Logika obliczania KPI na pulpicie Telegram – Proxima Research Poland

Panel Telegram wyświetla karty KPI, wykresy oraz szczegółowe metryki tabelaryczne dotyczące wydajności komunikacji Telegram.

Planowane
Wysłane
Wysłane %
Dostarczone
Dostarczone %
Przeczytane
Przeczytane %
Odwiedzone
Odwiedzone %
Wypisani
Wypisani %
Niedostarczone
Niedostarczone %
Niewysłane
Niewysłane %
Telegram Dostarczone Dynamiczne
Telegram Przeczytane Dynamiczne
Telegram Niedostarczone Dynamiczne
Telegram Odwiedzone Dynamiczne

Planowane

Pokazuje łączną liczbę wiadomości Telegram zaplanowanych do wysłania w wybranym okresie raportowania.

Formuła DAX

Telegram Planned =
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]), 
    'Distribution'[Communication_channel] = "telegram"
)

Logika obliczeń

Miara zlicza wszystkie rekordy dystrybucji, w których kanałem komunikacji jest telegram. Reprezentuje łączną liczbę zaplanowanych wiadomości Telegram dla wybranego okresu i filtrów.

Wysłane

Pokazuje liczbę wiadomości Telegram, które rozpoczęły proces wysyłki.

Formuła DAX

Telegram Sent =
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]), 
    FILTER(
        'Distribution Status',
        'Distribution Status'[Distribution_Sending_Status] IN {
            "DELIVERED", "BOUNCED", "DECLINED", "DEFERRED", "EXPIRED",
            "FAILED", "OLD", "REJECTED", "UNDELIVERABLE", "UNDELIVERED",
            "UNKNOWN", "ENQUEUED", "QUEUED", "SENT", "VISITED", "READ", "SEEN"
        }
        && RELATED('Distribution'[Communication_channel]) = "telegram"
    )
)

Logika obliczeń

Miara zlicza wiadomości Telegram o statusach wskazujących, że wiadomość rozpoczęła proces wysyłki. Obejmuje to wiadomości przetworzone pomyślnie oraz te z nieudanymi statusami dostarczenia.

Wysłane %

Pokazuje procent zaplanowanych wiadomości Telegram, które zostały wysłane.

Formuła DAX

Telegram Sent % =
[Telegram Sent] / [Telegram Planned]

Logika obliczeń

Miara dzieli liczbę wysłanych wiadomości Telegram przez liczbę zaplanowanych wiadomości Telegram.

Dostarczone

Pokazuje liczbę wiadomości Telegram, które zostały pomyślnie dostarczone odbiorcom.

Formuła DAX

Telegram Delivered =
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]), 
    FILTER(
        'Distribution Status',
        'Distribution Status'[Distribution_Sending_Status] IN {
            "DELIVERED", "READ", "VISITED", "SEEN"
        }
        && RELATED('Distribution'[Communication_channel]) = "telegram"
    )
)

Logika obliczeń

Miara zlicza wiadomości Telegram o statusach związanych z dostarczeniem. Statusy takie jak READ, VISITED i SEEN są uwzględnione, ponieważ te działania mogą wystąpić tylko po pomyślnym dostarczeniu.

Dostarczone %

Pokazuje procent wysłanych wiadomości Telegram, które zostały pomyślnie dostarczone.

Formuła DAX

Telegram Delivered % =
[Telegram Delivered] / [Telegram Sent]

Logika obliczeń

Miara dzieli liczbę dostarczonych wiadomości Telegram przez liczbę wysłanych wiadomości Telegram.

Przeczytane

Pokazuje liczbę wiadomości Telegram przeczytanych lub obejrzanych przez odbiorców.

Formuła DAX

Telegram Read =
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]), 
    FILTER(
        'Distribution Status',
        'Distribution Status'[Distribution_Sending_Status] IN {
            "READ", "VISITED", "SEEN"
        }
        && RELATED('Distribution'[Communication_channel]) = "telegram"
    )
)

Logika obliczeń

Miara zlicza wiadomości Telegram o statusach wskazujących na aktywność odbiorcy, taką jak czytanie lub oglądanie. Wiadomości ze statusem VISITED są również uwzględnione, ponieważ odwiedziny linków następują po zaangażowaniu odbiorcy.

Przeczytane %

Pokazuje procent dostarczonych wiadomości Telegram, które zostały przeczytane przez odbiorców.

Formuła DAX

Telegram Read % =
[Telegram Read] / [Telegram Delivered]

Logika obliczeń

Miara dzieli liczbę przeczytanych wiadomości Telegram przez liczbę dostarczonych wiadomości Telegram.

Odwiedzone

Pokazuje liczbę wiadomości Telegram, w których odbiorcy odwiedzili link.

Formuła DAX

Telegram Visited =
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]), 
    FILTER(
        'Distribution Status',
        'Distribution Status'[Distribution_Sending_Status] IN {
            "VISITED"
        }
        && RELATED('Distribution'[Communication_channel]) = "telegram"
    )
)

Logika obliczeń

Miara zlicza wiadomości Telegram o statusie VISITED. Pokazuje, ile komunikatów Telegram wygenerowało interakcję z linkiem.

Odwiedzone %

Pokazuje procent przeczytanych wiadomości Telegram, które spowodowały odwiedzenie linku.

Formuła DAX

Telegram Visited % =
[Telegram Visited] / [Telegram Read]

Logika obliczeń

Miara dzieli liczbę wiadomości Telegram z odwiedzinami linków przez liczbę przeczytanych wiadomości Telegram.

Wypisani

Pokazuje liczbę odbiorców, którzy wypisali się z komunikacji Telegram.

Formuła DAX

Telegram Unsubscribed =
CALCULATE(
    COUNT('Unsubscribed'[ID_Unsubscribed]), 
    'Distribution'[Communication_channel] = "telegram"
)

Logika obliczeń

Miara zlicza rekordy wypisania dla kanału komunikacji telegram.

Wypisani %

Pokazuje procent dostarczonych wiadomości Telegram, które spowodowały akcję wypisania.

Formuła DAX

Telegram Unsubscribed % =
[Telegram Unsubscribed] / [Telegram Delivered]

Logika obliczeń

Miara dzieli liczbę rekordów wypisania z Telegram przez liczbę dostarczonych wiadomości Telegram.

Niedostarczone

Pokazuje liczbę wysłanych wiadomości Telegram, które nie zostały dostarczone.

Formuła DAX

Telegram Undelivered =
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]), 
    FILTER(
        'Distribution Status',
        'Distribution Status'[Distribution_Sending_Status] IN {
            "UNDELIVERED", "UNDELIVERABLE",
            "RESENDING_SMS_UNDELIVERED",
            "RESENDING_SMS_UNDELIVERABLE",
            "EXPIRED", "OLD", "BOUNCED",
            "DEFERRED", "UNKNOWN"
        }
        && RELATED('Distribution'[Communication_channel]) = "telegram"
    )
)

Logika obliczeń

Miara zlicza wiadomości Telegram o statusach wskazujących na niepowodzenie dostarczenia.

Niedostarczone %

Pokazuje procent wysłanych wiadomości Telegram, które nie zostały dostarczone.

Formuła DAX

Telegram Undelivered % =
[Telegram Undelivered] / [Telegram Sent]

Logika obliczeń

Miara dzieli liczbę niedostarczonych wiadomości Telegram przez liczbę wysłanych wiadomości Telegram.

Niewysłane

Pokazuje liczbę zaplanowanych wiadomości Telegram, które nie zostały wysłane.

Formuła DAX

Telegram Unsent =
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]), 
    FILTER(
        'Distribution Status',
        'Distribution Status'[Distribution_Sending_Status] IN {
            "DUPLICATE", "INVALID_EMAIL", "EMPTY_RECIPIENT",
            "EMPTY_CONTENT", "MESSAGE_LIMIT", "EXCLUDED",
            "UNSUBSCRIBED", "FAILED", "DECLINED", "UNVERIFIED"
        }
        && RELATED('Distribution'[Communication_channel]) = "telegram"
    )
)

Logika obliczeń

Miara zlicza zaplanowane wiadomości Telegram, które nie zostały wysłane z powodu ograniczeń, duplikatów, brakujących danych odbiorcy, niepowodzenia przetwarzania, statusu wypisania lub innych problemów z wysyłką.

Niewysłane %

Pokazuje procent zaplanowanych wiadomości Telegram, które nie zostały wysłane.

Formuła DAX

Telegram Unsent % =
[Telegram Unsent] / [Telegram Planned]

Logika obliczeń

Miara dzieli liczbę niewysłanych wiadomości Telegram przez liczbę zaplanowanych wiadomości Telegram.

Telegram Dostarczone Dynamiczne

Pokazuje liczbę dostarczonych wiadomości Telegram w czasie dla wybranego okresu dynamicznego.

Formuła DAX

Telegram Delivered Dynamic =
VAR N = [DaysToShow Telegram]
VAR MaxDate =
    CALCULATE (
        MAX ( 'Distribution Status'[Send_DateOnly] ),
        ALL ( 'Distribution Status' )
    )
VAR Mode = SELECTEDVALUE(PeriodMode[Mode], "Day")
VAR StartDate_Day = MaxDate - (N - 1)
VAR StartDate_Month =
    DATE(
        YEAR ( EOMONTH ( MaxDate, -N + 1 ) ),
        MONTH( EOMONTH ( MaxDate, -N + 1 ) ),
        1
    )
VAR StartDate = IF(Mode = "Month", StartDate_Month, StartDate_Day)
RETURN
CALCULATE (
    COUNT ( 'Distribution Status'[ID_Distribution] ),
    FILTER (
        ALL ( 'Distribution Status'[Send_DateOnly] ),
        'Distribution Status'[Send_DateOnly] >= StartDate
            && 'Distribution Status'[Send_DateOnly] <= MaxDate
    ),
    KEEPFILTERS (
        'Distribution Status'[Distribution_Sending_Status] IN {
            "DELIVERED", "READ", "VISITED", "SEEN"
        }
    ),
    KEEPFILTERS ( 'Distribution'[Communication_channel] = "telegram" ),
    REMOVEFILTERS ( 'Calendar' ),
    REMOVEFILTERS ( 'PeriodsFilter' )
)

Logika obliczeń

Miara oblicza liczbę dostarczonych wiadomości Telegram dla wybranego okresu dynamicznego. Używa DaysToShow Telegram oraz wybranego trybu okresu, takiego jak Dzień lub Miesiąc, aby określić wyświetlany zakres dat.

Telegram Przeczytane Dynamiczne

Pokazuje liczbę przeczytanych wiadomości Telegram w czasie dla wybranego okresu dynamicznego.

Formuła DAX

Telegram Read Dynamic =
VAR N = [DaysToShow Telegram]
VAR MaxDate =
    CALCULATE (
        MAX ( 'Distribution Status'[Send_DateOnly] ),
        ALL ( 'Distribution Status' )
    )
VAR Mode = SELECTEDVALUE(PeriodMode[Mode], "Day")
VAR StartDate_Day = MaxDate - (N - 1)
VAR StartDate_Month =
    DATE(
        YEAR ( EOMONTH ( MaxDate, -N + 1 ) ),
        MONTH( EOMONTH ( MaxDate, -N + 1 ) ),
        1
    )
VAR StartDate = IF(Mode = "Month", StartDate_Month, StartDate_Day)
RETURN
CALCULATE (
    COUNT ( 'Distribution Status'[ID_Distribution] ),
    FILTER (
        ALL ( 'Distribution Status'[Send_DateOnly] ),
        'Distribution Status'[Send_DateOnly] >= StartDate
            && 'Distribution Status'[Send_DateOnly] <= MaxDate
    ),
    KEEPFILTERS (
        'Distribution Status'[Distribution_Sending_Status] IN {
            "READ", "VISITED", "SEEN"
        }
    ),
    KEEPFILTERS ( 'Distribution'[Communication_channel] = "telegram" ),
    REMOVEFILTERS ( 'Calendar' ),
    REMOVEFILTERS ( 'PeriodsFilter' )
)

Logika obliczeń

Miara oblicza liczbę wiadomości Telegram przeczytanych przez odbiorców w wybranym okresie dynamicznym. Jest używana na wykresie Trendy dostarczania i zaangażowania wiadomości.

Telegram Niedostarczone Dynamiczne

Pokazuje liczbę niedostarczonych wiadomości Telegram w czasie dla wybranego okresu dynamicznego.

Formuła DAX

Telegram Undelivred Dynamic =
VAR N = [DaysToShow Telegram]
VAR MaxDate =
    CALCULATE (
        MAX ( 'Distribution Status'[Send_DateOnly] ),
        ALL ( 'Distribution Status' )
    )
VAR Mode = SELECTEDVALUE(PeriodMode[Mode], "Day")
VAR StartDate =
    SWITCH (
        TRUE(),
        Mode = "Day", MaxDate - (N - 1),
        Mode = "Month", EOMONTH(MaxDate, -N + 1) + 1,
        MaxDate - N
    )
RETURN
CALCULATE (
    COUNT ( 'Distribution Status'[ID_Distribution] ),
    FILTER (
        ALL ( 'Distribution Status'[Send_DateOnly] ),
        'Distribution Status'[Send_DateOnly] >= StartDate
            && 'Distribution Status'[Send_DateOnly] <= MaxDate
    ),
    KEEPFILTERS (
        'Distribution Status'[Distribution_Sending_Status] IN {
            "UNDELIVERED", "UNDELIVERABLE",
            "RESENDING_SMS_UNDELIVERED",
            "RESENDING_SMS_UNDELIVERABLE",
            "EXPIRED", "OLD", "BOUNCED",
            "DEFERRED", "UNKNOWN"
        }
    ),
    KEEPFILTERS ( 'Distribution'[Communication_channel] = "telegram" ),
    REMOVEFILTERS ( 'Calendar' ),
    REMOVEFILTERS ( 'PeriodsFilter' )
)

Logika obliczeń

Miara oblicza liczbę niedostarczonych wiadomości Telegram w wybranym okresie dynamicznym. Służy do pokazania dynamiki niepowodzeń dostarczenia w czasie.

Telegram Odwiedzone Dynamiczne

Pokazuje liczbę wiadomości Telegram z odwiedzinami linków w czasie dla wybranego okresu dynamicznego.

Formuła DAX

Telegram Visited Dynamic =
VAR N = [DaysToShow Telegram]
VAR MaxDate =
    CALCULATE (
        MAX ( 'Distribution Status'[Send_DateOnly] ),
        ALL ( 'Distribution Status' )
    )
VAR Mode = SELECTEDVALUE(PeriodMode[Mode], "Day")
VAR StartDate =
    SWITCH (
        TRUE(),
        Mode = "Day", MaxDate - (N - 1),
        Mode = "Month", EOMONTH(MaxDate, -N + 1) + 1,
        MaxDate - N
    )
RETURN
CALCULATE (
    COUNT ( 'Distribution Status'[ID_Distribution] ),
    FILTER (
        ALL ( 'Distribution Status'[Send_DateOnly] ),
        'Distribution Status'[Send_DateOnly] >= StartDate
            && 'Distribution Status'[Send_DateOnly] <= MaxDate
    ),
    KEEPFILTERS (
        'Distribution Status'[Distribution_Sending_Status] IN {
            "VISITED"
        }
    ),
    KEEPFILTERS ( 'Distribution'[Communication_channel] = "telegram" ),
    REMOVEFILTERS ( 'Calendar' ),
    REMOVEFILTERS ( 'PeriodsFilter' )
)

Logika obliczeń

Miara oblicza liczbę wiadomości Telegram, w których odbiorcy odwiedzili link w wybranym okresie dynamicznym. Jest używana na wykresie trendów do pokazania aktywności odwiedzin linków Telegram w czasie.

Szukaj

Planowane

Wysłane

Wysłane %

Dostarczone

Dostarczone %

Przeczytane

Przeczytane %

Odwiedzone

Odwiedzone %

Wypisani

Wypisani %

Niedostarczone

Niedostarczone %

Niewysłane

Niewysłane %

Telegram Dostarczone Dynamiczne

Telegram Przeczytane Dynamiczne

Telegram Niedostarczone Dynamiczne

Telegram Odwiedzone Dynamiczne