Lógica de Cálculo dos KPIs do Painel Viber – Proxima Research Brazil

O painel Viber exibe cartões de KPIs, gráficos e métricas detalhadas em tabela para o desempenho da comunicação via Viber.

Planejado
Enviado
% Enviado
Viber Entregue
% Viber Entregue
Viber Lido
% Viber Lido
Viber Visitado
% Viber Visitado
Cancelados
% Cancelamento
Não Entregue
% Não Entregue
Não Enviado
% Não Enviado
Viber Entregue Dinâmico
Viber Lido Dinâmico
Viber Não Entregue Dinâmico
Viber Visitado Dinâmico

Viber Planejado

Mostra o número total de mensagens Viber planejadas para envio durante o período de relatório selecionado.

Fórmula DAX

Viber Planned =
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]), 
    'Distribution'[Communication_channel] = "viber"
)

Lógica de Cálculo

A métrica conta todos os registros de distribuição onde o canal de comunicação é viber.

Representa o número total de mensagens Viber planejadas para o período de relatório e filtros selecionados.

Viber Enviado

Mostra o número de mensagens Viber que entraram no processo de envio, independentemente do resultado final da entrega.

Fórmula DAX

Viber Sent =
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]), 
    FILTER(
        'Distribution Status',
        'Distribution Status'[Distribution_Sending_Status] IN {
            "DELIVERED", "BOUNCED", "DECLINED", "DEFERRED", "EXPIRED",
            "FAILED", "OLD", "REJECTED", "UNDELIVERABLE", "UNDELIVERED",
            "UNKNOWN", "ENQUEUED", "QUEUED", "SENT", "VISITED", "READ", "SEEN"
        }
        && RELATED('Distribution'[Communication_channel]) = "viber"
    )
)

Lógica de Cálculo

A métrica conta mensagens Viber com status de envio que indicam que a mensagem entrou no processo de envio.

Inclui mensagens entregues com sucesso, lidas, visitadas ou visualizadas, assim como mensagens com status de entrega malsucedida, como devolvidas, falhadas, rejeitadas, não entregáveis ou desconhecidas.

% Viber Enviado

Mostra a porcentagem de mensagens Viber planejadas que foram enviadas.

Fórmula DAX

Viber Sent % =
[Viber Sent] / [Viber Planned]

Lógica de Cálculo

A métrica calcula a parcela das mensagens Viber planejadas que foram enviadas.

No exemplo do cartão KPI, 1.149.942 mensagens foram enviadas de um total de 1.616.922 mensagens planejadas, o que equivale a 71,12%.

Viber Entregue

Mostra o número de mensagens Viber entregues com sucesso aos destinatários.

Fórmula DAX

Viber Delivered =
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]), 
    FILTER(
        'Distribution Status',
        'Distribution Status'[Distribution_Sending_Status] IN {
            "DELIVERED", "READ", "VISITED", "SEEN"
        }
        && RELATED('Distribution'[Communication_channel]) = "viber"
    )
)

Lógica de Cálculo

A métrica conta mensagens Viber que foram entregues com sucesso aos destinatários.

Mensagens com status READ, VISITED e SEEN também são incluídas, pois essas ações só podem ocorrer após a entrega bem-sucedida.

% Viber Entregue

Mostra a porcentagem de mensagens Viber enviadas que foram entregues com sucesso.

Fórmula DAX

Viber Delivered % =
[Viber Delivered] / [Viber Sent]

Lógica de Cálculo

A métrica calcula a parcela das mensagens Viber enviadas que foram entregues.

No exemplo do cartão KPI, 914.006 mensagens foram entregues de 1.149.942 mensagens enviadas, o que equivale a 79,48%.

Viber Lido

Mostra o número de mensagens Viber entregues que foram lidas ou visualizadas pelos destinatários.

Fórmula DAX

Viber Read =
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]), 
    FILTER(
        'Distribution Status',
        'Distribution Status'[Distribution_Sending_Status] IN {
            "READ", "VISITED", "SEEN"
        }
        && RELATED('Distribution'[Communication_channel]) = "viber"
    )
)

Lógica de Cálculo

A métrica conta mensagens Viber que foram lidas pelos destinatários.

Mensagens com status VISITED e SEEN também são incluídas, pois indicam engajamento do destinatário após a mensagem ter sido lida ou visualizada.

% Viber Lido

