Логіка розрахунку KPI на панелі Viber – Proxima Research Ukraine

Панель Viber відображає картки KPI, діаграми та детальні метрики у таблиці для оцінки ефективності комунікацій через Viber.

Заплановано
Відправлено
Відправлено %
Доставлено Viber
Доставлено Viber %
Прочитано Viber
Прочитано Viber %
Відвідано Viber
Відвідано Viber %
Відписано
Відписано %
Недоставлено
Недоставлено %
Не відправлено
Не відправлено %
Динаміка доставки Viber
Динаміка прочитання Viber
Динаміка недоставлення Viber
Динаміка відвідувань Viber

Заплановано Viber

Показує загальну кількість повідомлень Viber, запланованих до відправки за обраний звітний період.

Формула DAX

Viber Planned =
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]), 
    'Distribution'[Communication_channel] = "viber"
)

Логіка розрахунку

Ця міра рахує всі записи розсилки, де канал комунікації — viber.

Вона відображає загальну кількість запланованих повідомлень Viber за вибраний звітний період та застосовані фільтри.

Відправлено Viber

Показує кількість повідомлень Viber, які увійшли в процес відправки, незалежно від кінцевого результату доставки.

Формула DAX

Viber Sent =
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]), 
    FILTER(
        'Distribution Status',
        'Distribution Status'[Distribution_Sending_Status] IN {
            "DELIVERED", "BOUNCED", "DECLINED", "DEFERRED", "EXPIRED",
            "FAILED", "OLD", "REJECTED", "UNDELIVERABLE", "UNDELIVERED",
            "UNKNOWN", "ENQUEUED", "QUEUED", "SENT", "VISITED", "READ", "SEEN"
        }
        && RELATED('Distribution'[Communication_channel]) = "viber"
    )
)

Логіка розрахунку

Ця міра рахує повідомлення Viber зі статусами відправки, які вказують, що повідомлення увійшло у процес відправки.

Враховуються повідомлення, які були успішно доставлені, прочитані, відвідані або переглянуті, а також повідомлення зі статусами невдалої доставки, такими як bounced, failed, rejected, undeliverable або unknown.

Відправлено Viber %

Показує відсоток запланованих повідомлень Viber, які були відправлені.

Формула DAX

Viber Sent % =
[Viber Sent] / [Viber Planned]

Логіка розрахунку

Ця міра обчислює частку запланованих повідомлень Viber, які були відправлені.

У прикладі на картці KPI було відправлено 1 149 942 повідомлень із 1 616 922 запланованих, що становить 71,12%.

Доставлено Viber

Показує кількість повідомлень Viber, які успішно доставлені отримувачам.

Формула DAX

Viber Delivered =
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]), 
    FILTER(
        'Distribution Status',
        'Distribution Status'[Distribution_Sending_Status] IN {
            "DELIVERED", "READ", "VISITED", "SEEN"
        }
        && RELATED('Distribution'[Communication_channel]) = "viber"
    )
)

Логіка розрахунку

Ця міра рахує повідомлення Viber, які були успішно доставлені отримувачам.

Повідомлення зі статусами READ, VISITED та SEEN також включені, оскільки ці дії можуть відбутися лише після успішної доставки.

Доставлено Viber %

Показує відсоток відправлених повідомлень Viber, які були успішно доставлені.

Формула DAX

Viber Delivered % =
[Viber Delivered] / [Viber Sent]

Логіка розрахунку

Ця міра обчислює частку відправлених повідомлень Viber, які були доставлені.

У прикладі на картці KPI було доставлено 914 006 повідомлень із 1 149 942 відправлених, що становить 79,48%.

Прочитано Viber

Показує кількість доставлених повідомлень Viber, які були прочитані або переглянуті отримувачами.

Формула DAX

Viber Read =
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]), 
    FILTER(
        'Distribution Status',
        'Distribution Status'[Distribution_Sending_Status] IN {
            "READ", "VISITED", "SEEN"
        }
        && RELATED('Distribution'[Communication_channel]) = "viber"
    )
)

Логіка розрахунку

Ця міра рахує повідомлення Viber, які були прочитані отримувачами.

Повідомлення зі статусами VISITED і SEEN також включені, оскільки вони свідчать про залучення отримувача після того, як повідомлення було прочитане або переглянуте.

Прочитано Viber %

