Логика расчёта KPI на панели Viber – Proxima Research

Панель Viber отображает карточки KPI, диаграммы и подробные метрики таблиц для оценки эффективности коммуникаций через Viber.

Планируемые
Отправленные
Отправлено %
Доставленные Viber
Доставлено Viber %
Прочитанные Viber
Прочитано Viber %
Посещённые Viber
Посещено Viber %
Отписавшиеся
Отписка %
Недоставленные
Недоставлено %
Неотправленные
Неотправлено %
Динамика доставленных Viber
Динамика прочитанных Viber
Динамика недоставленных Viber
Динамика посещённых Viber

Планируемые Viber

Отображает общее количество сообщений Viber, запланированных к отправке за выбранный отчетный период.

Формула DAX

Viber Planned =
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]), 
    'Distribution'[Communication_channel] = "viber"
)

Логика расчёта

Мера подсчитывает все записи рассылки, где канал коммуникации — viber.

Она показывает общее количество запланированных сообщений Viber за выбранный период и с учётом выбранных фильтров.

Отправленные Viber

Отображает количество сообщений Viber, которые были запущены в процесс отправки, независимо от итогового результата доставки.

Формула DAX

Viber Sent =
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]), 
    FILTER(
        'Distribution Status',
        'Distribution Status'[Distribution_Sending_Status] IN {
            "DELIVERED", "BOUNCED", "DECLINED", "DEFERRED", "EXPIRED",
            "FAILED", "OLD", "REJECTED", "UNDELIVERABLE", "UNDELIVERED",
            "UNKNOWN", "ENQUEUED", "QUEUED", "SENT", "VISITED", "READ", "SEEN"
        }
        && RELATED('Distribution'[Communication_channel]) = "viber"
    )
)

Логика расчёта

Мера подсчитывает сообщения Viber с такими статусами отправки, которые означают, что сообщение вошло в процесс отправки.

Включает сообщения, успешно доставленные, прочитанные, посещённые или просмотренные, а также сообщения с неудачными статусами доставки, такими как bounced, failed, rejected, undeliverable или unknown.

Отправлено Viber %

Отображает процент запланированных сообщений Viber, которые были отправлены.

Формула DAX

Viber Sent % =
[Viber Sent] / [Viber Planned]

Логика расчёта

Мера вычисляет долю запланированных сообщений Viber, которые были отправлены.

В примере на карточке KPI было отправлено 1 149 942 сообщений из 1 616 922 запланированных, что составляет 71,12%.

Доставленные Viber

Отображает количество сообщений Viber, успешно доставленных получателям.

Формула DAX

Viber Delivered =
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]), 
    FILTER(
        'Distribution Status',
        'Distribution Status'[Distribution_Sending_Status] IN {
            "DELIVERED", "READ", "VISITED", "SEEN"
        }
        && RELATED('Distribution'[Communication_channel]) = "viber"
    )
)

Логика расчёта

Мера подсчитывает сообщения Viber, которые были успешно доставлены получателям.

Включены сообщения со статусами READ, VISITED и SEEN, поскольку эти действия возможны только после успешной доставки.

Доставлено Viber %

Отображает процент отправленных сообщений Viber, которые были успешно доставлены.

Формула DAX

Viber Delivered % =
[Viber Delivered] / [Viber Sent]

Логика расчёта

Мера вычисляет долю отправленных сообщений Viber, которые были доставлены.

В примере на карточке KPI было доставлено 914 006 сообщений из 1 149 942 отправленных, что составляет 79,48%.

Прочитанные Viber

Отображает количество доставленных сообщений Viber, которые были прочитаны или просмотрены получателями.

Формула DAX

Viber Read =
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]), 
    FILTER(
        'Distribution Status',
        'Distribution Status'[Distribution_Sending_Status] IN {
            "READ", "VISITED", "SEEN"
        }
        && RELATED('Distribution'[Communication_channel]) = "viber"
    )
)

Логика расчёта

Мера подсчитывает сообщения Viber, которые были прочитаны получателями.

Включены сообщения со статусами VISITED и SEEN, поскольку они указывают на вовлечённость получателя после прочтения или просмотра сообщения.

Прочитано Viber %

