Viber Gösterge Paneli KPI Hesaplama Mantığı – Proxima Research Turkey

Viber gösterge paneli, Viber iletişim performansı için KPI kartları, grafikler ve detaylı tablo metrikleri gösterir.

Planlanan
Gönderilen
Gönderilen %
Viber Teslim Edilen
Viber Teslim Edilen %
Viber Okunan
Viber Okunan %
Viber Ziyaret Edilen
Viber Ziyaret Edilen %
Abonelikten Çıkan
Abonelikten Çıkma %
Teslim Edilmeyen
Teslim Edilmeyen %
Gönderilmeyen
Gönderilmeyen %
Viber Teslim Edilen Dinamik
Viber Okunan Dinamik
Viber Teslim Edilmeyen Dinamik
Viber Ziyaret Edilen Dinamik

Viber Planlanan

Seçilen raporlama dönemi boyunca gönderilmesi planlanan toplam Viber mesaj sayısını gösterir.

DAX Formülü

Viber Planned =
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]), 
    'Distribution'[Communication_channel] = "viber"
)

Hesaplama Mantığı

Bu ölçü, iletişim kanalı viber olan tüm dağıtım kayıtlarını sayar.

Seçilen raporlama dönemi ve filtreler için planlanan toplam Viber mesaj sayısını temsil eder.

Viber Gönderilen

Son teslimat sonucu ne olursa olsun, gönderim sürecine giren Viber mesajlarının sayısını gösterir.

DAX Formülü

Viber Sent =
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]), 
    FILTER(
        'Distribution Status',
        'Distribution Status'[Distribution_Sending_Status] IN {
            "DELIVERED", "BOUNCED", "DECLINED", "DEFERRED", "EXPIRED",
            "FAILED", "OLD", "REJECTED", "UNDELIVERABLE", "UNDELIVERED",
            "UNKNOWN", "ENQUEUED", "QUEUED", "SENT", "VISITED", "READ", "SEEN"
        }
        && RELATED('Distribution'[Communication_channel]) = "viber"
    )
)

Hesaplama Mantığı

Bu ölçü, mesajın gönderim sürecine girdiğini gösteren gönderim durumlarına sahip Viber mesajlarını sayar.

Başarılı teslim edilen, okunan, ziyaret edilen veya görülen mesajların yanı sıra, başarısız teslim durumlarına sahip (bounce, failed, rejected, undeliverable, unknown gibi) mesajları da içerir.

Viber Gönderilen %

Planlanan Viber mesajlarının gönderilen yüzdesini gösterir.

DAX Formülü

Viber Sent % =
[Viber Sent] / [Viber Planned]

Hesaplama Mantığı

Planlanan Viber mesajlarının gönderilen kısmının oranını hesaplar.

KPI kart örneğinde, 1.149.942 mesaj, planlanan 1.616.922 mesajdan gönderilmiş olup, bu da %71,12 eder.

Viber Teslim Edilen

Alıcılara başarıyla teslim edilen Viber mesajlarının sayısını gösterir.

DAX Formülü

Viber Delivered =
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]), 
    FILTER(
        'Distribution Status',
        'Distribution Status'[Distribution_Sending_Status] IN {
            "DELIVERED", "READ", "VISITED", "SEEN"
        }
        && RELATED('Distribution'[Communication_channel]) = "viber"
    )
)

Hesaplama Mantığı

Başarıyla alıcılara teslim edilen Viber mesajlarını sayar.

Durumları READ, VISITED ve SEEN olan mesajlar da dahil edilir çünkü bu işlemler yalnızca başarılı teslimattan sonra gerçekleşebilir.

Viber Teslim Edilen %

Gönderilen Viber mesajlarının başarıyla teslim edilen yüzdesini gösterir.

DAX Formülü

Viber Delivered % =
[Viber Delivered] / [Viber Sent]

Hesaplama Mantığı

Gönderilen Viber mesajlarının teslim edilen kısmının oranını hesaplar.

KPI kart örneğinde, 914.006 mesaj, gönderilen 1.149.942 mesajdan teslim edilmiştir ve bu da %79,48 eder.

Viber Okunan

Alıcılar tarafından okunan veya görülen teslim edilen Viber mesajlarının sayısını gösterir.

DAX Formülü

Viber Read =
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]), 
    FILTER(
        'Distribution Status',
        'Distribution Status'[Distribution_Sending_Status] IN {
            "READ", "VISITED", "SEEN"
        }
        && RELATED('Distribution'[Communication_channel]) = "viber"
    )
)

Hesaplama Mantığı

Alıcılar tarafından okunan Viber mesajlarını sayar.

Durumları VISITED ve SEEN olan mesajlar da dahil edilir çünkü bunlar mesaj okunduktan veya görüldükten sonra alıcı etkileşimini gösterir.

