Viber Dashboard KPI Hisoblash Mantiqi – Proxima Research Oʻzbekiston

Viber boshqaruv paneli Viber aloqa samaradorligi uchun KPI kartalari, diagrammalar va batafsil jadval metrikalarini ko‘rsatadi.

Rejalashtirilgan
Yuborilgan
Yuborilgan %
Viber Yetkazilgan
Viber Yetkazilgan %
Viber O'qilgan
Viber O'qilgan %
Viber Tashrif Buyurilgan
Viber Tashrif Buyurilgan %
Obunani Bekor Qilganlar
Obunani Bekor Qilish %
Yetkazilmagan
Yetkazilmagan %
Yuborilmagan
Yuborilmagan %
Viber Yetkazilgan Dinamik
Viber O'qilgan Dinamik
Viber Yetkazilmagan Dinamik
Viber Tashrif Buyurilgan Dinamik

Viber Rejalashtirilgan

Tanlangan hisobot davrida yuborilishi rejalashtirilgan jami Viber xabarlari sonini ko‘rsatadi.

DAX Formulasi

Viber Planned =
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]), 
    'Distribution'[Communication_channel] = "viber"
)

Hisoblash Mantiqi

Ushbu o‘lchov aloqa kanali viber bo‘lgan barcha tarqatish yozuvlarini hisoblaydi.

Bu tanlangan hisobot davri va tanlangan filtrlar uchun rejalashtirilgan jami Viber xabarlari sonini ifodalaydi.

Viber Yuborilgan

Yakuniy yetkazib berish natijasidan qat’i nazar, yuborish jarayoniga kirgan Viber xabarlari sonini ko‘rsatadi.

DAX Formulasi

Viber Sent =
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]), 
    FILTER(
        'Distribution Status',
        'Distribution Status'[Distribution_Sending_Status] IN {
            "DELIVERED", "BOUNCED", "DECLINED", "DEFERRED", "EXPIRED",
            "FAILED", "OLD", "REJECTED", "UNDELIVERABLE", "UNDELIVERED",
            "UNKNOWN", "ENQUEUED", "QUEUED", "SENT", "VISITED", "READ", "SEEN"
        }
        && RELATED('Distribution'[Communication_channel]) = "viber"
    )
)

Hisoblash Mantiqi

Ushbu o‘lchov yuborish jarayoniga kirganligini ko‘rsatadigan yuborish holatlariga ega Viber xabarlarini hisoblaydi.

U muvaffaqiyatli yetkazilgan, o‘qilgan, tashrif buyurilgan yoki ko‘rilgan xabarlarni, shuningdek, qaytgan, muvaffaqiyatsiz, rad etilgan, yetkazib bo‘lmaydigan yoki noma’lum holatdagi xabarlarni o‘z ichiga oladi.

Viber Yuborilgan %

Rejalashtirilgan Viber xabarlarining yuborilgan foizini ko‘rsatadi.

DAX Formulasi

Viber Sent % =
[Viber Sent] / [Viber Planned]

Hisoblash Mantiqi

U rejalashtirilgan Viber xabarlarining yuborilgan ulushini hisoblaydi.

KPI karta misolida 1,149,942 xabar 1,616,922 rejalashtirilgan xabardan yuborilgan, bu 71.12% ga teng.

Viber Yetkazilgan

Qabul qiluvchilarga muvaffaqiyatli yetkazilgan Viber xabarlari sonini ko‘rsatadi.

DAX Formulasi

Viber Delivered =
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]), 
    FILTER(
        'Distribution Status',
        'Distribution Status'[Distribution_Sending_Status] IN {
            "DELIVERED", "READ", "VISITED", "SEEN"
        }
        && RELATED('Distribution'[Communication_channel]) = "viber"
    )
)

Hisoblash Mantiqi

U muvaffaqiyatli yetkazilgan Viber xabarlarini hisoblaydi.

O‘qilgan (READ), tashrif buyurilgan (VISITED) va ko‘rilgan (SEEN) holatlar ham kiritilgan, chunki bu harakatlar faqat muvaffaqiyatli yetkazilgandan keyin sodir bo‘ladi.

