Ana içeriğe geç

Ara

WhatsApp Dashboard - KPI Hesaplama Mantığı

kpiwhatsapp1.jpg

WhatsApp dashboardu, WhatsApp iletişim performansı için KPI kartlarını, grafikleri ve ayrıntılı tablo metriklerini gösterir.

Planned

KPI Açıklaması

Seçilen raporlama dönemi için planlanan WhatsApp iletişimlerinin toplam sayısını gösterir.

DAX Formülü

CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]),
    'Distribution'[Communication_channel] = "whatsapp"
)

Hesaplama Mantığı

İletişim kanalı whatsapp olan tüm dağıtım kayıtlarını sayar.

Sent

KPI Açıklaması

Gönderilen veya gönderimle ilgili herhangi bir duruma ulaşan WhatsApp mesajlarının sayısını gösterir.

DAX Formülü

CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]),
    FILTER(
        'Distribution Status',
        'Distribution Status'[Distribution_Sending_Status] IN {
            "DELIVERED", "BOUNCED", "DECLINED", "DEFERRED", "EXPIRED",
            "FAILED", "OLD", "REJECTED", "UNDELIVERABLE", "UNDELIVERED",
            "UNKNOWN", "ENQUEUED", "QUEUED", "SENT", "VISITED", "READ", "SEEN"
        }
        && RELATED('Distribution'[Communication_channel]) = "whatsapp"
    )
)

Hesaplama Mantığı

SENT, DELIVERED, READ, VISITED, BOUNCED, FAILED, REJECTED, UNDELIVERED, UNKNOWN ve diğer teknik gönderim durumlarına sahip WhatsApp kayıtlarını sayar.

Sent, %

KPI Açıklaması

Planlanan WhatsApp mesajlarının yüzde kaçının gönderildiğini gösterir.

DAX Formülü

Whatsapp Sent % =
[Whatsapp Sent] / [Whatsapp Planned]

Hesaplama Mantığı

Gönderilen WhatsApp mesajı sayısını planlanan WhatsApp mesajı sayısına böler.

Delivered

KPI Açıklaması

Alıcılara teslim edilen gönderilmiş WhatsApp mesajlarının sayısını gösterir.

DAX Formülü

Whatsapp Delivered =
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]),
    FILTER(
        'Distribution Status',
        'Distribution Status'[Distribution_Sending_Status] IN {
            "DELIVERED", "READ", "VISITED", "SEEN"
        }
        && RELATED('Distribution'[Communication_channel]) = "whatsapp"
    )
)

Hesaplama Mantığı

Teslimat aşamasına ulaşan WhatsApp mesajlarını sayar. READ, VISITED veya SEEN gibi sonraki engagement durumlarına sahip mesajlar da teslim edilmiş olarak sayılır.

Delivered, %

KPI Açıklaması

Gönderilen WhatsApp mesajlarının yüzde kaçının alıcılara teslim edildiğini gösterir.

DAX Formülü

Whatsapp Delivered % =
[Whatsapp Delivered] / [Whatsapp Sent]

Hesaplama Mantığı

Teslim edilen WhatsApp mesajı sayısını gönderilen WhatsApp mesajı sayısına böler.

Read

KPI Açıklaması

Alıcılar tarafından okunan teslim edilmiş WhatsApp mesajlarının sayısını gösterir.

DAX Formülü

CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]),
    FILTER(
        'Distribution Status',
        'Distribution Status'[Distribution_Sending_Status] IN {
            "READ", "VISITED", "SEEN"
        }
        && RELATED('Distribution'[Communication_channel]) = "whatsapp"
    )
)

Hesaplama Mantığı

Teslim edildikten sonra okunan veya ek engagement alan WhatsApp mesajlarını sayar.

Read, %

KPI Açıklaması

Teslim edilen WhatsApp mesajlarının yüzde kaçının alıcılar tarafından okunduğunu gösterir.

DAX Formülü

[Whatsapp Read] / [Whatsapp Delivered]

Hesaplama Mantığı

Okunan WhatsApp mesajı sayısını teslim edilen WhatsApp mesajı sayısına böler.

