Saltar al contenido principal

Búsqueda

SMS Dashboard KPI Calculation Logic

smskpi.jpg

 

Planificados

Muestra el número total de mensajes SMS planificados para enviar durante el período de reporte seleccionado.

Fórmula DAX

SMS Planned =
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]), 
    'Distribution'[Communication_channel] = "sms"
)

Lógica de Cálculo

La medida cuenta todos los registros de distribución donde el canal de comunicación es sms. Representa el número total de mensajes SMS planificados para el período y filtros seleccionados.

Enviados

Muestra el número de mensajes SMS que entraron en el proceso de envío.

Fórmula DAX

SMS Sent =
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]), 
    FILTER(
        'Distribution Status',
        'Distribution Status'[Distribution_Sending_Status] IN {
            "DELIVERED", "BOUNCED", "DECLINED", "DEFERRED", "EXPIRED",
            "FAILED", "OLD", "REJECTED", "UNDELIVERABLE", "UNDELIVERED",
            "UNKNOWN", "ENQUEUED", "QUEUED", "SENT", "VISITED", "READ", "SEEN"
        }
        && RELATED('Distribution'[Communication_channel]) = "sms"
    )
)

Lógica de Cálculo

La medida cuenta mensajes SMS con estados que indican que el mensaje entró en el proceso de envío. Incluye mensajes procesados exitosamente así como mensajes con estados de entrega fallida.

% Enviados

Muestra el porcentaje de mensajes SMS planificados que fueron enviados.

Fórmula DAX

SMS Sent % =
[SMS Sent] / [SMS Planned]

Lógica de Cálculo

La medida divide el número de mensajes SMS enviados por el número de mensajes SMS planificados.

Entregados

Muestra el número de mensajes SMS entregados exitosamente a los destinatarios.

Fórmula DAX

SMS Delivered =
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]), 
    FILTER(
        'Distribution Status',
        'Distribution Status'[Distribution_Sending_Status] IN {
            "DELIVERED", "READ", "VISITED", "SEEN"
        }
        && RELATED('Distribution'[Communication_channel]) = "sms"
    )
)

Lógica de Cálculo

La medida cuenta mensajes SMS con estados relacionados con la entrega. Estados como READ, VISITED y SEEN se incluyen porque estas acciones solo pueden ocurrir tras una entrega exitosa.

% Entregados

Muestra el porcentaje de mensajes SMS enviados que fueron entregados exitosamente.

Fórmula DAX

SMS Delivered % =
[SMS Delivered] / [SMS Sent]

Lógica de Cálculo

La medida divide el número de mensajes SMS entregados por el número de mensajes SMS enviados.

Leídos

Muestra el número de mensajes SMS leídos o vistos por los destinatarios.

Fórmula DAX

SMS Read =
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]), 
    FILTER(
        'Distribution Status',
        'Distribution Status'[Distribution_Sending_Status] IN {
            "READ", "VISITED", "SEEN"
        }
        && RELATED('Distribution'[Communication_channel]) = "sms"
    )
)

Lógica de Cálculo

La medida cuenta mensajes SMS con estados que indican actividad de lectura o visualización por parte del destinatario.

Visitados

Muestra el número de mensajes SMS donde los destinatarios visitaron un enlace.

Fórmula DAX

SMS Visited =
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]), 
    FILTER(
        'Distribution Status',
        'Distribution Status'[Distribution_Sending_Status] IN { "VISITED" }
        && RELATED('Distribution'[Communication_channel]) = "sms"
    )
)

Lógica de Cálculo

La medida cuenta mensajes SMS con el estado VISITED. Muestra cuántas comunicaciones SMS generaron interacción con enlaces.

% Visitados

Muestra el porcentaje de mensajes SMS entregados que resultaron en una visita a un enlace.

Fórmula DAX

SMS Visited % =
[SMS Visited] / [SMS Delivered]

Lógica de Cálculo

La medida divide el número de mensajes SMS con visitas a enlaces por el número de mensajes SMS entregados.

Darse de baja

Muestra el número de destinatarios que se dieron de baja de las comunicaciones SMS.

Fórmula DAX

SMS Unsubscribed =
CALCULATE(
    COUNT('Unsubscribed'[ID_Unsubscribed]), 
    'Distribution'[Communication_channel] = "sms"
)

Lógica de Cálculo

La medida cuenta los registros de bajas para el canal de comunicación sms.

% Darse de baja

Muestra el porcentaje de mensajes SMS entregados que resultaron en una acción de baja.

Fórmula DAX

SMS Unsubscribed % =
[SMS Unsubscribed] / [SMS Delivered]

Lógica de Cálculo

La medida divide el número de registros de baja de SMS por el número de mensajes SMS entregados.