Показує відсоток доставлених повідомлень Viber, які були прочитані отримувачами.

Формула DAX

Viber Read % =
[Viber Read] / [Viber Delivered]

Логіка розрахунку

Ця міра обчислює частку доставлених повідомлень Viber, які були прочитані отримувачами.

У прикладі на картці KPI було прочитано 613 848 повідомлень із 914 006 доставлених, що становить 67,16%.

Відвідано Viber

Показує кількість повідомлень Viber, які призвели до переходу отримувача за посиланням.

Формула DAX

Viber Visited =
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]), 
    FILTER(
        'Distribution Status',
        'Distribution Status'[Distribution_Sending_Status] IN { "VISITED" }
        && RELATED('Distribution'[Communication_channel]) = "viber"
    )
)

Логіка розрахунку

Ця міра рахує повідомлення Viber, за якими отримувачі перейшли за посиланням у повідомленні.

Вона показує, скільки Viber-комунікацій спричинили взаємодію з посиланням.

Відвідано Viber %

Показує відсоток прочитаних повідомлень Viber, які призвели до відвідування посилання.

Формула DAX

Viber Visited % =
[Viber Visited] / [Viber Read]

Логіка розрахунку

Ця міра обчислює частку прочитаних повідомлень Viber, які призвели до переходу за посиланням.

У прикладі на картці KPI 12 047 повідомлень призвели до відвідувань посилань із 613 848 прочитаних, що становить 1,96%.

Відписано Viber

Показує кількість отримувачів, які відписалися від комунікацій Viber.

Формула DAX

Viber Unsubscribed =
CALCULATE(
    COUNT('Unsubscribed'[ID_Unsubscribed]), 
    'Distribution'[Communication_channel] = "viber"
)

Логіка розрахунку

Ця міра рахує записи про відписку для каналу комунікації viber.

Вона показує, скільки отримувачів відписалися від комунікацій Viber за обраний звітний період.

Відписано Viber %

Показує відсоток доставлених повідомлень Viber, які призвели до дії відписки.

Формула DAX

Viber Unsubscribe % =
[Viber Unsubscribed] / [Viber Delivered]

Логіка розрахунку

Ця міра обчислює частку доставлених повідомлень Viber, які призвели до відписки.

У прикладі на картці KPI показано 556 записів про відписку. Відсоток, відображений на картці KPI, становить 0,06%.

Недоставлено Viber

Показує кількість відправлених повідомлень Viber, які не були доставлені, з вказаною причиною недоставлення.

Формула DAX

Viber Undelivered =
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]),
    FILTER(
        'Distribution Status',
        'Distribution Status'[Distribution_Sending_Status] IN {
            "UNDELIVERED", "UNDELIVERABLE",
            "RESENDING_SMS_UNDELIVERED",
            "RESENDING_SMS_UNDELIVERABLE",
            "EXPIRED", "OLD", "BOUNCED",
            "DEFERRED", "UNKNOWN"
        }
        && RELATED('Distribution'[Communication_channel]) = "viber"
        && TRIM('Distribution Status'[Reason_Undelivered_Viber]) <> ""
        && 'Distribution Status'[Reason_Undelivered_Viber] <> "Пусто"
        && NOT ISBLANK('Distribution Status'[Reason_Undelivered_Viber])
    )
)

Логіка розрахунку

Ця міра рахує відправлені повідомлення Viber, які не були доставлені та мають вказану причину недоставлення.

Вона використовується для аналізу причин невдач доставки та визначення повідомлень, які потребують розслідування за причиною.

Недоставлено Viber %

Показує відсоток відправлених повідомлень Viber, які не були доставлені.

Формула DAX

Viber Undelivered % =
[Viber Undelivered] / [Viber Sent]

Логіка розрахунку

Ця міра обчислює відсоток відправлених повідомлень Viber, які не були доставлені.

Вона допомагає користувачам оцінити частку невдач доставки серед усіх відправлених комунікацій Viber.

Не відправлено Viber

Показує кількість запланованих повідомлень Viber, які не були відправлені через обмеження, некоректні дані, дублікати, статус відписки або інші проблеми з відправкою.

Формула DAX

