Przejdź do głównej zawartości

Szukaj

WhatsApp Dashboard - Logika obliczania KPI

kpiwhatsapp1.jpg

Dashboard WhatsApp wyświetla karty KPI, wykresy oraz metryki tabeli szczegółowej dotyczące wydajności komunikacji WhatsApp.

Planned

Opis KPI
Pokazuje łączną liczbę zaplanowanych komunikacji WhatsApp dla wybranego okresu raportowania.

Formuła DAX

CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]),
    'Distribution'[Communication_channel] = "whatsapp"
)

Logika obliczeń
Zlicza wszystkie rekordy dystrybucji, w których kanał komunikacji to whatsapp.

Sent

Opis KPI
Pokazuje liczbę wiadomości WhatsApp, które zostały wysłane lub osiągnęły dowolny status związany z wysyłką.

Formuła DAX

CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]),
    FILTER(
        'Distribution Status',
        'Distribution Status'[Distribution_Sending_Status] IN {
            "DELIVERED", "BOUNCED", "DECLINED", "DEFERRED", "EXPIRED",
            "FAILED", "OLD", "REJECTED", "UNDELIVERABLE", "UNDELIVERED",
            "UNKNOWN", "ENQUEUED", "QUEUED", "SENT", "VISITED", "READ", "SEEN"
        }
        && RELATED('Distribution'[Communication_channel]) = "whatsapp"
    )
)

Logika obliczeń
Zlicza rekordy WhatsApp ze statusami związanymi z wysyłką, takimi jak SENT, DELIVERED, READ, VISITED, BOUNCED, FAILED, REJECTED, UNDELIVERED, UNKNOWN oraz innymi technicznymi statusami wysyłki.

Sent, %

Opis KPI
Pokazuje procent zaplanowanych wiadomości WhatsApp, które zostały wysłane.

Formuła DAX

[Whatsapp Sent] / [Whatsapp Planned]

Logika obliczeń
Dzieli liczbę wysłanych wiadomości WhatsApp przez liczbę zaplanowanych wiadomości WhatsApp.

Delivered

Opis KPI
Pokazuje liczbę wysłanych wiadomości WhatsApp dostarczonych do odbiorców.

Formuła DAX

CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]),
    FILTER(
        'Distribution Status',
        'Distribution Status'[Distribution_Sending_Status] IN {
            "DELIVERED", "READ", "VISITED", "SEEN"
        }
        && RELATED('Distribution'[Communication_channel]) = "whatsapp"
    )
)

Logika obliczeń
Zlicza wiadomości WhatsApp, które osiągnęły etap dostarczenia. Wiadomości z dalszymi statusami zaangażowania, takimi jak READ, VISITED lub SEEN, są również liczone jako dostarczone.

Delivered, %

Opis KPI
Pokazuje procent wysłanych wiadomości WhatsApp, które zostały dostarczone do odbiorców.

Formuła DAX

[Whatsapp Delivered] / [Whatsapp Sent]

Logika obliczeń
Dzieli liczbę dostarczonych wiadomości WhatsApp przez liczbę wysłanych wiadomości WhatsApp.

Read

Opis KPI
Pokazuje liczbę dostarczonych wiadomości WhatsApp przeczytanych przez odbiorców.

Formuła DAX

CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]),
    FILTER(
        'Distribution Status',
        'Distribution Status'[Distribution_Sending_Status] IN {
            "READ", "VISITED", "SEEN"
        }
        && RELATED('Distribution'[Communication_channel]) = "whatsapp"
    )
)

Logika obliczeń
Zlicza wiadomości WhatsApp, które zostały przeczytane lub miały dalsze zaangażowanie po dostarczeniu.

Read, %

Opis KPI
Pokazuje procent dostarczonych wiadomości WhatsApp, które zostały przeczytane przez odbiorców.

Formuła DAX

[Whatsapp Read] / [Whatsapp Delivered]

Logika obliczeń
Dzieli liczbę przeczytanych wiadomości WhatsApp przez liczbę dostarczonych wiadomości WhatsApp.