No entregados

Muestra el número de mensajes SMS enviados que no fueron entregados.

Fórmula DAX

SMS Undelivered =
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]), 
    FILTER(
        'Distribution Status',
        'Distribution Status'[Distribution_Sending_Status] IN {
            "UNDELIVERED", "UNDELIVERABLE",
            "RESENDING_SMS_UNDELIVERED",
            "RESENDING_SMS_UNDELIVERABLE",
            "EXPIRED", "OLD", "BOUNCED",
            "DEFERRED", "UNKNOWN"
        }
        && RELATED('Distribution'[Communication_channel]) = "sms"
    )
)

Lógica de Cálculo

La medida cuenta mensajes SMS con estados que indican fallo en la entrega.

% No entregados

Muestra el porcentaje de mensajes SMS enviados que no fueron entregados.

Fórmula DAX

SMS Undelivered % =
[SMS Undelivered] / [SMS Sent]

Lógica de Cálculo

La medida divide el número de mensajes SMS no entregados por el número de mensajes SMS enviados.

No enviados

Muestra el número de mensajes SMS planificados que no fueron enviados.

Fórmula DAX

SMS Unsent =
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]), 
    FILTER(
        'Distribution Status',
        'Distribution Status'[Distribution_Sending_Status] IN {
            "DUPLICATE", "INVALID_EMAIL", "EMPTY_RECIPIENT",
            "EMPTY_CONTENT", "MESSAGE_LIMIT", "EXCLUDED",
            "UNSUBSCRIBED", "FAILED", "DECLINED", "UNVERIFIED"
        }
        && RELATED('Distribution'[Communication_channel]) = "sms"
    )
)

Lógica de Cálculo

La medida cuenta mensajes SMS planificados que no fueron enviados debido a restricciones, registros duplicados, datos de destinatario faltantes, fallos en el procesamiento u otros problemas de envío.

% No enviados

Muestra el porcentaje de mensajes SMS planificados que no fueron enviados.

Fórmula DAX

SMS Unsent % =
[SMS Unsent] / [SMS Planned]

Lógica de Cálculo

La medida divide el número de mensajes SMS no enviados por el número de mensajes SMS planificados.

SMS Entregados Dinámicos

Muestra el número de mensajes SMS entregados a lo largo del tiempo para el período dinámico seleccionado.

Fórmula DAX

SMS Delivered Dynamic =
VAR N = [DaysToShow SMS]
VAR MaxDate =
    CALCULATE (
        MAX ( 'Distribution Status'[Send_DateOnly] ),
        ALL ( 'Distribution Status' )
    )
VAR Mode = SELECTEDVALUE(PeriodMode[Mode], "Day")
VAR StartDate_Day = MaxDate - (N - 1)
VAR StartDate_Month =
    DATE(
        YEAR ( EOMONTH ( MaxDate, -N + 1 ) ),
        MONTH( EOMONTH ( MaxDate, -N + 1 ) ),
        1
    )
VAR StartDate = IF(Mode = "Month", StartDate_Month, StartDate_Day)
RETURN
CALCULATE (
    COUNT ( 'Distribution Status'[ID_Distribution] ),
    FILTER (
        ALL ( 'Distribution Status'[Send_DateOnly] ),
        'Distribution Status'[Send_DateOnly] >= StartDate
            && 'Distribution Status'[Send_DateOnly] <= MaxDate
    ),
    KEEPFILTERS (
        'Distribution Status'[Distribution_Sending_Status] IN {
            "DELIVERED", "READ", "VISITED", "SEEN"
        }
    ),
    KEEPFILTERS ( 'Distribution'[Communication_channel] = "sms" ),
    REMOVEFILTERS ( 'Calendar' ),
    REMOVEFILTERS ( 'PeriodsFilter' )
)

Lógica de Cálculo

La medida calcula el número de mensajes SMS entregados para el período dinámico seleccionado. Usa DaysToShow SMS y el modo de período seleccionado, como Día o Mes, para definir el rango de fechas mostrado.

SMS Leídos Dinámicos

Muestra el número de mensajes SMS leídos a lo largo del tiempo para el período dinámico seleccionado.

Fórmula DAX

SMS Read Dynamic =
VAR N = [DaysToShow SMS]
VAR MaxDate =
    CALCULATE (
        MAX ( 'Distribution Status'[Send_DateOnly] ),
        ALL ( 'Distribution Status' )
    )
VAR Mode = SELECTEDVALUE(PeriodMode[Mode], "Day")
VAR StartDate_Day = MaxDate - (N - 1)
VAR StartDate_Month =
    DATE(
        YEAR ( EOMONTH ( MaxDate, -N + 1 ) ),
        MONTH( EOMONTH ( MaxDate, -N + 1 ) ),
        1
    )
