Перейти до основного контенту

Пошук

SMS Dashboard KPI Calculation Logic

smskpi.jpg

 

Заплановано

Показує загальну кількість SMS-повідомлень, запланованих до відправлення протягом вибраного звітного періоду.

Формула DAX

SMS Planned =
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]), 
    'Distribution'[Communication_channel] = "sms"
)

Логіка обчислення

Показник рахує всі записи розсилки, де канал комунікації — sms. Він відображає загальну кількість запланованих SMS-повідомлень за вибраний період та фільтри.

Відправлено

Показує кількість SMS-повідомлень, які увійшли у процес відправлення.

Формула DAX

SMS Sent =
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]), 
    FILTER(
        'Distribution Status',
        'Distribution Status'[Distribution_Sending_Status] IN {
            "DELIVERED", "BOUNCED", "DECLINED", "DEFERRED", "EXPIRED",
            "FAILED", "OLD", "REJECTED", "UNDELIVERABLE", "UNDELIVERED",
            "UNKNOWN", "ENQUEUED", "QUEUED", "SENT", "VISITED", "READ", "SEEN"
        }
        && RELATED('Distribution'[Communication_channel]) = "sms"
    )
)

Логіка обчислення

Показник рахує SMS-повідомлення зі статусами, які вказують, що повідомлення увійшло у процес відправлення. Він включає як успішно оброблені повідомлення, так і повідомлення зі статусами невдалої доставки.

Відправлено %

Показує відсоток запланованих SMS-повідомлень, які були відправлені.

Формула DAX

SMS Sent % =
[SMS Sent] / [SMS Planned]

Логіка обчислення

Показник ділить кількість відправлених SMS-повідомлень на кількість запланованих SMS-повідомлень.

Доставлено

Показує кількість SMS-повідомлень, успішно доставлених отримувачам.

Формула DAX

SMS Delivered =
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]), 
    FILTER(
        'Distribution Status',
        'Distribution Status'[Distribution_Sending_Status] IN {
            "DELIVERED", "READ", "VISITED", "SEEN"
        }
        && RELATED('Distribution'[Communication_channel]) = "sms"
    )
)

Логіка обчислення

Показник рахує SMS-повідомлення зі статусами, пов’язаними з доставкою. Статуси такі як READ, VISITED та SEEN включені, бо ці дії можуть відбутися лише після успішної доставки.

Доставлено %

Показує відсоток відправлених SMS-повідомлень, які були успішно доставлені.

Формула DAX

SMS Delivered % =
[SMS Delivered] / [SMS Sent]

Логіка обчислення

Показник ділить кількість доставлених SMS-повідомлень на кількість відправлених SMS-повідомлень.

Прочитано

Показує кількість SMS-повідомлень, прочитаних або переглянутих отримувачами.

Формула DAX

SMS Read =
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]), 
    FILTER(
        'Distribution Status',
        'Distribution Status'[Distribution_Sending_Status] IN {
            "READ", "VISITED", "SEEN"
        }
        && RELATED('Distribution'[Communication_channel]) = "sms"
    )
)

Логіка обчислення

Показник рахує SMS-повідомлення зі статусами, які вказують на активність читання або перегляду отримувачем.

Відвідано

Показує кількість SMS-повідомлень, у яких отримувачі перейшли за посиланням.

Формула DAX

SMS Visited =
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]), 
    FILTER(
        'Distribution Status',
        'Distribution Status'[Distribution_Sending_Status] IN { "VISITED" }
        && RELATED('Distribution'[Communication_channel]) = "sms"
    )
)

Логіка обчислення

Показник рахує SMS-повідомлення зі статусом VISITED. Він показує, скільки SMS-комунікацій спричинили взаємодію з посиланням.

Відвідано %

Показує відсоток доставлених SMS-повідомлень, які призвели до переходу за посиланням.

Формула DAX

SMS Visited % =
[SMS Visited] / [SMS Delivered]

Логіка обчислення

Показник ділить кількість SMS-повідомлень із переходами за посиланням на кількість доставлених SMS-повідомлень.

Відписалися

Показує кількість отримувачів, які відписалися від SMS-комунікацій.

Формула DAX

SMS Unsubscribed =
CALCULATE(
    COUNT('Unsubscribed'[ID_Unsubscribed]), 
    'Distribution'[Communication_channel] = "sms"
)

Логіка обчислення

Показник рахує записи про відписку для каналу комунікації sms.

Відписалися %

Показує відсоток доставлених SMS-повідомлень, які призвели до дії відписки.

Формула DAX

SMS Unsubscribed % =
[SMS Unsubscribed] / [SMS Delivered]

Логіка обчислення