Visited

KPI Açıklaması

Alıcıların bağlantıyı ziyaret ettiği WhatsApp mesajlarının sayısını gösterir.

DAX Formülü

CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]),
    FILTER(
        'Distribution Status',
        'Distribution Status'[Distribution_Sending_Status] IN {
            "VISITED"
        }
        && RELATED('Distribution'[Communication_channel]) = "whatsapp"
    )
)

Hesaplama Mantığı

VISITED durumuna sahip WhatsApp kayıtlarını sayar. Bu, alıcının WhatsApp mesajındaki bağlantıyı ziyaret ettiği anlamına gelir.

Visited, %

KPI Açıklaması

Okunan WhatsApp mesajlarının yüzde kaçının bağlantı ziyaretiyle sonuçlandığını gösterir.

DAX Formülü

[Whatsapp Visited] / [Whatsapp Read]

Hesaplama Mantığı

Bağlantı ziyareti olan WhatsApp mesajı sayısını okunan WhatsApp mesajı sayısına böler.

Unsubscribed

KPI Açıklaması

WhatsApp iletişimlerinden abonelikten çıkan alıcıların sayısını gösterir.

DAX Formülü

CALCULATE(
    COUNT('Unsubscribed'[ID_Unsubscribed]),
    'Distribution'[Communication_channel] = "whatsapp"
)

Hesaplama Mantığı

İletişim kanalı whatsapp olan abonelikten çıkma kayıtlarını sayar.

Unsubscribed, %

KPI Açıklaması

Teslim edilen WhatsApp mesajlarının yüzde kaçının abonelikten çıkma işlemiyle sonuçlandığını gösterir.

DAX Formülü

[Whatsapp Unsubscribed] / [Whatsapp Delivered]

Hesaplama Mantığı

Abonelikten çıkan alıcı sayısını teslim edilen WhatsApp mesajı sayısına böler.

Undelivered

KPI Açıklaması

Alıcılara teslim edilmeyen ve belirli bir teslim edilmeme nedeni bulunan gönderilmiş WhatsApp mesajlarının sayısını gösterir.

DAX Formülü

CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]),
    FILTER(
        'Distribution Status',
        'Distribution Status'[Distribution_Sending_Status] IN {
            "UNDELIVERED", "UNDELIVERABLE",
            "RESENDING_SMS_UNDELIVERED",
            "RESENDING_SMS_UNDELIVERABLE",
            "EXPIRED", "OLD", "BOUNCED",
            "DEFERRED", "UNKNOWN"
        }
        && RELATED('Distribution'[Communication_channel]) = "whatsapp"
        && TRIM('Distribution Status'[Reason_Undelivered_Whatsapp]) <> ""
        && 'Distribution Status'[Reason_Undelivered_Whatsapp] <> "Пусто"
        && NOT ISBLANK('Distribution Status'[Reason_Undelivered_Whatsapp])
    )
)

Hesaplama Mantığı

Teslim edilmeyen teslimat durumlarına ve boş olmayan teslim edilmeme nedenine sahip WhatsApp kayıtlarını sayar. Bu KPI, gönderilen ancak alıcılara ulaşmayan mesajları belirlemeye yardımcı olur.

Undelivered, %

KPI Açıklaması

Gönderilen WhatsApp mesajlarının yüzde kaçının teslim edilmediğini gösterir.

DAX Formülü

[Whatsapp Undelivered] / [Whatsapp Sent]

Hesaplama Mantığı

Teslim edilmeyen WhatsApp mesajı sayısını gönderilen WhatsApp mesajı sayısına böler.

Unsent

KPI Açıklaması

Gönderilmeyen planlanmış WhatsApp mesajlarının sayısını gösterir.

DAX Formülü

CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]),
    FILTER(
        'Distribution Status',
        'Distribution Status'[Distribution_Sending_Status] IN {
            "DUPLICATE", "INVALID_EMAIL", "EMPTY_RECIPIENT",
            "EMPTY_CONTENT", "MESSAGE_LIMIT", "EXCLUDED",
            "UNSUBSCRIBED", "FAILED", "DECLINED", "UNVERIFIED"
        }
        && RELATED('Distribution'[Communication_channel]) = "whatsapp"
    )
)

