Saltar al contenido principal

Búsqueda

WhatsApp Dashboard - Lógica de cálculo de KPI

kpiwhatsapp1.jpg

El dashboard WhatsApp muestra tarjetas KPI, gráficos y métricas de la tabla detallada para el rendimiento de la comunicación de WhatsApp.

Planned

Descripción del KPI

Muestra el número total de comunicaciones de WhatsApp planificadas para el período de informe seleccionado.

Fórmula DAX

CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]),
    'Distribution'[Communication_channel] = "whatsapp"
)

Lógica de cálculo

Cuenta todos los registros de distribución donde el canal de comunicación es whatsapp.

Sent

Descripción del KPI

Muestra el número de mensajes de WhatsApp que fueron enviados o alcanzaron cualquier estado relacionado con el envío.

Fórmula DAX

CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]),
    FILTER(
        'Distribution Status',
        'Distribution Status'[Distribution_Sending_Status] IN {
            "DELIVERED", "BOUNCED", "DECLINED", "DEFERRED", "EXPIRED",
            "FAILED", "OLD", "REJECTED", "UNDELIVERABLE", "UNDELIVERED",
            "UNKNOWN", "ENQUEUED", "QUEUED", "SENT", "VISITED", "READ", "SEEN"
        }
        && RELATED('Distribution'[Communication_channel]) = "whatsapp"
    )
)

Lógica de cálculo

Cuenta registros de WhatsApp con estados relacionados con el envío, como SENT, DELIVERED, READ, VISITED, BOUNCED, FAILED, REJECTED, UNDELIVERED, UNKNOWN y otros estados técnicos de envío.

Sent, %

Descripción del KPI

Muestra el porcentaje de mensajes de WhatsApp planificados que fueron enviados.

Fórmula DAX

Whatsapp Sent % =
[Whatsapp Sent] / [Whatsapp Planned]

Lógica de cálculo

Divide el número de mensajes de WhatsApp enviados entre el número de mensajes de WhatsApp planificados.

Delivered

Descripción del KPI

Muestra el número de mensajes de WhatsApp enviados que fueron entregados a los destinatarios.

Fórmula DAX

Whatsapp Delivered =
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]),
    FILTER(
        'Distribution Status',
        'Distribution Status'[Distribution_Sending_Status] IN {
            "DELIVERED", "READ", "VISITED", "SEEN"
        }
        && RELATED('Distribution'[Communication_channel]) = "whatsapp"
    )
)

Lógica de cálculo

Cuenta los mensajes de WhatsApp que alcanzaron la etapa de entrega. Los mensajes con estados de engagement posterior, como READ, VISITED o SEEN, también se cuentan como entregados.

Delivered, %

Descripción del KPI

Muestra el porcentaje de mensajes de WhatsApp enviados que fueron entregados a los destinatarios.

Fórmula DAX

Whatsapp Delivered % =
[Whatsapp Delivered] / [Whatsapp Sent]

Lógica de cálculo

Divide el número de mensajes de WhatsApp entregados entre el número de mensajes de WhatsApp enviados.

Read

Descripción del KPI

Muestra el número de mensajes de WhatsApp entregados que fueron leídos por los destinatarios.

Fórmula DAX

CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]),
    FILTER(
        'Distribution Status',
        'Distribution Status'[Distribution_Sending_Status] IN {
            "READ", "VISITED", "SEEN"
        }
        && RELATED('Distribution'[Communication_channel]) = "whatsapp"
    )
)

Lógica de cálculo

Cuenta los mensajes de WhatsApp que fueron leídos o tuvieron engagement adicional después de la entrega.

Read, %

Descripción del KPI

Muestra el porcentaje de mensajes de WhatsApp entregados que fueron leídos por los destinatarios.

Fórmula DAX

[Whatsapp Read] / [Whatsapp Delivered]

Lógica de cálculo