Показник ділить кількість записів про відписку від SMS на кількість доставлених SMS-повідомлень.

Не доставлено

Показує кількість відправлених SMS-повідомлень, які не були доставлені.

Формула DAX

SMS Undelivered =
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]), 
    FILTER(
        'Distribution Status',
        'Distribution Status'[Distribution_Sending_Status] IN {
            "UNDELIVERED", "UNDELIVERABLE",
            "RESENDING_SMS_UNDELIVERED",
            "RESENDING_SMS_UNDELIVERABLE",
            "EXPIRED", "OLD", "BOUNCED",
            "DEFERRED", "UNKNOWN"
        }
        && RELATED('Distribution'[Communication_channel]) = "sms"
    )
)

Логіка обчислення

Показник рахує SMS-повідомлення зі статусами, які вказують на невдачу доставки.

Не доставлено %

Показує відсоток відправлених SMS-повідомлень, які не були доставлені.

Формула DAX

SMS Undelivered % =
[SMS Undelivered] / [SMS Sent]

Логіка обчислення

Показник ділить кількість недоставлених SMS-повідомлень на кількість відправлених SMS-повідомлень.

Не відправлено

Показує кількість запланованих SMS-повідомлень, які не були відправлені.

Формула DAX

SMS Unsent =
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]), 
    FILTER(
        'Distribution Status',
        'Distribution Status'[Distribution_Sending_Status] IN {
            "DUPLICATE", "INVALID_EMAIL", "EMPTY_RECIPIENT",
            "EMPTY_CONTENT", "MESSAGE_LIMIT", "EXCLUDED",
            "UNSUBSCRIBED", "FAILED", "DECLINED", "UNVERIFIED"
        }
        && RELATED('Distribution'[Communication_channel]) = "sms"
    )
)

Логіка обчислення

Показник рахує заплановані SMS-повідомлення, які не були відправлені через обмеження, дублікати записів, відсутність даних отримувача, невдалу обробку або інші проблеми з відправленням.

Не відправлено %

Показує відсоток запланованих SMS-повідомлень, які не були відправлені.

Формула DAX

SMS Unsent % =
[SMS Unsent] / [SMS Planned]

Логіка обчислення

Показник ділить кількість не відправлених SMS-повідомлень на кількість запланованих SMS-повідомлень.

Динаміка доставлених SMS

Показує кількість доставлених SMS-повідомлень за часом для вибраного динамічного періоду.

Формула DAX

SMS Delivered Dynamic =
VAR N = [DaysToShow SMS]
VAR MaxDate =
    CALCULATE (
        MAX ( 'Distribution Status'[Send_DateOnly] ),
        ALL ( 'Distribution Status' )
    )
VAR Mode = SELECTEDVALUE(PeriodMode[Mode], "Day")
VAR StartDate_Day = MaxDate - (N - 1)
VAR StartDate_Month =
    DATE(
        YEAR ( EOMONTH ( MaxDate, -N + 1 ) ),
        MONTH( EOMONTH ( MaxDate, -N + 1 ) ),
        1
    )
VAR StartDate = IF(Mode = "Month", StartDate_Month, StartDate_Day)
RETURN
CALCULATE (
    COUNT ( 'Distribution Status'[ID_Distribution] ),
    FILTER (
        ALL ( 'Distribution Status'[Send_DateOnly] ),
        'Distribution Status'[Send_DateOnly] >= StartDate
            && 'Distribution Status'[Send_DateOnly] <= MaxDate
    ),
    KEEPFILTERS (
        'Distribution Status'[Distribution_Sending_Status] IN {
            "DELIVERED", "READ", "VISITED", "SEEN"
        }
    ),
    KEEPFILTERS ( 'Distribution'[Communication_channel] = "sms" ),
    REMOVEFILTERS ( 'Calendar' ),
    REMOVEFILTERS ( 'PeriodsFilter' )
)

Логіка обчислення

Показник обчислює кількість доставлених SMS-повідомлень за вибраний динамічний період. Він використовує DaysToShow SMS та вибраний режим періоду, наприклад День або Місяць, щоб визначити відображуваний діапазон дат.

Динаміка прочитаних SMS

Показує кількість прочитаних SMS-повідомлень за часом для вибраного динамічного періоду.

Формула DAX

SMS Read Dynamic =
VAR N = [DaysToShow SMS]
VAR MaxDate =
    CALCULATE (
        MAX ( 'Distribution Status'[Send_DateOnly] ),
        ALL ( 'Distribution Status' )
    )
