Logika obliczania KPI na pulpicie Viber – Proxima Research Poland

Pulpit Viber wyświetla karty KPI, wykresy i szczegółowe metryki tabelaryczne dotyczące wydajności komunikacji Viber.

Planowane
Wysłane
Wysłane %
Dostarczone Viber
Dostarczone Viber %
Przeczytane Viber
Przeczytane Viber %
Odwiedzone Viber
Odwiedzone Viber %
Wypisani
Wypisani %
Niedostarczone
Niedostarczone %
Niewysłane
Niewysłane %
Dynamicznie Dostarczone Viber
Dynamicznie Przeczytane Viber
Dynamicznie Niedostarczone Viber
Dynamicznie Odwiedzone Viber

Planowane Viber

Pokazuje łączną liczbę wiadomości Viber zaplanowanych do wysłania w wybranym okresie raportowania.

Formuła DAX

Viber Planned =
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]), 
    'Distribution'[Communication_channel] = "viber"
)

Logika obliczeń

Miara zlicza wszystkie rekordy dystrybucji, gdzie kanał komunikacji to viber.

Reprezentuje całkowitą liczbę zaplanowanych wiadomości Viber dla wybranego okresu raportowania i zastosowanych filtrów.

Wysłane Viber

Pokazuje liczbę wiadomości Viber, które rozpoczęły proces wysyłki, niezależnie od ostatecznego wyniku dostarczenia.

Formuła DAX

Viber Sent =
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]), 
    FILTER(
        'Distribution Status',
        'Distribution Status'[Distribution_Sending_Status] IN {
            "DELIVERED", "BOUNCED", "DECLINED", "DEFERRED", "EXPIRED",
            "FAILED", "OLD", "REJECTED", "UNDELIVERABLE", "UNDELIVERED",
            "UNKNOWN", "ENQUEUED", "QUEUED", "SENT", "VISITED", "READ", "SEEN"
        }
        && RELATED('Distribution'[Communication_channel]) = "viber"
    )
)

Logika obliczeń

Miara zlicza wiadomości Viber o statusach wysyłki wskazujących, że wiadomość rozpoczęła proces wysyłki.

Obejmuje wiadomości dostarczone, przeczytane, odwiedzone lub widziane, a także wiadomości z nieudanymi statusami dostarczenia, takimi jak odbite, nieudane, odrzucone, niedostarczalne lub nieznane.

Wysłane Viber %

Pokazuje procent zaplanowanych wiadomości Viber, które zostały wysłane.

Formuła DAX

Viber Sent % =
[Viber Sent] / [Viber Planned]

Logika obliczeń

Miara oblicza udział zaplanowanych wiadomości Viber, które zostały wysłane.

W przykładzie karty KPI wysłano 1 149 942 wiadomości z 1 616 922 zaplanowanych, co daje 71,12%.

Dostarczone Viber

Pokazuje liczbę wiadomości Viber pomyślnie dostarczonych odbiorcom.

Formuła DAX

Viber Delivered =
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]), 
    FILTER(
        'Distribution Status',
        'Distribution Status'[Distribution_Sending_Status] IN {
            "DELIVERED", "READ", "VISITED", "SEEN"
        }
        && RELATED('Distribution'[Communication_channel]) = "viber"
    )
)

Logika obliczeń

Miara zlicza wiadomości Viber, które zostały pomyślnie dostarczone odbiorcom.

Wiadomości ze statusami READ, VISITED i SEEN są również uwzględnione, ponieważ te działania mogą nastąpić tylko po pomyślnym dostarczeniu.

Dostarczone Viber %

Pokazuje procent wysłanych wiadomości Viber, które zostały pomyślnie dostarczone.

Formuła DAX

Viber Delivered % =
[Viber Delivered] / [Viber Sent]

Logika obliczeń

Miara oblicza udział wysłanych wiadomości Viber, które zostały dostarczone.

W przykładzie karty KPI dostarczono 914 006 wiadomości z 1 149 942 wysłanych, co daje 79,48%.

Przeczytane Viber

Pokazuje liczbę dostarczonych wiadomości Viber przeczytanych lub obejrzanych przez odbiorców.

Formuła DAX

Viber Read =
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]), 
    FILTER(
        'Distribution Status',
        'Distribution Status'[Distribution_Sending_Status] IN {
            "READ", "VISITED", "SEEN"
        }
        && RELATED('Distribution'[Communication_channel]) = "viber"
    )
)

Logika obliczeń

Miara zlicza wiadomości Viber, które zostały przeczytane przez odbiorców.

