Viber Dashboard KPI Calculation Logic – Proxima Research International

The Viber dashboard displays KPI cards, charts, and detailed table metrics for Viber communication performance.

Planned
Sent
Sent %
Viber Delivered
Viber Delivered %
Viber Read
Viber Read %
Viber Visited
Viber Visited %
Unsubscribed
Unsubscribe %
Undelivered
Undelivered %
Unsent
Unsent %
Viber Delivered Dynamic
Viber Read Dynamic
Viber Undelivered Dynamic
Viber Visited Dynamic

Viber Planned

Shows the total number of Viber messages planned for sending during the selected reporting period.

DAX Formula

Viber Planned =
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]), 
    'Distribution'[Communication_channel] = "viber"
)

Calculation Logic

The measure counts all distribution records where the communication channel is viber.

It represents the total number of planned Viber messages for the selected reporting period and selected filters.

Viber Sent

Shows the number of Viber messages that entered the sending process, regardless of final delivery result.

DAX Formula

Viber Sent =
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]), 
    FILTER(
        'Distribution Status',
        'Distribution Status'[Distribution_Sending_Status] IN {
            "DELIVERED", "BOUNCED", "DECLINED", "DEFERRED", "EXPIRED",
            "FAILED", "OLD", "REJECTED", "UNDELIVERABLE", "UNDELIVERED",
            "UNKNOWN", "ENQUEUED", "QUEUED", "SENT", "VISITED", "READ", "SEEN"
        }
        && RELATED('Distribution'[Communication_channel]) = "viber"
    )
)

Calculation Logic

The measure counts Viber messages with sending statuses that indicate the message entered the sending process.

It includes messages that were successfully delivered, read, visited, or seen, as well as messages with unsuccessful delivery statuses such as bounced, failed, rejected, undeliverable, or unknown.

Viber Sent %

Shows the percentage of planned Viber messages that were sent.

DAX Formula

Viber Sent % =
[Viber Sent] / [Viber Planned]

Calculation Logic

The measure calculates the share of planned Viber messages that were sent.

In the KPI card example, 1,149,942 messages were sent out of 1,616,922 planned messages, which equals 71.12%.

Viber Delivered

Shows the number of Viber messages successfully delivered to recipients.

DAX Formula

Viber Delivered =
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]), 
    FILTER(
        'Distribution Status',
        'Distribution Status'[Distribution_Sending_Status] IN {
            "DELIVERED", "READ", "VISITED", "SEEN"
        }
        && RELATED('Distribution'[Communication_channel]) = "viber"
    )
)

Calculation Logic

The measure counts Viber messages that were successfully delivered to recipients.

Messages with statuses READ, VISITED, and SEEN are also included because these actions can only happen after successful delivery.

Viber Delivered %

Shows the percentage of sent Viber messages that were successfully delivered.

DAX Formula

Viber Delivered % =
[Viber Delivered] / [Viber Sent]

Calculation Logic

The measure calculates the share of sent Viber messages that were delivered.

In the KPI card example, 914,006 messages were delivered out of 1,149,942 sent messages, which equals 79.48%.

Viber Read

Shows the number of delivered Viber messages read or seen by recipients.

DAX Formula

Viber Read =
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]), 
    FILTER(
        'Distribution Status',
        'Distribution Status'[Distribution_Sending_Status] IN {
            "READ", "VISITED", "SEEN"
        }
        && RELATED('Distribution'[Communication_channel]) = "viber"
    )
)

Calculation Logic

The measure counts Viber messages that were read by recipients.

Messages with statuses VISITED and SEEN are also included because they indicate recipient engagement after the message was read or seen.

Viber Read %

Shows the percentage of delivered Viber messages that were read by recipients.

DAX Formula

Viber Read % =
[Viber Read] / [Viber Delivered]

Calculation Logic

The measure calculates the share of delivered Viber messages that were read by recipients.

In the KPI card example, 613,848 messages were read out of 914,006 delivered messages, which equals 67.16%.

Viber Visited

Shows the number of Viber messages that resulted in a recipient visiting a link.

DAX Formula

Viber Visited =
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]), 
    FILTER(
        'Distribution Status',
        'Distribution Status'[Distribution_Sending_Status] IN { "VISITED" }
        && RELATED('Distribution'[Communication_channel]) = "viber"
    )
)

Calculation Logic

The measure counts Viber messages where recipients visited a link from the message.

It shows how many Viber communications generated link interaction.

Viber Visited %

Shows the percentage of read Viber messages that generated a link visit.

DAX Formula

Viber Visited % =
[Viber Visited] / [Viber Read]

Calculation Logic

The measure calculates the share of read Viber messages that resulted in a link visit.

In the KPI card example, 12,047 messages resulted in link visits out of 613,848 read messages, which equals 1.96%.

Viber Unsubscribed

Shows the number of recipients who unsubscribed from Viber communications.

DAX Formula

Viber Unsubscribed =
CALCULATE(
    COUNT('Unsubscribed'[ID_Unsubscribed]), 
    'Distribution'[Communication_channel] = "viber"
)

Calculation Logic

The measure counts unsubscribe records for the viber communication channel.