Visited

Opis KPI
Pokazuje liczbę wiadomości WhatsApp, w których odbiorcy odwiedzili link.

Formuła DAX

CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]),
    FILTER(
        'Distribution Status',
        'Distribution Status'[Distribution_Sending_Status] IN {
            "VISITED"
        }
        && RELATED('Distribution'[Communication_channel]) = "whatsapp"
    )
)

Logika obliczeń
Zlicza rekordy WhatsApp ze statusem VISITED, co oznacza, że odbiorca odwiedził link z wiadomości WhatsApp.

Visited, %

Opis KPI
Pokazuje procent przeczytanych wiadomości WhatsApp, które zakończyły się odwiedzeniem linku.

Formuła DAX

[Whatsapp Visited] / [Whatsapp Read]

Logika obliczeń
Dzieli liczbę wiadomości WhatsApp z odwiedzeniem linku przez liczbę przeczytanych wiadomości WhatsApp.

Unsubscribed

Opis KPI
Pokazuje liczbę odbiorców, którzy wypisali się z komunikacji WhatsApp.

Formuła DAX

CALCULATE(
    COUNT('Unsubscribed'[ID_Unsubscribed]),
    'Distribution'[Communication_channel] = "whatsapp"
)

Logika obliczeń
Zlicza rekordy rezygnacji z subskrypcji, w których kanał komunikacji to whatsapp.

Unsubscribed, %

Opis KPI
Pokazuje procent dostarczonych wiadomości WhatsApp, które doprowadziły do rezygnacji z subskrypcji.

Formuła DAX

[Whatsapp Unsubscribed] / [Whatsapp Delivered]

Logika obliczeń
Dzieli liczbę odbiorców, którzy wypisali się z komunikacji, przez liczbę dostarczonych wiadomości WhatsApp.

Undelivered

Opis KPI
Pokazuje liczbę wysłanych wiadomości WhatsApp, które nie zostały dostarczone do odbiorców i mają określony powód niedostarczenia.

Formuła DAX

CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]),
    FILTER(
        'Distribution Status',
        'Distribution Status'[Distribution_Sending_Status] IN {
            "UNDELIVERED", "UNDELIVERABLE",
            "RESENDING_SMS_UNDELIVERED",
            "RESENDING_SMS_UNDELIVERABLE",
            "EXPIRED", "OLD", "BOUNCED",
            "DEFERRED", "UNKNOWN"
        }
        && RELATED('Distribution'[Communication_channel]) = "whatsapp"
        && TRIM('Distribution Status'[Reason_Undelivered_Whatsapp]) <> ""
        && 'Distribution Status'[Reason_Undelivered_Whatsapp] <> "Пусто"
        && NOT ISBLANK('Distribution Status'[Reason_Undelivered_Whatsapp])
    )
)

Logika obliczeń
Zlicza rekordy WhatsApp ze statusami niedostarczenia i niepustym powodem niedostarczenia. Ten KPI pomaga identyfikować wiadomości, które zostały wysłane, ale nie dotarły do odbiorców.

Undelivered, %

Opis KPI
Pokazuje procent wysłanych wiadomości WhatsApp, które nie zostały dostarczone.

Formuła DAX

[Whatsapp Undelivered] / [Whatsapp Sent]

Logika obliczeń
Dzieli liczbę niedostarczonych wiadomości WhatsApp przez liczbę wysłanych wiadomości WhatsApp.

Unsent

Opis KPI
Pokazuje liczbę zaplanowanych wiadomości WhatsApp, które nie zostały wysłane.

Formuła DAX

CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]),
    FILTER(
        'Distribution Status',
        'Distribution Status'[Distribution_Sending_Status] IN {
            "DUPLICATE", "INVALID_EMAIL", "EMPTY_RECIPIENT",
            "EMPTY_CONTENT", "MESSAGE_LIMIT", "EXCLUDED",
            "UNSUBSCRIBED", "FAILED", "DECLINED", "UNVERIFIED"
        }
        && RELATED('Distribution'[Communication_channel]) = "whatsapp"
    )
)