Wiadomości ze statusami VISITED i SEEN są również uwzględnione, ponieważ wskazują na zaangażowanie odbiorcy po przeczytaniu lub obejrzeniu wiadomości.

Przeczytane Viber %

Pokazuje procent dostarczonych wiadomości Viber, które zostały przeczytane przez odbiorców.

Formuła DAX

Viber Read % =
[Viber Read] / [Viber Delivered]

Logika obliczeń

Miara oblicza udział dostarczonych wiadomości Viber, które zostały przeczytane przez odbiorców.

W przykładzie karty KPI przeczytano 613 848 wiadomości z 914 006 dostarczonych, co daje 67,16%.

Odwiedzone Viber

Pokazuje liczbę wiadomości Viber, które spowodowały odwiedzenie linku przez odbiorcę.

Formuła DAX

Viber Visited =
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]), 
    FILTER(
        'Distribution Status',
        'Distribution Status'[Distribution_Sending_Status] IN { "VISITED" }
        && RELATED('Distribution'[Communication_channel]) = "viber"
    )
)

Logika obliczeń

Miara zlicza wiadomości Viber, w których odbiorcy odwiedzili link z wiadomości.

Pokazuje, ile komunikacji Viber wygenerowało interakcję z linkiem.

Odwiedzone Viber %

Pokazuje procent przeczytanych wiadomości Viber, które spowodowały odwiedzenie linku.

Formuła DAX

Viber Visited % =
[Viber Visited] / [Viber Read]

Logika obliczeń

Miara oblicza udział przeczytanych wiadomości Viber, które spowodowały odwiedzenie linku.

W przykładzie karty KPI 12 047 wiadomości spowodowało odwiedzenie linku z 613 848 przeczytanych, co daje 1,96%.

Wypisani Viber

Pokazuje liczbę odbiorców, którzy wypisali się z komunikacji Viber.

Formuła DAX

Viber Unsubscribed =
CALCULATE(
    COUNT('Unsubscribed'[ID_Unsubscribed]), 
    'Distribution'[Communication_channel] = "viber"
)

Logika obliczeń

Miara zlicza rekordy wypisania dla kanału komunikacji viber.

Pokazuje, ilu odbiorców wypisało się z komunikacji Viber w wybranym okresie raportowania.

Wypisani Viber %

Pokazuje procent dostarczonych wiadomości Viber, które spowodowały wypisanie.

Formuła DAX

Viber Unsubscribe % =
[Viber Unsubscribed] / [Viber Delivered]

Logika obliczeń

Miara oblicza udział dostarczonych wiadomości Viber, które spowodowały wypisanie.

W przykładzie karty KPI pokazano 556 wypisań. Procent wyświetlany na karcie KPI to 0,06%.

Niedostarczone Viber

Pokazuje liczbę wysłanych wiadomości Viber, które nie zostały dostarczone i mają określony powód niedostarczenia.

Formuła DAX

Viber Undelivered =
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]),
    FILTER(
        'Distribution Status',
        'Distribution Status'[Distribution_Sending_Status] IN {
            "UNDELIVERED", "UNDELIVERABLE",
            "RESENDING_SMS_UNDELIVERED",
            "RESENDING_SMS_UNDELIVERABLE",
            "EXPIRED", "OLD", "BOUNCED",
            "DEFERRED", "UNKNOWN"
        }
        && RELATED('Distribution'[Communication_channel]) = "viber"
        && TRIM('Distribution Status'[Reason_Undelivered_Viber]) <> ""
        && 'Distribution Status'[Reason_Undelivered_Viber] <> "Пусто"
        && NOT ISBLANK('Distribution Status'[Reason_Undelivered_Viber])
    )
)

Logika obliczeń

Miara zlicza wysłane wiadomości Viber, które nie zostały dostarczone i mają określony powód niedostarczenia.

Służy do analizy niepowodzeń dostarczenia i identyfikacji wiadomości wymagających wyjaśnienia według powodu.

Niedostarczone Viber %

Pokazuje procent wysłanych wiadomości Viber, które nie zostały dostarczone.

Formuła DAX

Viber Undelivered % =
[Viber Undelivered] / [Viber Sent]

Logika obliczeń

Miara oblicza procent wysłanych wiadomości Viber, które nie zostały dostarczone.

Pomaga ocenić udział niepowodzeń dostarczenia wśród wszystkich wysłanych komunikatów Viber.

Niewysłane Viber

Pokazuje liczbę zaplanowanych wiadomości Viber, które nie zostały wysłane z powodu ograniczeń, nieprawidłowych danych, duplikatów, statusu wypisania lub innych problemów z wysyłką.

Formuła DAX