It shows how many recipients unsubscribed from Viber communications during the selected reporting period.

Viber Unsubscribe %

Shows the percentage of delivered Viber messages that resulted in an unsubscribe action.

DAX Formula

Viber Unsubscribe % =
[Viber Unsubscribed] / [Viber Delivered]

Calculation Logic

The measure calculates the share of delivered Viber messages that resulted in an unsubscribe action.

In the KPI card example, 556 unsubscribe records are shown. The percentage displayed in the KPI card is 0.06%.

Viber Undelivered

Shows the number of sent Viber messages that were not delivered and have a specified undelivered reason.

DAX Formula

Viber Undelivered =
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]),
    FILTER(
        'Distribution Status',
        'Distribution Status'[Distribution_Sending_Status] IN {
            "UNDELIVERED", "UNDELIVERABLE",
            "RESENDING_SMS_UNDELIVERED",
            "RESENDING_SMS_UNDELIVERABLE",
            "EXPIRED", "OLD", "BOUNCED",
            "DEFERRED", "UNKNOWN"
        }
        && RELATED('Distribution'[Communication_channel]) = "viber"
        && TRIM('Distribution Status'[Reason_Undelivered_Viber]) <> ""
        && 'Distribution Status'[Reason_Undelivered_Viber] <> "Пусто"
        && NOT ISBLANK('Distribution Status'[Reason_Undelivered_Viber])
    )
)

Calculation Logic

The measure counts sent Viber messages that were not delivered and have a specified undelivered reason.

It is used to analyze delivery failures and identify messages that require investigation by reason.

Viber Undelivered %

Shows the percentage of sent Viber messages that were not delivered.

DAX Formula

Viber Undelivered % =
[Viber Undelivered] / [Viber Sent]

Calculation Logic

The measure calculates the percentage of sent Viber messages that were not delivered.

It helps users evaluate the share of delivery failures among all sent Viber communications.

Viber Unsent

Shows the number of planned Viber messages that were not sent because of restrictions, invalid data, duplicates, unsubscribe status, or other sending issues.

DAX Formula

Viber Unsent =
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]), 
    FILTER(
        'Distribution Status',
        'Distribution Status'[Distribution_Sending_Status] IN {
            "DUPLICATE", "INVALID_EMAIL", "EMPTY_RECIPIENT",
            "EMPTY_CONTENT", "MESSAGE_LIMIT", "EXCLUDED",
            "UNSUBSCRIBED", "FAILED", "DECLINED", "UNVERIFIED"
        }
        && RELATED('Distribution'[Communication_channel]) = "viber"
    )
)

Calculation Logic

The measure counts planned Viber messages that were not sent because of sending restrictions, invalid or missing recipient data, unsubscribe status, duplicates, failed processing, or other system conditions.

Viber Unsent %

Shows the percentage of planned Viber messages that were not sent.

DAX Formula

Viber Unsent % =
[Viber Unsent] / [Viber Planned]

Calculation Logic

The measure calculates the share of planned Viber messages that were not sent.

It helps users evaluate how many planned Viber communications did not enter the sending process.

Viber Delivered Dynamic

Shows the number of delivered Viber messages over time for the selected dynamic period.

DAX Formula

Viber Delivered Dynamic =
VAR N = [DaysToShow Viber]
VAR MaxDate =
    CALCULATE (
        MAX ( 'Distribution Status'[Send_DateOnly] ),
        ALL ( 'Distribution Status' )
    )
VAR Mode = SELECTEDVALUE(PeriodMode[Mode], "Day")
VAR StartDate_Day = MaxDate - (N - 1)
VAR StartDate_Month =
    DATE(
        YEAR ( EOMONTH ( MaxDate, -N + 1 ) ),
        MONTH( EOMONTH ( MaxDate, -N + 1 ) ),
        1
    )
VAR StartDate = IF(Mode = "Month", StartDate_Month, StartDate_Day)
RETURN
CALCULATE (
    COUNT ( 'Distribution Status'[ID_Distribution] ),
    FILTER (
        ALL ( 'Distribution Status'[Send_DateOnly] ),
        'Distribution Status'[Send_DateOnly] >= StartDate
            && 'Distribution Status'[Send_DateOnly] <= MaxDate
    ),
    KEEPFILTERS (
        'Distribution Status'[Distribution_Sending_Status] IN {
            "DELIVERED", "READ", "VISITED", "SEEN"
        }
    ),
    KEEPFILTERS ( 'Distribution'[Communication_channel] = "viber" ),
    REMOVEFILTERS ( 'Calendar' ),
    REMOVEFILTERS ( 'PeriodsFilter' )
)

Calculation Logic

The measure calculates the number of delivered Viber messages for the selected dynamic period.

It uses the DaysToShow Viber value and selected period mode, such as Day or Month, to define the date range displayed in the trend chart.

Viber Read Dynamic

Shows the number of read Viber messages over time for the selected dynamic period.

DAX Formula

Viber Read Dynamic =
VAR N = [DaysToShow Viber]
VAR MaxDate =
    CALCULATE (
        MAX ( 'Distribution Status'[Send_DateOnly] ),
        ALL ( 'Distribution Status' )
    )