Viber Yetkazilgan %

Yuborilgan Viber xabarlarining muvaffaqiyatli yetkazilgan foizini ko‘rsatadi.

DAX Formulasi

Viber Delivered % =
[Viber Delivered] / [Viber Sent]

Hisoblash Mantiqi

U yuborilgan Viber xabarlarining yetkazilgan ulushini hisoblaydi.

KPI karta misolida 914,006 xabar 1,149,942 yuborilgan xabardan yetkazilgan, bu 79.48% ga teng.

Viber O'qilgan

Qabul qiluvchilar tomonidan o‘qilgan yoki ko‘rilgan yetkazilgan Viber xabarlari sonini ko‘rsatadi.

DAX Formulasi

Viber Read =
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]), 
    FILTER(
        'Distribution Status',
        'Distribution Status'[Distribution_Sending_Status] IN {
            "READ", "VISITED", "SEEN"
        }
        && RELATED('Distribution'[Communication_channel]) = "viber"
    )
)

Hisoblash Mantiqi

U qabul qiluvchilar tomonidan o‘qilgan Viber xabarlarini hisoblaydi.

Tashrif buyurilgan (VISITED) va ko‘rilgan (SEEN) holatlar ham kiritilgan, chunki ular xabar o‘qilgandan yoki ko‘rilgandan keyin qabul qiluvchi ishtirokini ko‘rsatadi.

Viber O'qilgan %

Yetkazilgan Viber xabarlarining qabul qiluvchilar tomonidan o‘qilgan foizini ko‘rsatadi.

DAX Formulasi

Viber Read % =
[Viber Read] / [Viber Delivered]

Hisoblash Mantiqi

U yetkazilgan Viber xabarlarining o‘qilgan ulushini hisoblaydi.

KPI karta misolida 613,848 xabar 914,006 yetkazilgan xabardan o‘qilgan, bu 67.16% ga teng.

Viber Tashrif Buyurilgan

Qabul qiluvchilar havolani bosgan Viber xabarlari sonini ko‘rsatadi.

DAX Formulasi

Viber Visited =
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]), 
    FILTER(
        'Distribution Status',
        'Distribution Status'[Distribution_Sending_Status] IN { "VISITED" }
        && RELATED('Distribution'[Communication_channel]) = "viber"
    )
)

Hisoblash Mantiqi

U xabar ichidagi havolani bosgan Viber xabarlarini hisoblaydi.

Bu Viber aloqalarining havola bilan o‘zaro aloqasini ko‘rsatadi.

Viber Tashrif Buyurilgan %

O‘qilgan Viber xabarlarining havola bosishga olib kelgan foizini ko‘rsatadi.

DAX Formulasi

Viber Visited % =
[Viber Visited] / [Viber Read]

Hisoblash Mantiqi

U o‘qilgan Viber xabarlarining havola bosishga olib kelgan ulushini hisoblaydi.

KPI karta misolida 12,047 xabar 613,848 o‘qilgan xabardan havola bosishga olib kelgan, bu 1.96% ga teng.

Viber Obunani Bekor Qilganlar

Viber aloqalaridan obunani bekor qilgan qabul qiluvchilar sonini ko‘rsatadi.

DAX Formulasi

Viber Unsubscribed =
CALCULATE(
    COUNT('Unsubscribed'[ID_Unsubscribed]), 
    'Distribution'[Communication_channel] = "viber"
)

Hisoblash Mantiqi

Bu o‘lchov viber aloqa kanali uchun obunani bekor qilish yozuvlarini hisoblaydi.

Tanlangan hisobot davrida Viber aloqalaridan nechta qabul qiluvchi obunani bekor qilganini ko‘rsatadi.

Viber Obunani Bekor Qilish %

Yetkazilgan Viber xabarlarining obunani bekor qilishga olib kelgan foizini ko‘rsatadi.

DAX Formulasi

Viber Unsubscribe % =
[Viber Unsubscribed] / [Viber Delivered]

Hisoblash Mantiqi

U yetkazilgan Viber xabarlarining obunani bekor qilishga olib kelgan ulushini hisoblaydi.