Viber Unsent =
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]), 
    FILTER(
        'Distribution Status',
        'Distribution Status'[Distribution_Sending_Status] IN {
            "DUPLICATE", "INVALID_EMAIL", "EMPTY_RECIPIENT",
            "EMPTY_CONTENT", "MESSAGE_LIMIT", "EXCLUDED",
            "UNSUBSCRIBED", "FAILED", "DECLINED", "UNVERIFIED"
        }
        && RELATED('Distribution'[Communication_channel]) = "viber"
    )
)

Логіка розрахунку

Ця міра рахує заплановані повідомлення Viber, які не були відправлені через обмеження відправки, некоректні або відсутні дані отримувача, статус відписки, дублікати, невдалу обробку або інші системні умови.

Не відправлено Viber %

Показує відсоток запланованих повідомлень Viber, які не були відправлені.

Формула DAX

Viber Unsent % =
[Viber Unsent] / [Viber Planned]

Логіка розрахунку

Ця міра обчислює частку запланованих повідомлень Viber, які не були відправлені.

Вона допомагає користувачам оцінити, скільки запланованих комунікацій Viber не увійшли у процес відправки.

Динаміка доставки Viber

Показує кількість доставлених повідомлень Viber за часом для обраного динамічного періоду.

Формула DAX

Viber Delivered Dynamic =
VAR N = [DaysToShow Viber]
VAR MaxDate =
    CALCULATE (
        MAX ( 'Distribution Status'[Send_DateOnly] ),
        ALL ( 'Distribution Status' )
    )
VAR Mode = SELECTEDVALUE(PeriodMode[Mode], "Day")
VAR StartDate_Day = MaxDate - (N - 1)
VAR StartDate_Month =
    DATE(
        YEAR ( EOMONTH ( MaxDate, -N + 1 ) ),
        MONTH( EOMONTH ( MaxDate, -N + 1 ) ),
        1
    )
VAR StartDate = IF(Mode = "Month", StartDate_Month, StartDate_Day)
RETURN
CALCULATE (
    COUNT ( 'Distribution Status'[ID_Distribution] ),
    FILTER (
        ALL ( 'Distribution Status'[Send_DateOnly] ),
        'Distribution Status'[Send_DateOnly] >= StartDate
            && 'Distribution Status'[Send_DateOnly] <= MaxDate
    ),
    KEEPFILTERS (
        'Distribution Status'[Distribution_Sending_Status] IN {
            "DELIVERED", "READ", "VISITED", "SEEN"
        }
    ),
    KEEPFILTERS ( 'Distribution'[Communication_channel] = "viber" ),
    REMOVEFILTERS ( 'Calendar' ),
    REMOVEFILTERS ( 'PeriodsFilter' )
)

Логіка розрахунку

Ця міра обчислює кількість доставлених повідомлень Viber за обраний динамічний період.

Вона використовує значення DaysToShow Viber та вибраний режим періоду, наприклад День або Місяць, щоб визначити діапазон дат, що відображається на графіку трендів.

Динаміка прочитання Viber

Показує кількість прочитаних повідомлень Viber за часом для обраного динамічного періоду.

Формула DAX

Viber Read Dynamic =
VAR N = [DaysToShow Viber]
VAR MaxDate =
    CALCULATE (
        MAX ( 'Distribution Status'[Send_DateOnly] ),
        ALL ( 'Distribution Status' )
    )
VAR Mode = SELECTEDVALUE(PeriodMode[Mode], "Day")
VAR StartDate_Day = MaxDate - (N - 1)
VAR StartDate_Month =
    DATE(
        YEAR ( EOMONTH ( MaxDate, -N + 1 ) ),
        MONTH( EOMONTH ( MaxDate, -N + 1 ) ),
        1
    )
VAR StartDate = IF(Mode = "Month", StartDate_Month, StartDate_Day)
RETURN
CALCULATE (
    COUNT ( 'Distribution Status'[ID_Distribution] ),
    FILTER (
        ALL ( 'Distribution Status'[Send_DateOnly] ),
        'Distribution Status'[Send_DateOnly] >= StartDate
            && 'Distribution Status'[Send_DateOnly] <= MaxDate
    ),
    KEEPFILTERS (
        'Distribution Status'[Distribution_Sending_Status] IN {
            "READ", "VISITED", "SEEN"
        }
    ),
    KEEPFILTERS ( 'Distribution'[Communication_channel] = "viber" ),
    REMOVEFILTERS ( 'Calendar' ),
    REMOVEFILTERS ( 'PeriodsFilter' )
)