VAR Mode = SELECTEDVALUE(PeriodMode[Mode], "Day")
VAR StartDate_Day = MaxDate - (N - 1)
VAR StartDate_Month =
    DATE(
        YEAR ( EOMONTH ( MaxDate, -N + 1 ) ),
        MONTH( EOMONTH ( MaxDate, -N + 1 ) ),
        1
    )
VAR StartDate = IF(Mode = "Month", StartDate_Month, StartDate_Day)
RETURN
CALCULATE (
    COUNT ( 'Distribution Status'[ID_Distribution] ),
    FILTER (
        ALL ( 'Distribution Status'[Send_DateOnly] ),
        'Distribution Status'[Send_DateOnly] >= StartDate
            && 'Distribution Status'[Send_DateOnly] <= MaxDate
    ),
    KEEPFILTERS (
        'Distribution Status'[Distribution_Sending_Status] IN {
            "READ", "VISITED", "SEEN"
        }
    ),
    KEEPFILTERS ( 'Distribution'[Communication_channel] = "viber" ),
    REMOVEFILTERS ( 'Calendar' ),
    REMOVEFILTERS ( 'PeriodsFilter' )
)

Calculation Logic

The measure calculates the number of read Viber messages for the selected dynamic period.

It is used in the Message Delivery & Engagement Trends chart to show how read activity changes over time.

Viber Undelivered Dynamic

Shows the number of undelivered Viber messages over time for the selected dynamic period.

DAX Formula

Viber Undelivred Dynamic =
VAR N = [DaysToShow Viber]
VAR MaxDate =
    CALCULATE (
        MAX ( 'Distribution Status'[Send_DateOnly] ),
        ALL ( 'Distribution Status' )
    )
VAR Mode = SELECTEDVALUE(PeriodMode[Mode], "Day")
VAR StartDate =
    SWITCH (
        TRUE(),
        Mode = "Day", MaxDate - (N - 1),
        Mode = "Month", EOMONTH(MaxDate, -N + 1) + 1,
        MaxDate - N
    )
RETURN
CALCULATE (
    COUNT ( 'Distribution Status'[ID_Distribution] ),
    FILTER (
        ALL ( 'Distribution Status'[Send_DateOnly] ),
        'Distribution Status'[Send_DateOnly] >= StartDate
            && 'Distribution Status'[Send_DateOnly] <= MaxDate
    ),
    KEEPFILTERS (
        'Distribution Status'[Distribution_Sending_Status] IN {
            "UNDELIVERED", "UNDELIVERABLE",
            "RESENDING_SMS_UNDELIVERED",
            "RESENDING_SMS_UNDELIVERABLE",
            "EXPIRED", "OLD", "BOUNCED",
            "DEFERRED", "UNKNOWN"
        }
    ),
    KEEPFILTERS ( 'Distribution'[Communication_channel] = "viber" ),
    REMOVEFILTERS ( 'Calendar' ),
    REMOVEFILTERS ( 'PeriodsFilter' )
)

Calculation Logic

The measure calculates the number of undelivered Viber messages for the selected dynamic period.

It is used in the trend chart to show delivery failure dynamics over time.

Viber Visited Dynamic

Shows the number of Viber messages with link visits over time for the selected dynamic period.

DAX Formula

Viber Visited Dynamic =
VAR N = [DaysToShow Viber]
VAR MaxDate =
    CALCULATE (
        MAX ( 'Distribution Status'[Send_DateOnly] ),
        ALL ( 'Distribution Status' )
    )
VAR Mode = SELECTEDVALUE(PeriodMode[Mode], "Day")
VAR StartDate =
    SWITCH (
        TRUE(),
        Mode = "Day", MaxDate - (N - 1),
        Mode = "Month", EOMONTH(MaxDate, -N + 1) + 1,
        MaxDate - N
    )
RETURN
CALCULATE (
    COUNT ( 'Distribution Status'[ID_Distribution] ),
    FILTER (
        ALL ( 'Distribution Status'[Send_DateOnly] ),
        'Distribution Status'[Send_DateOnly] >= StartDate
            && 'Distribution Status'[Send_DateOnly] <= MaxDate
    ),
    KEEPFILTERS (
        'Distribution Status'[Distribution_Sending_Status] IN { "VISITED" }
    ),
    KEEPFILTERS ( 'Distribution'[Communication_channel] = "viber" ),
    REMOVEFILTERS ( 'Calendar' ),
    REMOVEFILTERS ( 'PeriodsFilter' )
)

Calculation Logic

The measure calculates the number of Viber messages where recipients visited a link during the selected dynamic period.

It is used in the trend chart to show how Viber link visit activity changes over time.

Search

Viber Planned

Viber Sent

Viber Sent %

Viber Delivered

Viber Delivered %

Viber Read

Viber Read %

Viber Visited

Viber Visited %

Viber Unsubscribed

Viber Unsubscribe %

Viber Undelivered

Viber Undelivered %

Viber Unsent

Viber Unsent %

Viber Delivered Dynamic

Viber Read Dynamic

Viber Undelivered Dynamic

Viber Visited Dynamic