KPI karta misolida 556 obunani bekor qilish yozuvi ko‘rsatilgan. KPI kartadagi foiz 0.06%.

Viber Yetkazilmagan

Yuborilgan, lekin yetkazilmagan va aniq yetkazilmagan sabab ko‘rsatilgan Viber xabarlari sonini ko‘rsatadi.

DAX Formulasi

Viber Undelivered =
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]),
    FILTER(
        'Distribution Status',
        'Distribution Status'[Distribution_Sending_Status] IN {
            "UNDELIVERED", "UNDELIVERABLE",
            "RESENDING_SMS_UNDELIVERED",
            "RESENDING_SMS_UNDELIVERABLE",
            "EXPIRED", "OLD", "BOUNCED",
            "DEFERRED", "UNKNOWN"
        }
        && RELATED('Distribution'[Communication_channel]) = "viber"
        && TRIM('Distribution Status'[Reason_Undelivered_Viber]) <> ""
        && 'Distribution Status'[Reason_Undelivered_Viber] <> "Пусто"
        && NOT ISBLANK('Distribution Status'[Reason_Undelivered_Viber])
    )
)

Hisoblash Mantiqi

U yuborilgan, lekin yetkazilmagan va aniq yetkazilmagan sabab ko‘rsatilgan Viber xabarlarini hisoblaydi.

Yetkazib berish muvaffaqiyatsizliklarini tahlil qilish va sabab bo‘yicha tekshirish talab qilinadigan xabarlarni aniqlash uchun ishlatiladi.

Viber Yetkazilmagan %

Yuborilgan, lekin yetkazilmagan Viber xabarlarining foizini ko‘rsatadi.

DAX Formulasi

Viber Undelivered % =
[Viber Undelivered] / [Viber Sent]

Hisoblash Mantiqi

U yuborilgan, lekin yetkazilmagan Viber xabarlarining foizini hisoblaydi.

Foydalanuvchilarga barcha yuborilgan Viber aloqalaridagi yetkazib berish muvaffaqiyatsizliklari ulushini baholashga yordam beradi.

Viber Yuborilmagan

Rejalashtirilgan, ammo cheklovlar, noto‘g‘ri ma’lumotlar, takroriyliklar, obunani bekor qilish holati yoki boshqa yuborish muammolari sababli yuborilmagan Viber xabarlari sonini ko‘rsatadi.

DAX Formulasi

Viber Unsent =
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]), 
    FILTER(
        'Distribution Status',
        'Distribution Status'[Distribution_Sending_Status] IN {
            "DUPLICATE", "INVALID_EMAIL", "EMPTY_RECIPIENT",
            "EMPTY_CONTENT", "MESSAGE_LIMIT", "EXCLUDED",
            "UNSUBSCRIBED", "FAILED", "DECLINED", "UNVERIFIED"
        }
        && RELATED('Distribution'[Communication_channel]) = "viber"
    )
)

Hisoblash Mantiqi

U yuborish cheklovlari, noto‘g‘ri yoki yo‘qolgan qabul qiluvchi ma’lumotlari, obunani bekor qilish holati, takroriyliklar, muvaffaqiyatsiz ishlov berish yoki boshqa tizim sharoitlari sababli yuborilmagan rejalashtirilgan Viber xabarlarini hisoblaydi.

Viber Yuborilmagan %

Rejalashtirilgan, ammo yuborilmagan Viber xabarlarining foizini ko‘rsatadi.

DAX Formulasi

Viber Unsent % =
[Viber Unsent] / [Viber Planned]

Hisoblash Mantiqi

U rejalashtirilgan, ammo yuborilmagan Viber xabarlarining ulushini hisoblaydi.

Foydalanuvchilarga rejalashtirilgan Viber aloqalaridan nechtasi yuborish jarayoniga kirmaganini baholashga yordam beradi.

Viber Yetkazilgan Dinamik

Tanlangan dinamik davr uchun yetkazilgan Viber xabarlari sonini vaqt bo‘yicha ko‘rsatadi.

DAX Formulasi