Divide el número de mensajes de WhatsApp leídos entre el número de mensajes de WhatsApp entregados.

Visited

Descripción del KPI

Muestra el número de mensajes de WhatsApp en los que los destinatarios visitaron un enlace.

Fórmula DAX

CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]),
    FILTER(
        'Distribution Status',
        'Distribution Status'[Distribution_Sending_Status] IN {
            "VISITED"
        }
        && RELATED('Distribution'[Communication_channel]) = "whatsapp"
    )
)

Lógica de cálculo

Cuenta registros de WhatsApp con el estado VISITED, lo que significa que el destinatario visitó un enlace desde el mensaje de WhatsApp.

Visited, %

Descripción del KPI

Muestra el porcentaje de mensajes de WhatsApp leídos que resultaron en una visita a un enlace.

Fórmula DAX

[Whatsapp Visited] / [Whatsapp Read]

Lógica de cálculo

Divide el número de mensajes de WhatsApp con visita al enlace entre el número de mensajes de WhatsApp leídos.

Unsubscribed

Descripción del KPI

Muestra el número de destinatarios que se dieron de baja de las comunicaciones de WhatsApp.

Fórmula DAX

CALCULATE(
    COUNT('Unsubscribed'[ID_Unsubscribed]),
    'Distribution'[Communication_channel] = "whatsapp"
)

Lógica de cálculo

Cuenta los registros de baja donde el canal de comunicación es whatsapp.

Unsubscribed, %

Descripción del KPI

Muestra el porcentaje de mensajes de WhatsApp entregados que resultaron en una acción de baja.

Fórmula DAX

[Whatsapp Unsubscribed] / [Whatsapp Delivered]

Lógica de cálculo

Divide el número de destinatarios que se dieron de baja entre el número de mensajes de WhatsApp entregados.

Undelivered

Descripción del KPI

Muestra el número de mensajes de WhatsApp enviados que no fueron entregados a los destinatarios y tienen una razón de no entrega especificada.

Fórmula DAX

CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]),
    FILTER(
        'Distribution Status',
        'Distribution Status'[Distribution_Sending_Status] IN {
            "UNDELIVERED", "UNDELIVERABLE",
            "RESENDING_SMS_UNDELIVERED",
            "RESENDING_SMS_UNDELIVERABLE",
            "EXPIRED", "OLD", "BOUNCED",
            "DEFERRED", "UNKNOWN"
        }
        && RELATED('Distribution'[Communication_channel]) = "whatsapp"
        && TRIM('Distribution Status'[Reason_Undelivered_Whatsapp]) <> ""
        && 'Distribution Status'[Reason_Undelivered_Whatsapp] <> "Пусто"
        && NOT ISBLANK('Distribution Status'[Reason_Undelivered_Whatsapp])
    )
)

Lógica de cálculo

Cuenta registros de WhatsApp con estados de no entrega y una razón de no entrega no vacía. Este KPI ayuda a identificar mensajes que fueron enviados pero no llegaron a los destinatarios.

Undelivered, %

Descripción del KPI

Muestra el porcentaje de mensajes de WhatsApp enviados que no fueron entregados.

Fórmula DAX

[Whatsapp Undelivered] / [Whatsapp Sent]

Lógica de cálculo

Divide el número de mensajes de WhatsApp no entregados entre el número de mensajes de WhatsApp enviados.

Unsent

Descripción del KPI

Muestra el número de mensajes de WhatsApp planificados que no fueron enviados.

Fórmula DAX

CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]),
    FILTER(
        'Distribution Status',
        'Distribution Status'[Distribution_Sending_Status] IN {
            "DUPLICATE", "INVALID_EMAIL", "EMPTY_RECIPIENT",
            "EMPTY_CONTENT", "MESSAGE_LIMIT", "EXCLUDED",
            "UNSUBSCRIBED", "FAILED", "DECLINED", "UNVERIFIED"
        }
        && RELATED('Distribution'[Communication_channel]) = "whatsapp"
    )
)