Mostra a porcentagem de mensagens Viber entregues que foram lidas pelos destinatários.

Fórmula DAX

Viber Read % =
[Viber Read] / [Viber Delivered]

Lógica de Cálculo

A métrica calcula a parcela das mensagens Viber entregues que foram lidas pelos destinatários.

No exemplo do cartão KPI, 613.848 mensagens foram lidas de um total de 914.006 entregues, o que equivale a 67,16%.

Viber Visitado

Mostra o número de mensagens Viber que resultaram em uma visita do destinatário a um link.

Fórmula DAX

Viber Visited =
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]), 
    FILTER(
        'Distribution Status',
        'Distribution Status'[Distribution_Sending_Status] IN { "VISITED" }
        && RELATED('Distribution'[Communication_channel]) = "viber"
    )
)

Lógica de Cálculo

A métrica conta mensagens Viber onde os destinatários visitaram um link da mensagem.

Mostra quantas comunicações via Viber geraram interação com links.

% Viber Visitado

Mostra a porcentagem de mensagens Viber lidas que geraram uma visita a link.

Fórmula DAX

Viber Visited % =
[Viber Visited] / [Viber Read]

Lógica de Cálculo

A métrica calcula a parcela das mensagens Viber lidas que resultaram em visita a um link.

No exemplo do cartão KPI, 12.047 mensagens resultaram em visitas a links de um total de 613.848 mensagens lidas, o que equivale a 1,96%.

Viber Cancelados

Mostra o número de destinatários que cancelaram a inscrição nas comunicações via Viber.

Fórmula DAX

Viber Unsubscribed =
CALCULATE(
    COUNT('Unsubscribed'[ID_Unsubscribed]), 
    'Distribution'[Communication_channel] = "viber"
)

Lógica de Cálculo

A métrica conta registros de cancelamento para o canal de comunicação viber.

Mostra quantos destinatários cancelaram a inscrição nas comunicações via Viber durante o período de relatório selecionado.

% Cancelamento Viber

Mostra a porcentagem de mensagens Viber entregues que resultaram em ação de cancelamento.

Fórmula DAX

Viber Unsubscribe % =
[Viber Unsubscribed] / [Viber Delivered]

Lógica de Cálculo

A métrica calcula a parcela das mensagens Viber entregues que resultaram em ação de cancelamento.

No exemplo do cartão KPI, são exibidos 556 registros de cancelamento. A porcentagem mostrada no cartão KPI é 0,06%.

Viber Não Entregue

Mostra o número de mensagens Viber enviadas que não foram entregues e possuem um motivo especificado para a não entrega.

Fórmula DAX

Viber Undelivered =
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]),
    FILTER(
        'Distribution Status',
        'Distribution Status'[Distribution_Sending_Status] IN {
            "UNDELIVERED", "UNDELIVERABLE",
            "RESENDING_SMS_UNDELIVERED",
            "RESENDING_SMS_UNDELIVERABLE",
            "EXPIRED", "OLD", "BOUNCED",
            "DEFERRED", "UNKNOWN"
        }
        && RELATED('Distribution'[Communication_channel]) = "viber"
        && TRIM('Distribution Status'[Reason_Undelivered_Viber]) <> ""
        && 'Distribution Status'[Reason_Undelivered_Viber] <> "Пусто"
        && NOT ISBLANK('Distribution Status'[Reason_Undelivered_Viber])
    )
)

Lógica de Cálculo

A métrica conta mensagens Viber enviadas que não foram entregues e possuem um motivo especificado para a não entrega.

É usada para analisar falhas de entrega e identificar mensagens que requerem investigação pelo motivo.

% Viber Não Entregue

Mostra a porcentagem de mensagens Viber enviadas que não foram entregues.

Fórmula DAX

Viber Undelivered % =
[Viber Undelivered] / [Viber Sent]

Lógica de Cálculo

A métrica calcula a porcentagem de mensagens Viber enviadas que não foram entregues.

Ajuda os usuários a avaliar a parcela de falhas de entrega entre todas as comunicações Viber enviadas.

Viber Não Enviado

Mostra o número de mensagens Viber planejadas que não foram enviadas devido a restrições, dados inválidos, duplicatas, status de cancelamento ou outros problemas de envio.

Fórmula DAX