VAR StartDate = IF(Mode = "Month", StartDate_Month, StartDate_Day)
RETURN
CALCULATE (
    COUNT ( 'Distribution Status'[ID_Distribution] ),
    FILTER (
        ALL ( 'Distribution Status'[Send_DateOnly] ),
        'Distribution Status'[Send_DateOnly] >= StartDate
            && 'Distribution Status'[Send_DateOnly] <= MaxDate
    ),
    KEEPFILTERS (
        'Distribution Status'[Distribution_Sending_Status] IN {
            "READ", "VISITED", "SEEN"
        }
    ),
    KEEPFILTERS ( 'Distribution'[Communication_channel] = "sms" ),
    REMOVEFILTERS ( 'Calendar' ),
    REMOVEFILTERS ( 'PeriodsFilter' )
)

Lógica de Cálculo

La medida calcula el número de mensajes SMS leídos por los destinatarios dentro del período dinámico seleccionado. Se usa en el gráfico Tendencias de Entrega y Compromiso de Mensajes.

SMS No entregados Dinámicos

Muestra el número de mensajes SMS no entregados a lo largo del tiempo para el período dinámico seleccionado.

Fórmula DAX

SMS Undelivred Dynamic =
VAR N = [DaysToShow SMS]
VAR MaxDate =
    CALCULATE (
        MAX ( 'Distribution Status'[Send_DateOnly] ),
        ALL ( 'Distribution Status' )
    )
VAR Mode = SELECTEDVALUE(PeriodMode[Mode], "Day")
VAR StartDate =
    SWITCH (
        TRUE(),
        Mode = "Day", MaxDate - (N - 1),
        Mode = "Month", EOMONTH(MaxDate, -N + 1) + 1,
        MaxDate - N
    )
RETURN
CALCULATE (
    COUNT ( 'Distribution Status'[ID_Distribution] ),
    FILTER (
        ALL ( 'Distribution Status'[Send_DateOnly] ),
        'Distribution Status'[Send_DateOnly] >= StartDate
            && 'Distribution Status'[Send_DateOnly] <= MaxDate
    ),
    KEEPFILTERS (
        'Distribution Status'[Distribution_Sending_Status] IN {
            "UNDELIVERED", "UNDELIVERABLE",
            "RESENDING_SMS_UNDELIVERED",
            "RESENDING_SMS_UNDELIVERABLE",
            "EXPIRED", "OLD", "BOUNCED",
            "DEFERRED", "UNKNOWN"
        }
    ),
    KEEPFILTERS ( 'Distribution'[Communication_channel] = "sms" ),
    REMOVEFILTERS ( 'Calendar' ),
    REMOVEFILTERS ( 'PeriodsFilter' )
)

Lógica de Cálculo

La medida calcula el número de mensajes SMS no entregados dentro del período dinámico seleccionado. Se usa para mostrar la dinámica de fallos en la entrega a lo largo del tiempo.

SMS Visitados Dinámicos

Muestra el número de mensajes SMS con visitas a enlaces a lo largo del tiempo para el período dinámico seleccionado.

Fórmula DAX

SMS Visited Dynamic =
VAR N = [DaysToShow SMS]
VAR MaxDate =
    CALCULATE (
        MAX ( 'Distribution Status'[Send_DateOnly] ),
        ALL ( 'Distribution Status' )
    )
VAR Mode = SELECTEDVALUE(PeriodMode[Mode], "Day")
VAR StartDate =
    SWITCH (
        TRUE(),
        Mode = "Day", MaxDate - (N - 1),
        Mode = "Month", EOMONTH(MaxDate, -N + 1) + 1,
        MaxDate - N
    )
RETURN
CALCULATE (
    COUNT ( 'Distribution Status'[ID_Distribution] ),
    FILTER (
        ALL ( 'Distribution Status'[Send_DateOnly] ),
        'Distribution Status'[Send_DateOnly] >= StartDate
            && 'Distribution Status'[Send_DateOnly] <= MaxDate
    ),
    KEEPFILTERS (
        'Distribution Status'[Distribution_Sending_Status] IN { "VISITED" }
    ),
    KEEPFILTERS ( 'Distribution'[Communication_channel] = "sms" ),
    REMOVEFILTERS ( 'Calendar' ),
    REMOVEFILTERS ( 'PeriodsFilter' )
)

Lógica de Cálculo

La medida calcula el número de mensajes SMS donde los destinatarios visitaron un enlace durante el período dinámico seleccionado. Se usa en el gráfico de tendencias para mostrar la actividad de visitas a enlaces de SMS a lo largo del tiempo.