Lógica de cálculo

Cuenta registros planificados de WhatsApp que no fueron enviados debido a problemas de datos, configuración, destinatario, contenido, límite o validación.

Unsent, %

Descripción del KPI

Muestra el porcentaje de mensajes de WhatsApp planificados que no fueron enviados.

Fórmula DAX

[Whatsapp Unsent] / [Whatsapp Planned]

Lógica de cálculo

Divide el número de mensajes de WhatsApp no enviados entre el número de mensajes de WhatsApp planificados.

Reason Undelivered

Descripción del KPI

Muestra el número de registros de WhatsApp con una razón de no entrega. Esta medida se usa en el gráfico Reasons for undelivered messages para analizar por qué los mensajes de WhatsApp no fueron entregados.

Fórmula DAX

CALCULATE(
    COUNT('Distribution Status'[Reason_Undelivered_Emails_Flag]),
    'Distribution'[Communication_channel] = "whatsapp"
)

Lógica de cálculo

Cuenta registros donde está disponible una marca de razón de no entrega para el canal de comunicación whatsapp.

WhatsApp Devices

Descripción del KPI

Muestra el número de registros de visitas a enlaces por dispositivo para comunicaciones de WhatsApp. Esta medida se usa en el gráfico Type of devices from which the link was visited.

Fórmula DAX

CALCULATE(
    COUNT('Devices'[ID_Linkstats]),
    'Distribution'[Communication_channel] = "whatsapp"
)

Lógica de cálculo

Cuenta registros de la tabla Devices donde el canal de comunicación es whatsapp.

WhatsApp Delivered to Read

Descripción del KPI

Muestra el número de mensajes de WhatsApp para los que está disponible el tiempo desde la entrega hasta la lectura. Esta medida se usa en la visualización Delivered vs Read.

Fórmula DAX

CALCULATE(
    COUNT('Distribution Status'[Time from delivered to read]),
    'Distribution'[Communication_channel] = "whatsapp"
)

Lógica de cálculo

Cuenta registros de WhatsApp que contienen un valor en el campo Time from delivered to read.

WhatsApp AVG Delivered to Read

Descripción del KPI

Muestra el tiempo promedio entre la entrega del mensaje de WhatsApp y su lectura. El resultado se muestra en formato HH:MM:SS.

Fórmula DAX

VAR TotalSeconds =
    AVERAGEX(
        FILTER(
            'Distribution Status',
            CALCULATE(
                COUNT('Distribution'[ID_Distribution]),
                'Distribution'[Communication_channel] = "whatsapp"
            ) > 0
            && NOT(ISBLANK('Distribution Status'[Difference in seconds 1]))
        ),
        'Distribution Status'[Difference in seconds 1]
    )
VAR Hours = INT(TotalSeconds / 3600)
VAR Minutes = INT(MOD(TotalSeconds, 3600) / 60)
VAR Seconds = MOD(TotalSeconds, 60)
RETURN
    FORMAT(Hours, "00") & ":" &
    FORMAT(Minutes, "00") & ":" &
    FORMAT(Seconds, "00")

Lógica de cálculo

Calcula el valor promedio de Difference in seconds 1 para registros de WhatsApp y luego convierte el resultado en horas, minutos y segundos.

WhatsApp Delivered to Visited

Descripción del KPI

Muestra el número de mensajes de WhatsApp para los que está disponible el tiempo desde la entrega hasta la visita al enlace. Esta medida se usa en la visualización Delivered vs Visited.

Fórmula DAX

CALCULATE(
    COUNT('Distribution Status'[Time from delivered to visited]),
    'Distribution'[Communication_channel] = "whatsapp"
)

Lógica de cálculo

Cuenta registros de WhatsApp que contienen un valor en el campo Time from delivered to visited.

WhatsApp AVG Delivered to Visited