Hesaplama Mantığı

Veri, yapılandırma, alıcı, içerik, limit veya doğrulama sorunları nedeniyle gönderilmeyen planlanmış WhatsApp kayıtlarını sayar.

Unsent, %

KPI Açıklaması

Planlanan WhatsApp mesajlarının yüzde kaçının gönderilmediğini gösterir.

DAX Formülü

[Whatsapp Unsent] / [Whatsapp Planned]

Hesaplama Mantığı

Gönderilmeyen WhatsApp mesajı sayısını planlanan WhatsApp mesajı sayısına böler.

Reason Undelivered

KPI Açıklaması

Teslim edilmeme nedeni bulunan WhatsApp kayıtlarının sayısını gösterir. Bu ölçüm, WhatsApp mesajlarının neden teslim edilmediğini analiz etmek için Reasons for undelivered messages grafiğinde kullanılır.

DAX Formülü

CALCULATE(
    COUNT('Distribution Status'[Reason_Undelivered_Emails_Flag]),
    'Distribution'[Communication_channel] = "whatsapp"
)

Hesaplama Mantığı

whatsapp iletişim kanalı için teslim edilmeme nedeni bayrağı bulunan kayıtları sayar.

WhatsApp Devices

KPI Açıklaması

WhatsApp iletişimleri için cihaza göre bağlantı ziyareti kayıtlarının sayısını gösterir. Bu ölçüm Type of devices from which the link was visited grafiğinde kullanılır.

DAX Formülü

CALCULATE(
    COUNT('Devices'[ID_Linkstats]),
    'Distribution'[Communication_channel] = "whatsapp"
)

Hesaplama Mantığı

İletişim kanalı whatsapp olan Devices tablosundaki kayıtları sayar.

WhatsApp Delivered to Read

KPI Açıklaması

Teslimattan okumaya kadar geçen süresi mevcut olan WhatsApp mesajlarının sayısını gösterir. Bu ölçüm Delivered vs Read görselleştirmesinde kullanılır.

DAX Formülü

CALCULATE(
    COUNT('Distribution Status'[Time from delivered to read]),
    'Distribution'[Communication_channel] = "whatsapp"
)

Hesaplama Mantığı

Time from delivered to read alanında değer bulunan WhatsApp kayıtlarını sayar.

WhatsApp AVG Delivered to Read

KPI Açıklaması

WhatsApp mesajının teslim edilmesi ile okunması arasındaki ortalama süreyi gösterir. Sonuç HH:MM:SS formatında gösterilir.

DAX Formülü

VAR TotalSeconds =
    AVERAGEX(
        FILTER(
            'Distribution Status',
            CALCULATE(
                COUNT('Distribution'[ID_Distribution]),
                'Distribution'[Communication_channel] = "whatsapp"
            ) > 0
            && NOT(ISBLANK('Distribution Status'[Difference in seconds 1]))
        ),
        'Distribution Status'[Difference in seconds 1]
    )
VAR Hours = INT(TotalSeconds / 3600)
VAR Minutes = INT(MOD(TotalSeconds, 3600) / 60)
VAR Seconds = MOD(TotalSeconds, 60)
RETURN
    FORMAT(Hours, "00") & ":" &
    FORMAT(Minutes, "00") & ":" &
    FORMAT(Seconds, "00")

Hesaplama Mantığı

WhatsApp kayıtları için Difference in seconds 1 ortalama değerini hesaplar, ardından sonucu saat, dakika ve saniyeye dönüştürür.

WhatsApp Delivered to Visited

KPI Açıklaması

Teslimattan bağlantı ziyaretine kadar geçen süresi mevcut olan WhatsApp mesajlarının sayısını gösterir. Bu ölçüm Delivered vs Visited görselleştirmesinde kullanılır.

DAX Formülü

CALCULATE(
    COUNT('Distribution Status'[Time from delivered to visited]),
    'Distribution'[Communication_channel] = "whatsapp"
)