Logika obliczeń
Zlicza zaplanowane rekordy WhatsApp, które nie zostały wysłane z powodu problemów z danymi, konfiguracją, odbiorcą, treścią, limitem lub walidacją.

Unsent, %

Opis KPI
Pokazuje procent zaplanowanych wiadomości WhatsApp, które nie zostały wysłane.

Formuła DAX

[Whatsapp Unsent] / [Whatsapp Planned]

Logika obliczeń
Dzieli liczbę niewysłanych wiadomości WhatsApp przez liczbę zaplanowanych wiadomości WhatsApp.

Reason Undelivered

Opis KPI
Pokazuje liczbę rekordów WhatsApp z powodem niedostarczenia. Ta miara jest używana na wykresie Reasons for undelivered messages do analizy, dlaczego wiadomości WhatsApp nie zostały dostarczone.

Formuła DAX

CALCULATE(
    COUNT('Distribution Status'[Reason_Undelivered_Emails_Flag]),
    'Distribution'[Communication_channel] = "whatsapp"
)

Logika obliczeń
Zlicza rekordy, w których dostępna jest flaga powodu niedostarczenia dla kanału komunikacji whatsapp.

WhatsApp Devices

Opis KPI
Pokazuje liczbę rekordów odwiedzeń linków według urządzenia dla komunikacji WhatsApp. Ta miara jest używana na wykresie Type of devices from which the link was visited.

Formuła DAX

CALCULATE(
    COUNT('Devices'[ID_Linkstats]),
    'Distribution'[Communication_channel] = "whatsapp"
)

Logika obliczeń
Zlicza rekordy z tabeli Devices, w których kanał komunikacji to whatsapp.

WhatsApp Delivered to Read

Opis KPI
Pokazuje liczbę wiadomości WhatsApp, dla których dostępny jest czas od dostarczenia do przeczytania. Ta miara jest używana w wizualizacji Delivered vs Read.

Formuła DAX

CALCULATE(
    COUNT('Distribution Status'[Time from delivered to read]),
    'Distribution'[Communication_channel] = "whatsapp"
)

Logika obliczeń
Zlicza rekordy WhatsApp, które zawierają wartość w polu Time from delivered to read.

WhatsApp AVG Delivered to Read

Opis KPI
Pokazuje średni czas między dostarczeniem wiadomości WhatsApp a jej przeczytaniem. Wynik jest wyświetlany w formacie HH:MM:SS.

Formuła DAX

VAR TotalSeconds =
    AVERAGEX(
        FILTER(
            'Distribution Status',
            CALCULATE(
                COUNT('Distribution'[ID_Distribution]),
                'Distribution'[Communication_channel] = "whatsapp"
            ) > 0
            && NOT(ISBLANK('Distribution Status'[Difference in seconds 1]))
        ),
        'Distribution Status'[Difference in seconds 1]
    )
VAR Hours = INT(TotalSeconds / 3600)
VAR Minutes = INT(MOD(TotalSeconds, 3600) / 60)
VAR Seconds = MOD(TotalSeconds, 60)
RETURN
    FORMAT(Hours, "00") & ":" &
    FORMAT(Minutes, "00") & ":" &
    FORMAT(Seconds, "00")

Logika obliczeń
Oblicza średnią wartość Difference in seconds 1 dla rekordów WhatsApp, a następnie konwertuje wynik na godziny, minuty i sekundy.

WhatsApp Delivered to Visited

Opis KPI
Pokazuje liczbę wiadomości WhatsApp, dla których dostępny jest czas od dostarczenia do odwiedzenia linku. Ta miara jest używana w wizualizacji Delivered vs Visited.

Formuła DAX

CALCULATE(
    COUNT('Distribution Status'[Time from delivered to visited]),
    'Distribution'[Communication_channel] = "whatsapp"
)