Descripción del KPI

Muestra el tiempo promedio entre la entrega del mensaje de WhatsApp y la visita al enlace. El resultado se muestra en formato HH:MM:SS.

Fórmula DAX

VAR TotalSeconds =
    AVERAGEX(
        FILTER(
            'Distribution Status',
            CALCULATE(
                COUNT('Distribution'[ID_Distribution]),
                'Distribution'[Communication_channel] = "whatsapp"
            ) > 0
            && NOT(ISBLANK('Distribution Status'[Difference in seconds 2]))
        ),
        'Distribution Status'[Difference in seconds 2]
    )
VAR Hours = INT(TotalSeconds / 3600)
VAR Minutes = INT(MOD(TotalSeconds, 3600) / 60)
VAR Seconds = MOD(TotalSeconds, 60)
RETURN
    FORMAT(Hours, "00") & ":" &
    FORMAT(Minutes, "00") & ":" &
    FORMAT(Seconds, "00")

Lógica de cálculo

Calcula el valor promedio de Difference in seconds 2 para registros de WhatsApp y luego convierte el resultado en horas, minutos y segundos.

WhatsApp Delivered Dynamic

Descripción del KPI

Muestra el número de mensajes de WhatsApp entregados para el rango de días o meses seleccionado en el gráfico Message Delivery & Engagement Trends.

Fórmula DAX

VAR N = [DaysToShow Whatsapp]
VAR MaxDate =
    CALCULATE(
        MAX('Distribution Status'[Send_DateOnly]),
        ALL('Distribution Status')
    )
VAR Mode = SELECTEDVALUE(PeriodMode[Mode], "Day")

VAR StartDate_Day = MaxDate - (N - 1)
VAR StartDate_Month =
    DATE(
        YEAR(EOMONTH(MaxDate, -N + 1)),
        MONTH(EOMONTH(MaxDate, -N + 1)),
        1
    )

VAR StartDate = IF(Mode = "Month", StartDate_Month, StartDate_Day)

RETURN
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]),
    FILTER(
        ALL('Distribution Status'[Send_DateOnly]),
        'Distribution Status'[Send_DateOnly] >= StartDate
            && 'Distribution Status'[Send_DateOnly] <= MaxDate
    ),
    KEEPFILTERS(
        'Distribution Status'[Distribution_Sending_Status] IN {
            "DELIVERED", "READ", "VISITED", "SEEN"
        }
    ),
    KEEPFILTERS('Distribution'[Communication_channel] = "whatsapp"),
    REMOVEFILTERS('Calendar'),
    REMOVEFILTERS('PeriodsFilter')
)

Lógica de cálculo

Calcula los mensajes de WhatsApp entregados dentro del rango dinámico de fechas seleccionado. El rango depende del modo de período seleccionado: Day o Month.

WhatsApp Read Dynamic

Descripción del KPI

Muestra el número de mensajes de WhatsApp leídos para el rango de días o meses seleccionado en el gráfico Message Delivery & Engagement Trends.

Fórmula DAX

VAR N = [DaysToShow whatsapp]
VAR MaxDate =
    CALCULATE(
        MAX('Distribution Status'[Send_DateOnly]),
        ALL('Distribution Status')
    )
VAR Mode = SELECTEDVALUE(PeriodMode[Mode], "Day")

VAR StartDate_Day = MaxDate - (N - 1)
VAR StartDate_Month =
    DATE(
        YEAR(EOMONTH(MaxDate, -N + 1)),
        MONTH(EOMONTH(MaxDate, -N + 1)),
        1
    )

VAR StartDate = IF(Mode = "Month", StartDate_Month, StartDate_Day)