Hesaplama Mantığı

Time from delivered to visited alanında değer bulunan WhatsApp kayıtlarını sayar.

WhatsApp AVG Delivered to Visited

KPI Açıklaması

WhatsApp mesajının teslim edilmesi ile bağlantı ziyareti arasındaki ortalama süreyi gösterir. Sonuç HH:MM:SS formatında gösterilir.

DAX Formülü

VAR TotalSeconds =
    AVERAGEX(
        FILTER(
            'Distribution Status',
            CALCULATE(
                COUNT('Distribution'[ID_Distribution]),
                'Distribution'[Communication_channel] = "whatsapp"
            ) > 0
            && NOT(ISBLANK('Distribution Status'[Difference in seconds 2]))
        ),
        'Distribution Status'[Difference in seconds 2]
    )
VAR Hours = INT(TotalSeconds / 3600)
VAR Minutes = INT(MOD(TotalSeconds, 3600) / 60)
VAR Seconds = MOD(TotalSeconds, 60)
RETURN
    FORMAT(Hours, "00") & ":" &
    FORMAT(Minutes, "00") & ":" &
    FORMAT(Seconds, "00")

Hesaplama Mantığı

WhatsApp kayıtları için Difference in seconds 2 ortalama değerini hesaplar, ardından sonucu saat, dakika ve saniyeye dönüştürür.

WhatsApp Delivered Dynamic

KPI Açıklaması

Message Delivery & Engagement Trends grafiğinde seçilen gün veya ay aralığı için teslim edilen WhatsApp mesajlarının sayısını gösterir.

DAX Formülü

VAR N = [DaysToShow Whatsapp]
VAR MaxDate =
    CALCULATE(
        MAX('Distribution Status'[Send_DateOnly]),
        ALL('Distribution Status')
    )
VAR Mode = SELECTEDVALUE(PeriodMode[Mode], "Day")

VAR StartDate_Day = MaxDate - (N - 1)
VAR StartDate_Month =
    DATE(
        YEAR(EOMONTH(MaxDate, -N + 1)),
        MONTH(EOMONTH(MaxDate, -N + 1)),
        1
    )

VAR StartDate = IF(Mode = "Month", StartDate_Month, StartDate_Day)

RETURN
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]),
    FILTER(
        ALL('Distribution Status'[Send_DateOnly]),
        'Distribution Status'[Send_DateOnly] >= StartDate
            && 'Distribution Status'[Send_DateOnly] <= MaxDate
    ),
    KEEPFILTERS(
        'Distribution Status'[Distribution_Sending_Status] IN {
            "DELIVERED", "READ", "VISITED", "SEEN"
        }
    ),
    KEEPFILTERS('Distribution'[Communication_channel] = "whatsapp"),
    REMOVEFILTERS('Calendar'),
    REMOVEFILTERS('PeriodsFilter')
)

Hesaplama Mantığı

Seçilen dinamik tarih aralığında teslim edilen WhatsApp mesajlarını hesaplar. Aralık, seçilen dönem moduna bağlıdır: Day veya Month.

WhatsApp Read Dynamic

KPI Açıklaması

Message Delivery & Engagement Trends grafiğinde seçilen gün veya ay aralığı için okunan WhatsApp mesajlarının sayısını gösterir.

DAX Formülü

VAR N = [DaysToShow whatsapp]
VAR MaxDate =
    CALCULATE(
        MAX('Distribution Status'[Send_DateOnly]),
        ALL('Distribution Status')
    )
VAR Mode = SELECTEDVALUE(PeriodMode[Mode], "Day")

VAR StartDate_Day = MaxDate - (N - 1)
VAR StartDate_Month =
    DATE(
        YEAR(EOMONTH(MaxDate, -N + 1)),
        MONTH(EOMONTH(MaxDate, -N + 1)),
        1
    )

VAR StartDate = IF(Mode = "Month", StartDate_Month, StartDate_Day)