Logika obliczeń
Zlicza rekordy WhatsApp, które zawierają wartość w polu Time from delivered to visited.

WhatsApp AVG Delivered to Visited

Opis KPI
Pokazuje średni czas między dostarczeniem wiadomości WhatsApp a odwiedzeniem linku. Wynik jest wyświetlany w formacie HH:MM:SS.

Formuła DAX

VAR TotalSeconds =
    AVERAGEX(
        FILTER(
            'Distribution Status',
            CALCULATE(
                COUNT('Distribution'[ID_Distribution]),
                'Distribution'[Communication_channel] = "whatsapp"
            ) > 0
            && NOT(ISBLANK('Distribution Status'[Difference in seconds 2]))
        ),
        'Distribution Status'[Difference in seconds 2]
    )
VAR Hours = INT(TotalSeconds / 3600)
VAR Minutes = INT(MOD(TotalSeconds, 3600) / 60)
VAR Seconds = MOD(TotalSeconds, 60)
RETURN
    FORMAT(Hours, "00") & ":" &
    FORMAT(Minutes, "00") & ":" &
    FORMAT(Seconds, "00")

Logika obliczeń
Oblicza średnią wartość Difference in seconds 2 dla rekordów WhatsApp, a następnie konwertuje wynik na godziny, minuty i sekundy.

WhatsApp Delivered Dynamic

Opis KPI
Pokazuje liczbę dostarczonych wiadomości WhatsApp dla wybranego zakresu dni lub miesięcy na wykresie Message Delivery & Engagement Trends.

Formuła DAX

VAR N = [DaysToShow Whatsapp]
VAR MaxDate =
    CALCULATE(
        MAX('Distribution Status'[Send_DateOnly]),
        ALL('Distribution Status')
    )
VAR Mode = SELECTEDVALUE(PeriodMode[Mode], "Day")

VAR StartDate_Day = MaxDate - (N - 1)
VAR StartDate_Month =
    DATE(
        YEAR(EOMONTH(MaxDate, -N + 1)),
        MONTH(EOMONTH(MaxDate, -N + 1)),
        1
    )

VAR StartDate = IF(Mode = "Month", StartDate_Month, StartDate_Day)

RETURN
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]),
    FILTER(
        ALL('Distribution Status'[Send_DateOnly]),
        'Distribution Status'[Send_DateOnly] >= StartDate
            && 'Distribution Status'[Send_DateOnly] <= MaxDate
    ),
    KEEPFILTERS(
        'Distribution Status'[Distribution_Sending_Status] IN {
            "DELIVERED", "READ", "VISITED", "SEEN"
        }
    ),
    KEEPFILTERS('Distribution'[Communication_channel] = "whatsapp"),
    REMOVEFILTERS('Calendar'),
    REMOVEFILTERS('PeriodsFilter')

Logika obliczeń
Oblicza dostarczone wiadomości WhatsApp w wybranym dynamicznym zakresie dat. Zakres zależy od wybranego trybu okresu: Day lub Month.

WhatsApp Read Dynamic

Opis KPI
Pokazuje liczbę przeczytanych wiadomości WhatsApp dla wybranego zakresu dni lub miesięcy na wykresie Message Delivery & Engagement Trends.

Formuła DAX

VAR N = [DaysToShow whatsapp]
VAR MaxDate =
    CALCULATE(
        MAX('Distribution Status'[Send_DateOnly]),
        ALL('Distribution Status')
    )
VAR Mode = SELECTEDVALUE(PeriodMode[Mode], "Day")

VAR StartDate_Day = MaxDate - (N - 1)
VAR StartDate_Month =
    DATE(
        YEAR(EOMONTH(MaxDate, -N + 1)),
        MONTH(EOMONTH(MaxDate, -N + 1)),
        1
    )

VAR StartDate = IF(Mode = "Month", StartDate_Month, StartDate_Day)