VAR Mode = SELECTEDVALUE(PeriodMode[Mode], "Day")
VAR StartDate_Day = MaxDate - (N - 1)
VAR StartDate_Month =
    DATE(
        YEAR ( EOMONTH ( MaxDate, -N + 1 ) ),
        MONTH( EOMONTH ( MaxDate, -N + 1 ) ),
        1
    )
VAR StartDate = IF(Mode = "Month", StartDate_Month, StartDate_Day)
RETURN
CALCULATE (
    COUNT ( 'Distribution Status'[ID_Distribution] ),
    FILTER (
        ALL ( 'Distribution Status'[Send_DateOnly] ),
        'Distribution Status'[Send_DateOnly] >= StartDate
            && 'Distribution Status'[Send_DateOnly] <= MaxDate
    ),
    KEEPFILTERS (
        'Distribution Status'[Distribution_Sending_Status] IN {
            "READ", "VISITED", "SEEN"
        }
    ),
    KEEPFILTERS ( 'Distribution'[Communication_channel] = "sms" ),
    REMOVEFILTERS ( 'Calendar' ),
    REMOVEFILTERS ( 'PeriodsFilter' )
)

Логіка обчислення

Показник обчислює кількість SMS-повідомлень, прочитаних отримувачами протягом вибраного динамічного періоду. Використовується у графіку Тенденції доставки повідомлень та залучення.

Динаміка недоставлених SMS

Показує кількість недоставлених SMS-повідомлень за часом для вибраного динамічного періоду.

Формула DAX

SMS Undelivred Dynamic =
VAR N = [DaysToShow SMS]
VAR MaxDate =
    CALCULATE (
        MAX ( 'Distribution Status'[Send_DateOnly] ),
        ALL ( 'Distribution Status' )
    )
VAR Mode = SELECTEDVALUE(PeriodMode[Mode], "Day")
VAR StartDate =
    SWITCH (
        TRUE(),
        Mode = "Day", MaxDate - (N - 1),
        Mode = "Month", EOMONTH(MaxDate, -N + 1) + 1,
        MaxDate - N
    )
RETURN
CALCULATE (
    COUNT ( 'Distribution Status'[ID_Distribution] ),
    FILTER (
        ALL ( 'Distribution Status'[Send_DateOnly] ),
        'Distribution Status'[Send_DateOnly] >= StartDate
            && 'Distribution Status'[Send_DateOnly] <= MaxDate
    ),
    KEEPFILTERS (
        'Distribution Status'[Distribution_Sending_Status] IN {
            "UNDELIVERED", "UNDELIVERABLE",
            "RESENDING_SMS_UNDELIVERED",
            "RESENDING_SMS_UNDELIVERABLE",
            "EXPIRED", "OLD", "BOUNCED",
            "DEFERRED", "UNKNOWN"
        }
    ),
    KEEPFILTERS ( 'Distribution'[Communication_channel] = "sms" ),
    REMOVEFILTERS ( 'Calendar' ),
    REMOVEFILTERS ( 'PeriodsFilter' )
)

Логіка обчислення

Показник обчислює кількість недоставлених SMS-повідомлень за вибраний динамічний період. Використовується для відображення динаміки помилок доставки за часом.

Динаміка відвіданих SMS

Показує кількість SMS-повідомлень із переходами за посиланням за часом для вибраного динамічного періоду.

Формула DAX

SMS Visited Dynamic =
VAR N = [DaysToShow SMS]
VAR MaxDate =
    CALCULATE (
        MAX ( 'Distribution Status'[Send_DateOnly] ),
        ALL ( 'Distribution Status' )
    )
VAR Mode = SELECTEDVALUE(PeriodMode[Mode], "Day")
VAR StartDate =
    SWITCH (
        TRUE(),
        Mode = "Day", MaxDate - (N - 1),
        Mode = "Month", EOMONTH(MaxDate, -N + 1) + 1,
        MaxDate - N
    )
RETURN
CALCULATE (
    COUNT ( 'Distribution Status'[ID_Distribution] ),
    FILTER (
        ALL ( 'Distribution Status'[Send_DateOnly] ),
        'Distribution Status'[Send_DateOnly] >= StartDate
            && 'Distribution Status'[Send_DateOnly] <= MaxDate
    ),
    KEEPFILTERS (
        'Distribution Status'[Distribution_Sending_Status] IN { "VISITED" }
    ),
    KEEPFILTERS ( 'Distribution'[Communication_channel] = "sms" ),
    REMOVEFILTERS ( 'Calendar' ),
    REMOVEFILTERS ( 'PeriodsFilter' )
)

Логіка обчислення

Показник обчислює кількість SMS-повідомлень, у яких отримувачі перейшли за посиланням протягом вибраного динамічного періоду. Використовується у графіку тенденцій для відображення активності переходів за посиланнями SMS за часом.