Viber Okunan %

Alıcılar tarafından okunan teslim edilen Viber mesajlarının yüzdesini gösterir.

DAX Formülü

Viber Read % =
[Viber Read] / [Viber Delivered]

Hesaplama Mantığı

Teslim edilen Viber mesajlarının alıcılar tarafından okunan kısmının oranını hesaplar.

KPI kart örneğinde, 613.848 mesaj, teslim edilen 914.006 mesajdan okunmuş olup, bu da %67,16 eder.

Viber Ziyaret Edilen

Alıcıların bir bağlantıyı ziyaret etmesiyle sonuçlanan Viber mesajlarının sayısını gösterir.

DAX Formülü

Viber Visited =
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]), 
    FILTER(
        'Distribution Status',
        'Distribution Status'[Distribution_Sending_Status] IN { "VISITED" }
        && RELATED('Distribution'[Communication_channel]) = "viber"
    )
)

Hesaplama Mantığı

Alıcıların mesajdaki bir bağlantıyı ziyaret ettiği Viber mesajlarını sayar.

Kaç Viber iletişiminin bağlantı etkileşimi yarattığını gösterir.

Viber Ziyaret Edilen %

Okunan Viber mesajlarının bağlantı ziyareti oluşturma yüzdesini gösterir.

DAX Formülü

Viber Visited % =
[Viber Visited] / [Viber Read]

Hesaplama Mantığı

Okunan Viber mesajlarının kaçının bağlantı ziyaretine yol açtığını hesaplar.

KPI kart örneğinde, 12.047 mesaj, okunan 613.848 mesajdan bağlantı ziyaretine neden olmuş ve bu da %1,96 eder.

Viber Abonelikten Çıkan

Viber iletişimlerinden aboneliği iptal eden alıcıların sayısını gösterir.

DAX Formülü

Viber Unsubscribed =
CALCULATE(
    COUNT('Unsubscribed'[ID_Unsubscribed]), 
    'Distribution'[Communication_channel] = "viber"
)

Hesaplama Mantığı

viber iletişim kanalı için abonelikten çıkma kayıtlarını sayar.

Seçilen raporlama döneminde kaç alıcının Viber iletişimlerinden aboneliği iptal ettiğini gösterir.

Viber Abonelikten Çıkma %

Teslim edilen Viber mesajlarından kaçının abonelik iptaline yol açtığını gösterir.

DAX Formülü

Viber Unsubscribe % =
[Viber Unsubscribed] / [Viber Delivered]

Hesaplama Mantığı

Teslim edilen Viber mesajlarının kaçının abonelik iptaline neden olduğunu hesaplar.

KPI kart örneğinde, 556 abonelikten çıkma kaydı gösterilir. KPI kartında gösterilen yüzde %0,06’dır.

Viber Teslim Edilmeyen

Gönderilen ancak teslim edilmeyen ve belirtilmiş bir teslim edilmeme nedeni olan Viber mesajlarının sayısını gösterir.

DAX Formülü

Viber Undelivered =
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]),
    FILTER(
        'Distribution Status',
        'Distribution Status'[Distribution_Sending_Status] IN {
            "UNDELIVERED", "UNDELIVERABLE",
            "RESENDING_SMS_UNDELIVERED",
            "RESENDING_SMS_UNDELIVERABLE",
            "EXPIRED", "OLD", "BOUNCED",
            "DEFERRED", "UNKNOWN"
        }
        && RELATED('Distribution'[Communication_channel]) = "viber"
        && TRIM('Distribution Status'[Reason_Undelivered_Viber]) <> ""
        && 'Distribution Status'[Reason_Undelivered_Viber] <> "Пусто"
        && NOT ISBLANK('Distribution Status'[Reason_Undelivered_Viber])
    )
)

Hesaplama Mantığı

Teslim edilmeyen ve teslim edilmeme nedeni belirtilmiş gönderilmiş Viber mesajlarını sayar.

Teslimat başarısızlıklarını analiz etmek ve neden bazında inceleme gerektiren mesajları belirlemek için kullanılır.

Viber Teslim Edilmeyen %

Gönderilen Viber mesajlarından kaçının teslim edilmediğini gösterir.

DAX Formülü

Viber Undelivered % =
[Viber Undelivered] / [Viber Sent]

Hesaplama Mantığı

Gönderilen Viber mesajlarının teslim edilmeyen yüzdesini hesaplar.

Kullanıcıların gönderilen tüm Viber iletişimleri içinde teslimat başarısızlıklarının oranını değerlendirmesine yardımcı olur.

Viber Gönderilmeyen

Planlanan ancak kısıtlamalar, geçersiz veriler, çoğaltmalar, abonelikten çıkma durumu veya diğer gönderim sorunları nedeniyle gönderilmeyen Viber mesajlarının sayısını gösterir.