Viber Delivered Dynamic =
VAR N = [DaysToShow Viber]
VAR MaxDate =
    CALCULATE (
        MAX ( 'Distribution Status'[Send_DateOnly] ),
        ALL ( 'Distribution Status' )
    )
VAR Mode = SELECTEDVALUE(PeriodMode[Mode], "Day")
VAR StartDate_Day = MaxDate - (N - 1)
VAR StartDate_Month =
    DATE(
        YEAR ( EOMONTH ( MaxDate, -N + 1 ) ),
        MONTH( EOMONTH ( MaxDate, -N + 1 ) ),
        1
    )
VAR StartDate = IF(Mode = "Month", StartDate_Month, StartDate_Day)
RETURN
CALCULATE (
    COUNT ( 'Distribution Status'[ID_Distribution] ),
    FILTER (
        ALL ( 'Distribution Status'[Send_DateOnly] ),
        'Distribution Status'[Send_DateOnly] >= StartDate
            && 'Distribution Status'[Send_DateOnly] <= MaxDate
    ),
    KEEPFILTERS (
        'Distribution Status'[Distribution_Sending_Status] IN {
            "DELIVERED", "READ", "VISITED", "SEEN"
        }
    ),
    KEEPFILTERS ( 'Distribution'[Communication_channel] = "viber" ),
    REMOVEFILTERS ( 'Calendar' ),
    REMOVEFILTERS ( 'PeriodsFilter' )
)

Hisoblash Mantiqi

Tanlangan dinamik davr uchun yetkazilgan Viber xabarlari sonini hisoblaydi.

U DaysToShow Viber qiymati va tanlangan davr rejimidan, masalan Kun yoki Oy dan foydalanib, trend diagrammasida ko‘rsatiladigan sana oralig‘ini belgilaydi.

Viber O'qilgan Dinamik

Tanlangan dinamik davr uchun o‘qilgan Viber xabarlari sonini vaqt bo‘yicha ko‘rsatadi.

DAX Formulasi

Viber Read Dynamic =
VAR N = [DaysToShow Viber]
VAR MaxDate =
    CALCULATE (
        MAX ( 'Distribution Status'[Send_DateOnly] ),
        ALL ( 'Distribution Status' )
    )
VAR Mode = SELECTEDVALUE(PeriodMode[Mode], "Day")
VAR StartDate_Day = MaxDate - (N - 1)
VAR StartDate_Month =
    DATE(
        YEAR ( EOMONTH ( MaxDate, -N + 1 ) ),
        MONTH( EOMONTH ( MaxDate, -N + 1 ) ),
        1
    )
VAR StartDate = IF(Mode = "Month", StartDate_Month, StartDate_Day)
RETURN
CALCULATE (
    COUNT ( 'Distribution Status'[ID_Distribution] ),
    FILTER (
        ALL ( 'Distribution Status'[Send_DateOnly] ),
        'Distribution Status'[Send_DateOnly] >= StartDate
            && 'Distribution Status'[Send_DateOnly] <= MaxDate
    ),
    KEEPFILTERS (
        'Distribution Status'[Distribution_Sending_Status] IN {
            "READ", "VISITED", "SEEN"
        }
    ),
    KEEPFILTERS ( 'Distribution'[Communication_channel] = "viber" ),
    REMOVEFILTERS ( 'Calendar' ),
    REMOVEFILTERS ( 'PeriodsFilter' )
)

Hisoblash Mantiqi

Tanlangan dinamik davr uchun o‘qilgan Viber xabarlari sonini hisoblaydi.

U Xabar Yetkazilishi va Ishtirok Trendlari diagrammasida o‘qilganlik faolligining vaqt davomida qanday o‘zgarishini ko‘rsatish uchun ishlatiladi.

Viber Yetkazilmagan Dinamik

Tanlangan dinamik davr uchun yetkazilmagan Viber xabarlari sonini vaqt bo‘yicha ko‘rsatadi.

DAX Formulasi

Viber Undelivred Dynamic =
VAR N = [DaysToShow Viber]
VAR MaxDate =
    CALCULATE (
        MAX ( 'Distribution Status'[Send_DateOnly] ),
        ALL ( 'Distribution Status' )
    )