Viber Unsent =
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]), 
    FILTER(
        'Distribution Status',
        'Distribution Status'[Distribution_Sending_Status] IN {
            "DUPLICATE", "INVALID_EMAIL", "EMPTY_RECIPIENT",
            "EMPTY_CONTENT", "MESSAGE_LIMIT", "EXCLUDED",
            "UNSUBSCRIBED", "FAILED", "DECLINED", "UNVERIFIED"
        }
        && RELATED('Distribution'[Communication_channel]) = "viber"
    )
)

Logika obliczeń

Miara zlicza zaplanowane wiadomości Viber, które nie zostały wysłane z powodu ograniczeń wysyłki, nieprawidłowych lub brakujących danych odbiorcy, statusu wypisania, duplikatów, niepowodzenia przetwarzania lub innych warunków systemowych.

Niewysłane Viber %

Pokazuje procent zaplanowanych wiadomości Viber, które nie zostały wysłane.

Formuła DAX

Viber Unsent % =
[Viber Unsent] / [Viber Planned]

Logika obliczeń

Miara oblicza udział zaplanowanych wiadomości Viber, które nie zostały wysłane.

Pomaga ocenić, ile zaplanowanych komunikatów Viber nie rozpoczęło procesu wysyłki.

Dynamicznie Dostarczone Viber

Pokazuje liczbę dostarczonych wiadomości Viber w czasie dla wybranego okresu dynamicznego.

Formuła DAX

Viber Delivered Dynamic =
VAR N = [DaysToShow Viber]
VAR MaxDate =
    CALCULATE (
        MAX ( 'Distribution Status'[Send_DateOnly] ),
        ALL ( 'Distribution Status' )
    )
VAR Mode = SELECTEDVALUE(PeriodMode[Mode], "Day")
VAR StartDate_Day = MaxDate - (N - 1)
VAR StartDate_Month =
    DATE(
        YEAR ( EOMONTH ( MaxDate, -N + 1 ) ),
        MONTH( EOMONTH ( MaxDate, -N + 1 ) ),
        1
    )
VAR StartDate = IF(Mode = "Month", StartDate_Month, StartDate_Day)
RETURN
CALCULATE (
    COUNT ( 'Distribution Status'[ID_Distribution] ),
    FILTER (
        ALL ( 'Distribution Status'[Send_DateOnly] ),
        'Distribution Status'[Send_DateOnly] >= StartDate
            && 'Distribution Status'[Send_DateOnly] <= MaxDate
    ),
    KEEPFILTERS (
        'Distribution Status'[Distribution_Sending_Status] IN {
            "DELIVERED", "READ", "VISITED", "SEEN"
        }
    ),
    KEEPFILTERS ( 'Distribution'[Communication_channel] = "viber" ),
    REMOVEFILTERS ( 'Calendar' ),
    REMOVEFILTERS ( 'PeriodsFilter' )
)

Logika obliczeń

Miara oblicza liczbę dostarczonych wiadomości Viber dla wybranego okresu dynamicznego.

Używa wartości DaysToShow Viber oraz wybranego trybu okresu, takiego jak Dzień lub Miesiąc, aby zdefiniować zakres dat wyświetlany na wykresie trendów.

Dynamicznie Przeczytane Viber

Pokazuje liczbę przeczytanych wiadomości Viber w czasie dla wybranego okresu dynamicznego.

Formuła DAX

Viber Read Dynamic =
VAR N = [DaysToShow Viber]
VAR MaxDate =
    CALCULATE (
        MAX ( 'Distribution Status'[Send_DateOnly] ),
        ALL ( 'Distribution Status' )
    )
VAR Mode = SELECTEDVALUE(PeriodMode[Mode], "Day")
VAR StartDate_Day = MaxDate - (N - 1)
VAR StartDate_Month =
    DATE(
        YEAR ( EOMONTH ( MaxDate, -N + 1 ) ),
        MONTH( EOMONTH ( MaxDate, -N + 1 ) ),
        1
    )
VAR StartDate = IF(Mode = "Month", StartDate_Month, StartDate_Day)
RETURN
CALCULATE (
    COUNT ( 'Distribution Status'[ID_Distribution] ),
    FILTER (
        ALL ( 'Distribution Status'[Send_DateOnly] ),
        'Distribution Status'[Send_DateOnly] >= StartDate
            && 'Distribution Status'[Send_DateOnly] <= MaxDate
    ),
    KEEPFILTERS (
        'Distribution Status'[Distribution_Sending_Status] IN {
            "READ", "VISITED", "SEEN"
        }
    ),
    KEEPFILTERS ( 'Distribution'[Communication_channel] = "viber" ),
    REMOVEFILTERS ( 'Calendar' ),
    REMOVEFILTERS ( 'PeriodsFilter' )
)