DAX Formülü

Viber Unsent =
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]), 
    FILTER(
        'Distribution Status',
        'Distribution Status'[Distribution_Sending_Status] IN {
            "DUPLICATE", "INVALID_EMAIL", "EMPTY_RECIPIENT",
            "EMPTY_CONTENT", "MESSAGE_LIMIT", "EXCLUDED",
            "UNSUBSCRIBED", "FAILED", "DECLINED", "UNVERIFIED"
        }
        && RELATED('Distribution'[Communication_channel]) = "viber"
    )
)

Hesaplama Mantığı

Gönderim kısıtlamaları, geçersiz veya eksik alıcı verileri, abonelikten çıkma durumu, çoğaltmalar, başarısız işleme veya diğer sistem koşulları nedeniyle gönderilmeyen planlanan Viber mesajlarını sayar.

Viber Gönderilmeyen %

Planlanan ancak gönderilmeyen Viber mesajlarının yüzdesini gösterir.

DAX Formülü

Viber Unsent % =
[Viber Unsent] / [Viber Planned]

Hesaplama Mantığı

Planlanan ancak gönderilmeyen Viber mesajlarının oranını hesaplar.

Kullanıcıların planlanan Viber iletişimlerinin ne kadarının gönderim sürecine girmediğini değerlendirmesine yardımcı olur.

Viber Teslim Edilen Dinamik

Seçilen dinamik dönem için zaman içinde teslim edilen Viber mesajlarının sayısını gösterir.

DAX Formülü

Viber Delivered Dynamic =
VAR N = [DaysToShow Viber]
VAR MaxDate =
    CALCULATE (
        MAX ( 'Distribution Status'[Send_DateOnly] ),
        ALL ( 'Distribution Status' )
    )
VAR Mode = SELECTEDVALUE(PeriodMode[Mode], "Day")
VAR StartDate_Day = MaxDate - (N - 1)
VAR StartDate_Month =
    DATE(
        YEAR ( EOMONTH ( MaxDate, -N + 1 ) ),
        MONTH( EOMONTH ( MaxDate, -N + 1 ) ),
        1
    )
VAR StartDate = IF(Mode = "Month", StartDate_Month, StartDate_Day)
RETURN
CALCULATE (
    COUNT ( 'Distribution Status'[ID_Distribution] ),
    FILTER (
        ALL ( 'Distribution Status'[Send_DateOnly] ),
        'Distribution Status'[Send_DateOnly] >= StartDate
            && 'Distribution Status'[Send_DateOnly] <= MaxDate
    ),
    KEEPFILTERS (
        'Distribution Status'[Distribution_Sending_Status] IN {
            "DELIVERED", "READ", "VISITED", "SEEN"
        }
    ),
    KEEPFILTERS ( 'Distribution'[Communication_channel] = "viber" ),
    REMOVEFILTERS ( 'Calendar' ),
    REMOVEFILTERS ( 'PeriodsFilter' )
)

Hesaplama Mantığı

Seçilen dinamik dönem için teslim edilen Viber mesajlarının sayısını hesaplar.

DaysToShow Viber değeri ve seçilen dönem modu (örneğin Gün veya Ay) kullanılarak trend grafiğinde gösterilen tarih aralığı belirlenir.

Viber Okunan Dinamik

Seçilen dinamik dönem için zaman içinde okunan Viber mesajlarının sayısını gösterir.

DAX Formülü

Viber Read Dynamic =
VAR N = [DaysToShow Viber]
VAR MaxDate =
    CALCULATE (
        MAX ( 'Distribution Status'[Send_DateOnly] ),
        ALL ( 'Distribution Status' )
    )
VAR Mode = SELECTEDVALUE(PeriodMode[Mode], "Day")
VAR StartDate_Day = MaxDate - (N - 1)
VAR StartDate_Month =
    DATE(
        YEAR ( EOMONTH ( MaxDate, -N + 1 ) ),
        MONTH( EOMONTH ( MaxDate, -N + 1 ) ),
        1
    )
VAR StartDate = IF(Mode = "Month", StartDate_Month, StartDate_Day)
RETURN
CALCULATE (
    COUNT ( 'Distribution Status'[ID_Distribution] ),
    FILTER (
        ALL ( 'Distribution Status'[Send_DateOnly] ),
        'Distribution Status'[Send_DateOnly] >= StartDate
            && 'Distribution Status'[Send_DateOnly] <= MaxDate
    ),
    KEEPFILTERS (
        'Distribution Status'[Distribution_Sending_Status] IN {
            "READ", "VISITED", "SEEN"
        }
    ),
    KEEPFILTERS ( 'Distribution'[Communication_channel] = "viber" ),
    REMOVEFILTERS ( 'Calendar' ),
    REMOVEFILTERS ( 'PeriodsFilter' )
)