Viber Unsent =
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]), 
    FILTER(
        'Distribution Status',
        'Distribution Status'[Distribution_Sending_Status] IN {
            "DUPLICATE", "INVALID_EMAIL", "EMPTY_RECIPIENT",
            "EMPTY_CONTENT", "MESSAGE_LIMIT", "EXCLUDED",
            "UNSUBSCRIBED", "FAILED", "DECLINED", "UNVERIFIED"
        }
        && RELATED('Distribution'[Communication_channel]) = "viber"
    )
)

Lógica de Cálculo

A métrica conta mensagens Viber planejadas que não foram enviadas devido a restrições de envio, dados inválidos ou ausentes do destinatário, status de cancelamento, duplicatas, falhas no processamento ou outras condições do sistema.

% Viber Não Enviado

Mostra a porcentagem de mensagens Viber planejadas que não foram enviadas.

Fórmula DAX

Viber Unsent % =
[Viber Unsent] / [Viber Planned]

Lógica de Cálculo

A métrica calcula a parcela das mensagens Viber planejadas que não foram enviadas.

Ajuda os usuários a avaliar quantas comunicações Viber planejadas não entraram no processo de envio.

Viber Entregue Dinâmico

Mostra o número de mensagens Viber entregues ao longo do tempo para o período dinâmico selecionado.

Fórmula DAX

Viber Delivered Dynamic =
VAR N = [DaysToShow Viber]
VAR MaxDate =
    CALCULATE (
        MAX ( 'Distribution Status'[Send_DateOnly] ),
        ALL ( 'Distribution Status' )
    )
VAR Mode = SELECTEDVALUE(PeriodMode[Mode], "Day")
VAR StartDate_Day = MaxDate - (N - 1)
VAR StartDate_Month =
    DATE(
        YEAR ( EOMONTH ( MaxDate, -N + 1 ) ),
        MONTH( EOMONTH ( MaxDate, -N + 1 ) ),
        1
    )
VAR StartDate = IF(Mode = "Month", StartDate_Month, StartDate_Day)
RETURN
CALCULATE (
    COUNT ( 'Distribution Status'[ID_Distribution] ),
    FILTER (
        ALL ( 'Distribution Status'[Send_DateOnly] ),
        'Distribution Status'[Send_DateOnly] >= StartDate
            && 'Distribution Status'[Send_DateOnly] <= MaxDate
    ),
    KEEPFILTERS (
        'Distribution Status'[Distribution_Sending_Status] IN {
            "DELIVERED", "READ", "VISITED", "SEEN"
        }
    ),
    KEEPFILTERS ( 'Distribution'[Communication_channel] = "viber" ),
    REMOVEFILTERS ( 'Calendar' ),
    REMOVEFILTERS ( 'PeriodsFilter' )
)

Lógica de Cálculo

A métrica calcula o número de mensagens Viber entregues para o período dinâmico selecionado.

Utiliza o valor DaysToShow Viber e o modo de período selecionado, como Dia ou Mês, para definir o intervalo de datas exibido no gráfico de tendência.

Viber Lido Dinâmico

Mostra o número de mensagens Viber lidas ao longo do tempo para o período dinâmico selecionado.

Fórmula DAX

Viber Read Dynamic =
VAR N = [DaysToShow Viber]
VAR MaxDate =
    CALCULATE (
        MAX ( 'Distribution Status'[Send_DateOnly] ),
        ALL ( 'Distribution Status' )
    )
VAR Mode = SELECTEDVALUE(PeriodMode[Mode], "Day")
VAR StartDate_Day = MaxDate - (N - 1)
VAR StartDate_Month =
    DATE(
        YEAR ( EOMONTH ( MaxDate, -N + 1 ) ),
        MONTH( EOMONTH ( MaxDate, -N + 1 ) ),
        1
    )
VAR StartDate = IF(Mode = "Month", StartDate_Month, StartDate_Day)
RETURN
CALCULATE (
    COUNT ( 'Distribution Status'[ID_Distribution] ),
    FILTER (
        ALL ( 'Distribution Status'[Send_DateOnly] ),
        'Distribution Status'[Send_DateOnly] >= StartDate
            && 'Distribution Status'[Send_DateOnly] <= MaxDate
    ),
    KEEPFILTERS (
        'Distribution Status'[Distribution_Sending_Status] IN {
            "READ", "VISITED", "SEEN"
        }
    ),
    KEEPFILTERS ( 'Distribution'[Communication_channel] = "viber" ),
    REMOVEFILTERS ( 'Calendar' ),
    REMOVEFILTERS ( 'PeriodsFilter' )
)