VAR Mode = SELECTEDVALUE(PeriodMode[Mode], "Day")
VAR StartDate =
    SWITCH (
        TRUE(),
        Mode = "Day", MaxDate - (N - 1),
        Mode = "Month", EOMONTH(MaxDate, -N + 1) + 1,
        MaxDate - N
    )
RETURN
CALCULATE (
    COUNT ( 'Distribution Status'[ID_Distribution] ),
    FILTER (
        ALL ( 'Distribution Status'[Send_DateOnly] ),
        'Distribution Status'[Send_DateOnly] >= StartDate
            && 'Distribution Status'[Send_DateOnly] <= MaxDate
    ),
    KEEPFILTERS (
        'Distribution Status'[Distribution_Sending_Status] IN {
            "UNDELIVERED", "UNDELIVERABLE",
            "RESENDING_SMS_UNDELIVERED",
            "RESENDING_SMS_UNDELIVERABLE",
            "EXPIRED", "OLD", "BOUNCED",
            "DEFERRED", "UNKNOWN"
        }
    ),
    KEEPFILTERS ( 'Distribution'[Communication_channel] = "viber" ),
    REMOVEFILTERS ( 'Calendar' ),
    REMOVEFILTERS ( 'PeriodsFilter' )
)

Hisoblash Mantiqi

Tanlangan dinamik davr uchun yetkazilmagan Viber xabarlari sonini hisoblaydi.

U yetkazib berish muvaffaqiyatsizliklarining vaqt davomida qanday o‘zgarishini ko‘rsatish uchun trend diagrammasida ishlatiladi.

Viber Tashrif Buyurilgan Dinamik

Tanlangan dinamik davr uchun havolaga tashrif buyurilgan Viber xabarlari sonini vaqt bo‘yicha ko‘rsatadi.

DAX Formulasi

Viber Visited Dynamic =
VAR N = [DaysToShow Viber]
VAR MaxDate =
    CALCULATE (
        MAX ( 'Distribution Status'[Send_DateOnly] ),
        ALL ( 'Distribution Status' )
    )
VAR Mode = SELECTEDVALUE(PeriodMode[Mode], "Day")
VAR StartDate =
    SWITCH (
        TRUE(),
        Mode = "Day", MaxDate - (N - 1),
        Mode = "Month", EOMONTH(MaxDate, -N + 1) + 1,
        MaxDate - N
    )
RETURN
CALCULATE (
    COUNT ( 'Distribution Status'[ID_Distribution] ),
    FILTER (
        ALL ( 'Distribution Status'[Send_DateOnly] ),
        'Distribution Status'[Send_DateOnly] >= StartDate
            && 'Distribution Status'[Send_DateOnly] <= MaxDate
    ),
    KEEPFILTERS (
        'Distribution Status'[Distribution_Sending_Status] IN { "VISITED" }
    ),
    KEEPFILTERS ( 'Distribution'[Communication_channel] = "viber" ),
    REMOVEFILTERS ( 'Calendar' ),
    REMOVEFILTERS ( 'PeriodsFilter' )
)

Hisoblash Mantiqi

Tanlangan dinamik davr mobaynida qabul qiluvchilar havolani bosgan Viber xabarlari sonini hisoblaydi.

U trend diagrammasida Viber havola bosish faoliyatining vaqt davomida qanday o‘zgarishini ko‘rsatish uchun ishlatiladi.

Qidirish

Viber Rejalashtirilgan

Viber Yuborilgan

Viber Yuborilgan %

Viber Yetkazilgan

Viber Yetkazilgan %

Viber O'qilgan

Viber O'qilgan %

Viber Tashrif Buyurilgan

Viber Tashrif Buyurilgan %

Viber Obunani Bekor Qilganlar

Viber Obunani Bekor Qilish %

Viber Yetkazilmagan

Viber Yetkazilmagan %

Viber Yuborilmagan

Viber Yuborilmagan %

Viber Yetkazilgan Dinamik

Viber O'qilgan Dinamik

Viber Yetkazilmagan Dinamik

Viber Tashrif Buyurilgan Dinamik