Logika obliczeń

Miara oblicza liczbę przeczytanych wiadomości Viber dla wybranego okresu dynamicznego.

Jest używana na wykresie Trendy dostarczania i zaangażowania wiadomości, aby pokazać, jak zmienia się aktywność czytania w czasie.

Dynamicznie Niedostarczone Viber

Pokazuje liczbę niedostarczonych wiadomości Viber w czasie dla wybranego okresu dynamicznego.

Formuła DAX

Viber Undelivred Dynamic =
VAR N = [DaysToShow Viber]
VAR MaxDate =
    CALCULATE (
        MAX ( 'Distribution Status'[Send_DateOnly] ),
        ALL ( 'Distribution Status' )
    )
VAR Mode = SELECTEDVALUE(PeriodMode[Mode], "Day")
VAR StartDate =
    SWITCH (
        TRUE(),
        Mode = "Day", MaxDate - (N - 1),
        Mode = "Month", EOMONTH(MaxDate, -N + 1) + 1,
        MaxDate - N
    )
RETURN
CALCULATE (
    COUNT ( 'Distribution Status'[ID_Distribution] ),
    FILTER (
        ALL ( 'Distribution Status'[Send_DateOnly] ),
        'Distribution Status'[Send_DateOnly] >= StartDate
            && 'Distribution Status'[Send_DateOnly] <= MaxDate
    ),
    KEEPFILTERS (
        'Distribution Status'[Distribution_Sending_Status] IN {
            "UNDELIVERED", "UNDELIVERABLE",
            "RESENDING_SMS_UNDELIVERED",
            "RESENDING_SMS_UNDELIVERABLE",
            "EXPIRED", "OLD", "BOUNCED",
            "DEFERRED", "UNKNOWN"
        }
    ),
    KEEPFILTERS ( 'Distribution'[Communication_channel] = "viber" ),
    REMOVEFILTERS ( 'Calendar' ),
    REMOVEFILTERS ( 'PeriodsFilter' )
)

Logika obliczeń

Miara oblicza liczbę niedostarczonych wiadomości Viber dla wybranego okresu dynamicznego.

Jest używana na wykresie trendów, aby pokazać dynamikę niepowodzeń dostarczenia w czasie.

Dynamicznie Odwiedzone Viber

Pokazuje liczbę wiadomości Viber z odwiedzinami linków w czasie dla wybranego okresu dynamicznego.

Formuła DAX

Viber Visited Dynamic =
VAR N = [DaysToShow Viber]
VAR MaxDate =
    CALCULATE (
        MAX ( 'Distribution Status'[Send_DateOnly] ),
        ALL ( 'Distribution Status' )
    )
VAR Mode = SELECTEDVALUE(PeriodMode[Mode], "Day")
VAR StartDate =
    SWITCH (
        TRUE(),
        Mode = "Day", MaxDate - (N - 1),
        Mode = "Month", EOMONTH(MaxDate, -N + 1) + 1,
        MaxDate - N
    )
RETURN
CALCULATE (
    COUNT ( 'Distribution Status'[ID_Distribution] ),
    FILTER (
        ALL ( 'Distribution Status'[Send_DateOnly] ),
        'Distribution Status'[Send_DateOnly] >= StartDate
            && 'Distribution Status'[Send_DateOnly] <= MaxDate
    ),
    KEEPFILTERS (
        'Distribution Status'[Distribution_Sending_Status] IN { "VISITED" }
    ),
    KEEPFILTERS ( 'Distribution'[Communication_channel] = "viber" ),
    REMOVEFILTERS ( 'Calendar' ),
    REMOVEFILTERS ( 'PeriodsFilter' )
)

Logika obliczeń

Miara oblicza liczbę wiadomości Viber, w których odbiorcy odwiedzili link w wybranym okresie dynamicznym.

Jest używana na wykresie trendów, aby pokazać, jak zmienia się aktywność odwiedzin linków Viber w czasie.

Szukaj

Planowane Viber

Wysłane Viber

Wysłane Viber %

Dostarczone Viber

Dostarczone Viber %

Przeczytane Viber

Przeczytane Viber %

Odwiedzone Viber

Odwiedzone Viber %

Wypisani Viber

Wypisani Viber %

Niedostarczone Viber

Niedostarczone Viber %

Niewysłane Viber

Niewysłane Viber %

Dynamicznie Dostarczone Viber

Dynamicznie Przeczytane Viber

Dynamicznie Niedostarczone Viber

Dynamicznie Odwiedzone Viber