Логіка розрахунку

Ця міра обчислює кількість прочитаних повідомлень Viber за обраний динамічний період.

Вона використовується на діаграмі Тренди доставки та залучення повідомлень, щоб показати, як змінюється активність прочитання з часом.

Динаміка недоставлення Viber

Показує кількість недоставлених повідомлень Viber за часом для обраного динамічного періоду.

Формула DAX

Viber Undelivred Dynamic =
VAR N = [DaysToShow Viber]
VAR MaxDate =
    CALCULATE (
        MAX ( 'Distribution Status'[Send_DateOnly] ),
        ALL ( 'Distribution Status' )
    )
VAR Mode = SELECTEDVALUE(PeriodMode[Mode], "Day")
VAR StartDate =
    SWITCH (
        TRUE(),
        Mode = "Day", MaxDate - (N - 1),
        Mode = "Month", EOMONTH(MaxDate, -N + 1) + 1,
        MaxDate - N
    )
RETURN
CALCULATE (
    COUNT ( 'Distribution Status'[ID_Distribution] ),
    FILTER (
        ALL ( 'Distribution Status'[Send_DateOnly] ),
        'Distribution Status'[Send_DateOnly] >= StartDate
            && 'Distribution Status'[Send_DateOnly] <= MaxDate
    ),
    KEEPFILTERS (
        'Distribution Status'[Distribution_Sending_Status] IN {
            "UNDELIVERED", "UNDELIVERABLE",
            "RESENDING_SMS_UNDELIVERED",
            "RESENDING_SMS_UNDELIVERABLE",
            "EXPIRED", "OLD", "BOUNCED",
            "DEFERRED", "UNKNOWN"
        }
    ),
    KEEPFILTERS ( 'Distribution'[Communication_channel] = "viber" ),
    REMOVEFILTERS ( 'Calendar' ),
    REMOVEFILTERS ( 'PeriodsFilter' )
)

Логіка розрахунку

Ця міра обчислює кількість недоставлених повідомлень Viber за обраний динамічний період.

Вона використовується на графіку трендів, щоб показати динаміку невдач доставки з часом.

Динаміка відвідувань Viber

Показує кількість повідомлень Viber із переходами за посиланнями за часом для обраного динамічного періоду.

Формула DAX

Viber Visited Dynamic =
VAR N = [DaysToShow Viber]
VAR MaxDate =
    CALCULATE (
        MAX ( 'Distribution Status'[Send_DateOnly] ),
        ALL ( 'Distribution Status' )
    )
VAR Mode = SELECTEDVALUE(PeriodMode[Mode], "Day")
VAR StartDate =
    SWITCH (
        TRUE(),
        Mode = "Day", MaxDate - (N - 1),
        Mode = "Month", EOMONTH(MaxDate, -N + 1) + 1,
        MaxDate - N
    )
RETURN
CALCULATE (
    COUNT ( 'Distribution Status'[ID_Distribution] ),
    FILTER (
        ALL ( 'Distribution Status'[Send_DateOnly] ),
        'Distribution Status'[Send_DateOnly] >= StartDate
            && 'Distribution Status'[Send_DateOnly] <= MaxDate
    ),
    KEEPFILTERS (
        'Distribution Status'[Distribution_Sending_Status] IN { "VISITED" }
    ),
    KEEPFILTERS ( 'Distribution'[Communication_channel] = "viber" ),
    REMOVEFILTERS ( 'Calendar' ),
    REMOVEFILTERS ( 'PeriodsFilter' )
)

Логіка розрахунку

Ця міра обчислює кількість повідомлень Viber, за якими отримувачі перейшли за посиланням протягом обраного динамічного періоду.

Вона використовується на графіку трендів, щоб показати, як змінюється активність переходів за посиланнями у Viber з часом.

Пошук

Заплановано Viber

Відправлено Viber

Відправлено Viber %

Доставлено Viber

Доставлено Viber %

Прочитано Viber

Прочитано Viber %

Відвідано Viber

Відвідано Viber %

Відписано Viber

Відписано Viber %

Недоставлено Viber

Недоставлено Viber %

Не відправлено Viber

Не відправлено Viber %

Динаміка доставки Viber

Динаміка прочитання Viber

Динаміка недоставлення Viber

Динаміка відвідувань Viber