Отображает процент доставленных сообщений Viber, которые были прочитаны получателями.

Формула DAX

Viber Read % =
[Viber Read] / [Viber Delivered]

Логика расчёта

Мера вычисляет долю доставленных сообщений Viber, которые были прочитаны получателями.

В примере на карточке KPI было прочитано 613 848 сообщений из 914 006 доставленных, что составляет 67,16%.

Посещённые Viber

Отображает количество сообщений Viber, которые привели к переходу получателя по ссылке.

Формула DAX

Viber Visited =
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]), 
    FILTER(
        'Distribution Status',
        'Distribution Status'[Distribution_Sending_Status] IN { "VISITED" }
        && RELATED('Distribution'[Communication_channel]) = "viber"
    )
)

Логика расчёта

Мера подсчитывает сообщения Viber, при которых получатели перешли по ссылке из сообщения.

Отображает, сколько коммуникаций Viber вызвало взаимодействие со ссылкой.

Посещено Viber %

Отображает процент прочитанных сообщений Viber, которые вызвали переход по ссылке.

Формула DAX

Viber Visited % =
[Viber Visited] / [Viber Read]

Логика расчёта

Мера вычисляет долю прочитанных сообщений Viber, которые привели к переходу по ссылке.

В примере на карточке KPI 12 047 сообщений вызвали переходы по ссылкам из 613 848 прочитанных, что составляет 1,96%.

Отписавшиеся Viber

Отображает количество получателей, которые отписались от коммуникаций Viber.

Формула DAX

Viber Unsubscribed =
CALCULATE(
    COUNT('Unsubscribed'[ID_Unsubscribed]), 
    'Distribution'[Communication_channel] = "viber"
)

Логика расчёта

Мера подсчитывает записи об отписках по каналу коммуникации viber.

Показывает, сколько получателей отписались от коммуникаций Viber за выбранный период.

Отписка Viber %

Отображает процент доставленных сообщений Viber, которые привели к отписке.

Формула DAX

Viber Unsubscribe % =
[Viber Unsubscribed] / [Viber Delivered]

Логика расчёта

Мера вычисляет долю доставленных сообщений Viber, которые привели к отписке.

В примере на карточке KPI показано 556 записей об отписке. Процент в карточке KPI составляет 0,06%.

Недоставленные Viber

Отображает количество отправленных сообщений Viber, которые не были доставлены и имеют указанную причину недоставки.

Формула DAX

Viber Undelivered =
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]),
    FILTER(
        'Distribution Status',
        'Distribution Status'[Distribution_Sending_Status] IN {
            "UNDELIVERED", "UNDELIVERABLE",
            "RESENDING_SMS_UNDELIVERED",
            "RESENDING_SMS_UNDELIVERABLE",
            "EXPIRED", "OLD", "BOUNCED",
            "DEFERRED", "UNKNOWN"
        }
        && RELATED('Distribution'[Communication_channel]) = "viber"
        && TRIM('Distribution Status'[Reason_Undelivered_Viber]) <> ""
        && 'Distribution Status'[Reason_Undelivered_Viber] <> "Пусто"
        && NOT ISBLANK('Distribution Status'[Reason_Undelivered_Viber])
    )
)

Логика расчёта

Мера подсчитывает отправленные сообщения Viber, которые не были доставлены и имеют указанную причину недоставки.

Используется для анализа сбоев доставки и выявления сообщений, требующих расследования по причине.

Недоставлено Viber %

Отображает процент отправленных сообщений Viber, которые не были доставлены.

Формула DAX

Viber Undelivered % =
[Viber Undelivered] / [Viber Sent]

Логика расчёта

Мера вычисляет процент отправленных сообщений Viber, которые не были доставлены.

Помогает пользователям оценить долю сбоев доставки среди всех отправленных коммуникаций Viber.

Неотправленные Viber

Отображает количество запланированных сообщений Viber, которые не были отправлены из-за ограничений, некорректных данных, дубликатов, статуса отписки или других проблем с отправкой.

Формула DAX