RETURN
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]),
    FILTER(
        ALL('Distribution Status'[Send_DateOnly]),
        'Distribution Status'[Send_DateOnly] >= StartDate
            && 'Distribution Status'[Send_DateOnly] <= MaxDate
    ),
    KEEPFILTERS(
        'Distribution Status'[Distribution_Sending_Status] IN {
            "READ", "VISITED", "SEEN"
        }
    ),
    KEEPFILTERS('Distribution'[Communication_channel] = "whatsapp"),
    REMOVEFILTERS('Calendar'),
    REMOVEFILTERS('PeriodsFilter')
)

Hesaplama Mantığı

Seçilen dinamik tarih aralığında okunan WhatsApp mesajlarını hesaplar. VISITED veya SEEN gibi sonraki engagement durumlarına sahip mesajlar da dahil edilir.

WhatsApp Visited Dynamic

KPI Açıklaması

Message Delivery & Engagement Trends grafiğinde seçilen gün veya ay aralığı için bağlantı ziyareti olan WhatsApp mesajlarının sayısını gösterir.

DAX Formülü

VAR N = [DaysToShow Whatsapp]
VAR MaxDate =
    CALCULATE(
        MAX('Distribution Status'[Send_DateOnly]),
        ALL('Distribution Status')
    )
VAR Mode = SELECTEDVALUE(PeriodMode[Mode], "Day")
VAR StartDate =
    SWITCH(
        TRUE(),
        Mode = "Day", MaxDate - (N - 1),
        Mode = "Month", EOMONTH(MaxDate, -N + 1) + 1,
        MaxDate - N
    )
RETURN
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]),
    FILTER(
        ALL('Distribution Status'[Send_DateOnly]),
        'Distribution Status'[Send_DateOnly] >= StartDate
            && 'Distribution Status'[Send_DateOnly] <= MaxDate
    ),
    KEEPFILTERS(
        'Distribution Status'[Distribution_Sending_Status] IN {
            "VISITED"
        }
    ),
    KEEPFILTERS('Distribution'[Communication_channel] = "whatsapp"),
    REMOVEFILTERS('Calendar'),
    REMOVEFILTERS('PeriodsFilter')
)

Hesaplama Mantığı

Seçilen dinamik tarih aralığında WhatsApp bağlantı ziyaretlerini hesaplar.

WhatsApp Undelivered Dynamic

KPI Açıklaması

Message Delivery & Engagement Trends grafiğinde seçilen gün veya ay aralığı için teslim edilmeyen WhatsApp mesajlarının sayısını gösterir.

DAX Formülü

VAR N = [DaysToShow Whatsapp]
VAR MaxDate =
    CALCULATE(
        MAX('Distribution Status'[Send_DateOnly]),
        ALL('Distribution Status')
    )
VAR Mode = SELECTEDVALUE(PeriodMode[Mode], "Day")
VAR StartDate =
    SWITCH(
        TRUE(),
        Mode = "Day", MaxDate - (N - 1),
        Mode = "Month", EOMONTH(MaxDate, -N + 1) + 1,
        MaxDate - N
    )
RETURN
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]),
    FILTER(
        ALL('Distribution Status'[Send_DateOnly]),
        'Distribution Status'[Send_DateOnly] >= StartDate
            && 'Distribution Status'[Send_DateOnly] <= MaxDate
    ),
    KEEPFILTERS(
        'Distribution Status'[Distribution_Sending_Status] IN {
            "UNDELIVERED", "UNDELIVERABLE",
            "RESENDING_SMS_UNDELIVERED",
            "RESENDING_SMS_UNDELIVERABLE",
            "EXPIRED", "OLD", "BOUNCED",
            "DEFERRED", "UNKNOWN"
        }
    ),
    KEEPFILTERS('Distribution'[Communication_channel] = "whatsapp"),
    REMOVEFILTERS('Calendar'),
    REMOVEFILTERS('PeriodsFilter')
)

Hesaplama Mantığı

Seçilen dinamik tarih aralığında teslim edilmeyen WhatsApp mesajlarını hesaplar. Kaynak dosyada ölçüm adı Whatsapp Undelivred Dynamic olarak yazılmıştır.