RETURN
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]),
    FILTER(
        ALL('Distribution Status'[Send_DateOnly]),
        'Distribution Status'[Send_DateOnly] >= StartDate
            && 'Distribution Status'[Send_DateOnly] <= MaxDate
    ),
    KEEPFILTERS(
        'Distribution Status'[Distribution_Sending_Status] IN {
            "READ", "VISITED", "SEEN"
        }
    ),
    KEEPFILTERS('Distribution'[Communication_channel] = "whatsapp"),
    REMOVEFILTERS('Calendar'),
    REMOVEFILTERS('PeriodsFilter')
)

Lógica de cálculo

Calcula los mensajes de WhatsApp leídos dentro del rango dinámico de fechas seleccionado. Se incluyen mensajes con estados de engagement posterior, como VISITED o SEEN.

WhatsApp Visited Dynamic

Descripción del KPI

Muestra el número de mensajes de WhatsApp con visitas a enlaces para el rango de días o meses seleccionado en el gráfico Message Delivery & Engagement Trends.

Fórmula DAX

VAR N = [DaysToShow Whatsapp]
VAR MaxDate =
    CALCULATE(
        MAX('Distribution Status'[Send_DateOnly]),
        ALL('Distribution Status')
    )
VAR Mode = SELECTEDVALUE(PeriodMode[Mode], "Day")
VAR StartDate =
    SWITCH(
        TRUE(),
        Mode = "Day", MaxDate - (N - 1),
        Mode = "Month", EOMONTH(MaxDate, -N + 1) + 1,
        MaxDate - N
    )
RETURN
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]),
    FILTER(
        ALL('Distribution Status'[Send_DateOnly]),
        'Distribution Status'[Send_DateOnly] >= StartDate
            && 'Distribution Status'[Send_DateOnly] <= MaxDate
    ),
    KEEPFILTERS(
        'Distribution Status'[Distribution_Sending_Status] IN {
            "VISITED"
        }
    ),
    KEEPFILTERS('Distribution'[Communication_channel] = "whatsapp"),
    REMOVEFILTERS('Calendar'),
    REMOVEFILTERS('PeriodsFilter')
)

Lógica de cálculo

Calcula las visitas a enlaces de WhatsApp dentro del rango dinámico de fechas seleccionado.

WhatsApp Undelivered Dynamic

Descripción del KPI

Muestra el número de mensajes de WhatsApp no entregados para el rango de días o meses seleccionado en el gráfico Message Delivery & Engagement Trends.

Fórmula DAX

VAR N = [DaysToShow Whatsapp]
VAR MaxDate =
    CALCULATE(
        MAX('Distribution Status'[Send_DateOnly]),
        ALL('Distribution Status')
    )
VAR Mode = SELECTEDVALUE(PeriodMode[Mode], "Day")
VAR StartDate =
    SWITCH(
        TRUE(),
        Mode = "Day", MaxDate - (N - 1),
        Mode = "Month", EOMONTH(MaxDate, -N + 1) + 1,
        MaxDate - N
    )
RETURN
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]),
    FILTER(
        ALL('Distribution Status'[Send_DateOnly]),
        'Distribution Status'[Send_DateOnly] >= StartDate
            && 'Distribution Status'[Send_DateOnly] <= MaxDate
    ),
    KEEPFILTERS(
        'Distribution Status'[Distribution_Sending_Status] IN {
            "UNDELIVERED", "UNDELIVERABLE",
            "RESENDING_SMS_UNDELIVERED",
            "RESENDING_SMS_UNDELIVERABLE",
            "EXPIRED", "OLD", "BOUNCED",
            "DEFERRED", "UNKNOWN"
        }
    ),
    KEEPFILTERS('Distribution'[Communication_channel] = "whatsapp"),
    REMOVEFILTERS('Calendar'),
    REMOVEFILTERS('PeriodsFilter')
)

Lógica de cálculo

Calcula los mensajes de WhatsApp no entregados dentro del rango dinámico de fechas seleccionado. El nombre de la medida en el archivo fuente está escrito como Whatsapp Undelivred Dynamic.