Viber Unsent =
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]), 
    FILTER(
        'Distribution Status',
        'Distribution Status'[Distribution_Sending_Status] IN {
            "DUPLICATE", "INVALID_EMAIL", "EMPTY_RECIPIENT",
            "EMPTY_CONTENT", "MESSAGE_LIMIT", "EXCLUDED",
            "UNSUBSCRIBED", "FAILED", "DECLINED", "UNVERIFIED"
        }
        && RELATED('Distribution'[Communication_channel]) = "viber"
    )
)

Логика расчёта

Мера подсчитывает запланированные сообщения Viber, которые не были отправлены из-за ограничений отправки, некорректных или отсутствующих данных получателя, статуса отписки, дубликатов, сбоев обработки или других системных условий.

Неотправлено Viber %

Отображает процент запланированных сообщений Viber, которые не были отправлены.

Формула DAX

Viber Unsent % =
[Viber Unsent] / [Viber Planned]

Логика расчёта

Мера вычисляет долю запланированных сообщений Viber, которые не были отправлены.

Помогает пользователям оценить, сколько запланированных коммуникаций Viber не вошли в процесс отправки.

Динамика доставленных Viber

Отображает количество доставленных сообщений Viber за выбранный динамический период.

Формула DAX

Viber Delivered Dynamic =
VAR N = [DaysToShow Viber]
VAR MaxDate =
    CALCULATE (
        MAX ( 'Distribution Status'[Send_DateOnly] ),
        ALL ( 'Distribution Status' )
    )
VAR Mode = SELECTEDVALUE(PeriodMode[Mode], "Day")
VAR StartDate_Day = MaxDate - (N - 1)
VAR StartDate_Month =
    DATE(
        YEAR ( EOMONTH ( MaxDate, -N + 1 ) ),
        MONTH( EOMONTH ( MaxDate, -N + 1 ) ),
        1
    )
VAR StartDate = IF(Mode = "Month", StartDate_Month, StartDate_Day)
RETURN
CALCULATE (
    COUNT ( 'Distribution Status'[ID_Distribution] ),
    FILTER (
        ALL ( 'Distribution Status'[Send_DateOnly] ),
        'Distribution Status'[Send_DateOnly] >= StartDate
            && 'Distribution Status'[Send_DateOnly] <= MaxDate
    ),
    KEEPFILTERS (
        'Distribution Status'[Distribution_Sending_Status] IN {
            "DELIVERED", "READ", "VISITED", "SEEN"
        }
    ),
    KEEPFILTERS ( 'Distribution'[Communication_channel] = "viber" ),
    REMOVEFILTERS ( 'Calendar' ),
    REMOVEFILTERS ( 'PeriodsFilter' )
)

Логика расчёта

Мера вычисляет количество доставленных сообщений Viber за выбранный динамический период.

Использует значение DaysToShow Viber и выбранный режим периода, например День или Месяц, чтобы определить диапазон дат, отображаемый на графике трендов.

Динамика прочитанных Viber

Отображает количество прочитанных сообщений Viber за выбранный динамический период.

Формула DAX

Viber Read Dynamic =
VAR N = [DaysToShow Viber]
VAR MaxDate =
    CALCULATE (
        MAX ( 'Distribution Status'[Send_DateOnly] ),
        ALL ( 'Distribution Status' )
    )
VAR Mode = SELECTEDVALUE(PeriodMode[Mode], "Day")
VAR StartDate_Day = MaxDate - (N - 1)
VAR StartDate_Month =
    DATE(
        YEAR ( EOMONTH ( MaxDate, -N + 1 ) ),
        MONTH( EOMONTH ( MaxDate, -N + 1 ) ),
        1
    )
VAR StartDate = IF(Mode = "Month", StartDate_Month, StartDate_Day)
RETURN
CALCULATE (
    COUNT ( 'Distribution Status'[ID_Distribution] ),
    FILTER (
        ALL ( 'Distribution Status'[Send_DateOnly] ),
        'Distribution Status'[Send_DateOnly] >= StartDate
            && 'Distribution Status'[Send_DateOnly] <= MaxDate
    ),
    KEEPFILTERS (
        'Distribution Status'[Distribution_Sending_Status] IN {
            "READ", "VISITED", "SEEN"
        }
    ),
    KEEPFILTERS ( 'Distribution'[Communication_channel] = "viber" ),
    REMOVEFILTERS ( 'Calendar' ),
    REMOVEFILTERS ( 'PeriodsFilter' )
)