RETURN
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]),
    FILTER(
        ALL('Distribution Status'[Send_DateOnly]),
        'Distribution Status'[Send_DateOnly] >= StartDate
            && 'Distribution Status'[Send_DateOnly] <= MaxDate
    ),
    KEEPFILTERS(
        'Distribution Status'[Distribution_Sending_Status] IN {
            "READ", "VISITED", "SEEN"
        }
    ),
    KEEPFILTERS('Distribution'[Communication_channel] = "whatsapp"),
    REMOVEFILTERS('Calendar'),
    REMOVEFILTERS('PeriodsFilter')
)

Logika obliczeń
Oblicza przeczytane wiadomości WhatsApp w wybranym dynamicznym zakresie dat. Wiadomości z dalszymi statusami zaangażowania, takimi jak VISITED lub SEEN, są uwzględniane.

WhatsApp Visited Dynamic

Opis KPI
Pokazuje liczbę wiadomości WhatsApp z odwiedzeniami linków dla wybranego zakresu dni lub miesięcy na wykresie Message Delivery & Engagement Trends.

Formuła DAX

VAR N = [DaysToShow Whatsapp]
VAR MaxDate =
    CALCULATE(
        MAX('Distribution Status'[Send_DateOnly]),
        ALL('Distribution Status')
    )
VAR Mode = SELECTEDVALUE(PeriodMode[Mode], "Day")
VAR StartDate =
    SWITCH(
        TRUE(),
        Mode = "Day", MaxDate - (N - 1),
        Mode = "Month", EOMONTH(MaxDate, -N + 1) + 1,
        MaxDate - N
    )
RETURN
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]),
    FILTER(
        ALL('Distribution Status'[Send_DateOnly]),
        'Distribution Status'[Send_DateOnly] >= StartDate
            && 'Distribution Status'[Send_DateOnly] <= MaxDate
    ),
    KEEPFILTERS(
        'Distribution Status'[Distribution_Sending_Status] IN {
            "VISITED"
        }
    ),
    KEEPFILTERS('Distribution'[Communication_channel] = "whatsapp"),
    REMOVEFILTERS('Calendar'),
    REMOVEFILTERS('PeriodsFilter')

Logika obliczeń
Oblicza odwiedzenia linków WhatsApp w wybranym dynamicznym zakresie dat.

WhatsApp Undelivered Dynamic

Opis KPI
Pokazuje liczbę niedostarczonych wiadomości WhatsApp dla wybranego zakresu dni lub miesięcy na wykresie Message Delivery & Engagement Trends.

Formuła DAX

VAR N = [DaysToShow Whatsapp]
VAR MaxDate =
    CALCULATE(
        MAX('Distribution Status'[Send_DateOnly]),
        ALL('Distribution Status')
    )
VAR Mode = SELECTEDVALUE(PeriodMode[Mode], "Day")
VAR StartDate =
    SWITCH(
        TRUE(),
        Mode = "Day", MaxDate - (N - 1),
        Mode = "Month", EOMONTH(MaxDate, -N + 1) + 1,
        MaxDate - N
    )
RETURN
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]),
    FILTER(
        ALL('Distribution Status'[Send_DateOnly]),
        'Distribution Status'[Send_DateOnly] >= StartDate
            && 'Distribution Status'[Send_DateOnly] <= MaxDate
    ),
    KEEPFILTERS(
        'Distribution Status'[Distribution_Sending_Status] IN {
            "UNDELIVERED", "UNDELIVERABLE",
            "RESENDING_SMS_UNDELIVERED",
            "RESENDING_SMS_UNDELIVERABLE",
            "EXPIRED", "OLD", "BOUNCED",
            "DEFERRED", "UNKNOWN"
        }
    ),
    KEEPFILTERS('Distribution'[Communication_channel] = "whatsapp"),
    REMOVEFILTERS('Calendar'),
    REMOVEFILTERS('PeriodsFilter')

Logika obliczeń
Oblicza niedostarczone wiadomości WhatsApp w wybranym dynamicznym zakresie dat. Nazwa miary w pliku źródłowym jest zapisana jako Whatsapp Undelivred Dynamic.