Hesaplama Mantığı

Seçilen dinamik dönem için okunan Viber mesajlarının sayısını hesaplar.

Mesaj Teslimi ve Etkileşim Trendleri grafiğinde okuma aktivitesinin zaman içindeki değişimini göstermek için kullanılır.

Viber Teslim Edilmeyen Dinamik

Seçilen dinamik dönem için zaman içinde teslim edilmeyen Viber mesajlarının sayısını gösterir.

DAX Formülü

Viber Undelivred Dynamic =
VAR N = [DaysToShow Viber]
VAR MaxDate =
    CALCULATE (
        MAX ( 'Distribution Status'[Send_DateOnly] ),
        ALL ( 'Distribution Status' )
    )
VAR Mode = SELECTEDVALUE(PeriodMode[Mode], "Day")
VAR StartDate =
    SWITCH (
        TRUE(),
        Mode = "Day", MaxDate - (N - 1),
        Mode = "Month", EOMONTH(MaxDate, -N + 1) + 1,
        MaxDate - N
    )
RETURN
CALCULATE (
    COUNT ( 'Distribution Status'[ID_Distribution] ),
    FILTER (
        ALL ( 'Distribution Status'[Send_DateOnly] ),
        'Distribution Status'[Send_DateOnly] >= StartDate
            && 'Distribution Status'[Send_DateOnly] <= MaxDate
    ),
    KEEPFILTERS (
        'Distribution Status'[Distribution_Sending_Status] IN {
            "UNDELIVERED", "UNDELIVERABLE",
            "RESENDING_SMS_UNDELIVERED",
            "RESENDING_SMS_UNDELIVERABLE",
            "EXPIRED", "OLD", "BOUNCED",
            "DEFERRED", "UNKNOWN"
        }
    ),
    KEEPFILTERS ( 'Distribution'[Communication_channel] = "viber" ),
    REMOVEFILTERS ( 'Calendar' ),
    REMOVEFILTERS ( 'PeriodsFilter' )
)

Hesaplama Mantığı

Seçilen dinamik dönem için teslim edilmeyen Viber mesajlarının sayısını hesaplar.

Teslimat başarısızlığı dinamiklerini zaman içinde göstermek için trend grafiğinde kullanılır.

Viber Ziyaret Edilen Dinamik

Seçilen dinamik dönem için zaman içinde bağlantı ziyaretine sahip Viber mesajlarının sayısını gösterir.

DAX Formülü

Viber Visited Dynamic =
VAR N = [DaysToShow Viber]
VAR MaxDate =
    CALCULATE (
        MAX ( 'Distribution Status'[Send_DateOnly] ),
        ALL ( 'Distribution Status' )
    )
VAR Mode = SELECTEDVALUE(PeriodMode[Mode], "Day")
VAR StartDate =
    SWITCH (
        TRUE(),
        Mode = "Day", MaxDate - (N - 1),
        Mode = "Month", EOMONTH(MaxDate, -N + 1) + 1,
        MaxDate - N
    )
RETURN
CALCULATE (
    COUNT ( 'Distribution Status'[ID_Distribution] ),
    FILTER (
        ALL ( 'Distribution Status'[Send_DateOnly] ),
        'Distribution Status'[Send_DateOnly] >= StartDate
            && 'Distribution Status'[Send_DateOnly] <= MaxDate
    ),
    KEEPFILTERS (
        'Distribution Status'[Distribution_Sending_Status] IN { "VISITED" }
    ),
    KEEPFILTERS ( 'Distribution'[Communication_channel] = "viber" ),
    REMOVEFILTERS ( 'Calendar' ),
    REMOVEFILTERS ( 'PeriodsFilter' )
)

Hesaplama Mantığı

Seçilen dinamik dönem boyunca alıcıların bir bağlantıyı ziyaret ettiği Viber mesajlarının sayısını hesaplar.

Trend grafiğinde Viber bağlantı ziyaret etkinliğinin zaman içindeki değişimini göstermek için kullanılır.

Ara

Viber Planlanan

Viber Gönderilen

Viber Gönderilen %

Viber Teslim Edilen

Viber Teslim Edilen %

Viber Okunan

Viber Okunan %

Viber Ziyaret Edilen

Viber Ziyaret Edilen %

Viber Abonelikten Çıkan

Viber Abonelikten Çıkma %

Viber Teslim Edilmeyen

Viber Teslim Edilmeyen %

Viber Gönderilmeyen

Viber Gönderilmeyen %

Viber Teslim Edilen Dinamik

Viber Okunan Dinamik

Viber Teslim Edilmeyen Dinamik

Viber Ziyaret Edilen Dinamik