Lógica de Cálculo

A métrica calcula o número de mensagens Viber lidas para o período dinâmico selecionado.

É usada no gráfico Tendências de Entrega e Engajamento de Mensagens para mostrar como a atividade de leitura varia ao longo do tempo.

Viber Não Entregue Dinâmico

Mostra o número de mensagens Viber não entregues ao longo do tempo para o período dinâmico selecionado.

Fórmula DAX

Viber Undelivred Dynamic =
VAR N = [DaysToShow Viber]
VAR MaxDate =
    CALCULATE (
        MAX ( 'Distribution Status'[Send_DateOnly] ),
        ALL ( 'Distribution Status' )
    )
VAR Mode = SELECTEDVALUE(PeriodMode[Mode], "Day")
VAR StartDate =
    SWITCH (
        TRUE(),
        Mode = "Day", MaxDate - (N - 1),
        Mode = "Month", EOMONTH(MaxDate, -N + 1) + 1,
        MaxDate - N
    )
RETURN
CALCULATE (
    COUNT ( 'Distribution Status'[ID_Distribution] ),
    FILTER (
        ALL ( 'Distribution Status'[Send_DateOnly] ),
        'Distribution Status'[Send_DateOnly] >= StartDate
            && 'Distribution Status'[Send_DateOnly] <= MaxDate
    ),
    KEEPFILTERS (
        'Distribution Status'[Distribution_Sending_Status] IN {
            "UNDELIVERED", "UNDELIVERABLE",
            "RESENDING_SMS_UNDELIVERED",
            "RESENDING_SMS_UNDELIVERABLE",
            "EXPIRED", "OLD", "BOUNCED",
            "DEFERRED", "UNKNOWN"
        }
    ),
    KEEPFILTERS ( 'Distribution'[Communication_channel] = "viber" ),
    REMOVEFILTERS ( 'Calendar' ),
    REMOVEFILTERS ( 'PeriodsFilter' )
)

Lógica de Cálculo

A métrica calcula o número de mensagens Viber não entregues para o período dinâmico selecionado.

É usada no gráfico de tendência para mostrar a dinâmica das falhas de entrega ao longo do tempo.

Viber Visitado Dinâmico

Mostra o número de mensagens Viber com visitas a links ao longo do tempo para o período dinâmico selecionado.

Fórmula DAX

Viber Visited Dynamic =
VAR N = [DaysToShow Viber]
VAR MaxDate =
    CALCULATE (
        MAX ( 'Distribution Status'[Send_DateOnly] ),
        ALL ( 'Distribution Status' )
    )
VAR Mode = SELECTEDVALUE(PeriodMode[Mode], "Day")
VAR StartDate =
    SWITCH (
        TRUE(),
        Mode = "Day", MaxDate - (N - 1),
        Mode = "Month", EOMONTH(MaxDate, -N + 1) + 1,
        MaxDate - N
    )
RETURN
CALCULATE (
    COUNT ( 'Distribution Status'[ID_Distribution] ),
    FILTER (
        ALL ( 'Distribution Status'[Send_DateOnly] ),
        'Distribution Status'[Send_DateOnly] >= StartDate
            && 'Distribution Status'[Send_DateOnly] <= MaxDate
    ),
    KEEPFILTERS (
        'Distribution Status'[Distribution_Sending_Status] IN { "VISITED" }
    ),
    KEEPFILTERS ( 'Distribution'[Communication_channel] = "viber" ),
    REMOVEFILTERS ( 'Calendar' ),
    REMOVEFILTERS ( 'PeriodsFilter' )
)

Lógica de Cálculo

A métrica calcula o número de mensagens Viber em que os destinatários visitaram um link durante o período dinâmico selecionado.

É usada no gráfico de tendência para mostrar como a atividade de visitas a links via Viber varia ao longo do tempo.

Pesquisa

Viber Planejado

Viber Enviado

% Viber Enviado

Viber Entregue

% Viber Entregue

Viber Lido

% Viber Lido

Viber Visitado

% Viber Visitado

Viber Cancelados

% Cancelamento Viber

Viber Não Entregue

% Viber Não Entregue

Viber Não Enviado

% Viber Não Enviado

Viber Entregue Dinâmico

Viber Lido Dinâmico

Viber Não Entregue Dinâmico

Viber Visitado Dinâmico