Логика расчёта

Мера вычисляет количество прочитанных сообщений Viber за выбранный динамический период.

Используется в диаграмме Тенденции доставки и вовлечённости сообщений для отображения изменений активности чтения со временем.

Динамика недоставленных Viber

Отображает количество недоставленных сообщений Viber за выбранный динамический период.

Формула DAX

Viber Undelivred Dynamic =
VAR N = [DaysToShow Viber]
VAR MaxDate =
    CALCULATE (
        MAX ( 'Distribution Status'[Send_DateOnly] ),
        ALL ( 'Distribution Status' )
    )
VAR Mode = SELECTEDVALUE(PeriodMode[Mode], "Day")
VAR StartDate =
    SWITCH (
        TRUE(),
        Mode = "Day", MaxDate - (N - 1),
        Mode = "Month", EOMONTH(MaxDate, -N + 1) + 1,
        MaxDate - N
    )
RETURN
CALCULATE (
    COUNT ( 'Distribution Status'[ID_Distribution] ),
    FILTER (
        ALL ( 'Distribution Status'[Send_DateOnly] ),
        'Distribution Status'[Send_DateOnly] >= StartDate
            && 'Distribution Status'[Send_DateOnly] <= MaxDate
    ),
    KEEPFILTERS (
        'Distribution Status'[Distribution_Sending_Status] IN {
            "UNDELIVERED", "UNDELIVERABLE",
            "RESENDING_SMS_UNDELIVERED",
            "RESENDING_SMS_UNDELIVERABLE",
            "EXPIRED", "OLD", "BOUNCED",
            "DEFERRED", "UNKNOWN"
        }
    ),
    KEEPFILTERS ( 'Distribution'[Communication_channel] = "viber" ),
    REMOVEFILTERS ( 'Calendar' ),
    REMOVEFILTERS ( 'PeriodsFilter' )
)

Логика расчёта

Мера вычисляет количество недоставленных сообщений Viber за выбранный динамический период.

Используется на графике трендов для отображения динамики сбоев доставки со временем.

Динамика посещённых Viber

Отображает количество сообщений Viber с переходами по ссылкам за выбранный динамический период.

Формула DAX

Viber Visited Dynamic =
VAR N = [DaysToShow Viber]
VAR MaxDate =
    CALCULATE (
        MAX ( 'Distribution Status'[Send_DateOnly] ),
        ALL ( 'Distribution Status' )
    )
VAR Mode = SELECTEDVALUE(PeriodMode[Mode], "Day")
VAR StartDate =
    SWITCH (
        TRUE(),
        Mode = "Day", MaxDate - (N - 1),
        Mode = "Month", EOMONTH(MaxDate, -N + 1) + 1,
        MaxDate - N
    )
RETURN
CALCULATE (
    COUNT ( 'Distribution Status'[ID_Distribution] ),
    FILTER (
        ALL ( 'Distribution Status'[Send_DateOnly] ),
        'Distribution Status'[Send_DateOnly] >= StartDate
            && 'Distribution Status'[Send_DateOnly] <= MaxDate
    ),
    KEEPFILTERS (
        'Distribution Status'[Distribution_Sending_Status] IN { "VISITED" }
    ),
    KEEPFILTERS ( 'Distribution'[Communication_channel] = "viber" ),
    REMOVEFILTERS ( 'Calendar' ),
    REMOVEFILTERS ( 'PeriodsFilter' )
)

Логика расчёта

Мера вычисляет количество сообщений Viber, при которых получатели переходили по ссылке в выбранный динамический период.

Используется на графике трендов для отображения изменений активности переходов по ссылкам в Viber со временем.

Поиск

Планируемые Viber

Отправленные Viber

Отправлено Viber %

Доставленные Viber

Доставлено Viber %

Прочитанные Viber

Прочитано Viber %

Посещённые Viber

Посещено Viber %

Отписавшиеся Viber

Отписка Viber %

Недоставленные Viber

Недоставлено Viber %

Неотправленные Viber

Неотправлено Viber %

Динамика доставленных Viber

Динамика прочитанных Viber

Динамика недоставленных Viber

Динамика посещённых Viber