Pular para o conteúdo principal

Pesquisa

WhatsApp Dashboard - Lógica de cálculo de KPI

kpiwhatsapp1.jpg

O dashboard WhatsApp exibe cartões de KPI, gráficos e métricas da tabela detalhada para o desempenho da comunicação via WhatsApp.

Planned

Descrição do KPI
Mostra o número total de comunicações WhatsApp planejadas para o período de relatório selecionado.

Fórmula DAX

CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]),
    'Distribution'[Communication_channel] = "whatsapp"
)

Lógica de cálculo
Conta todos os registros de distribuição em que o canal de comunicação é whatsapp.

Sent

Descrição do KPI
Mostra o número de mensagens do WhatsApp que foram enviadas ou atingiram qualquer status relacionado ao envio.

Fórmula DAX

CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]),
    FILTER(
        'Distribution Status',
        'Distribution Status'[Distribution_Sending_Status] IN {
            "DELIVERED", "BOUNCED", "DECLINED", "DEFERRED", "EXPIRED",
            "FAILED", "OLD", "REJECTED", "UNDELIVERABLE", "UNDELIVERED",
            "UNKNOWN", "ENQUEUED", "QUEUED", "SENT", "VISITED", "READ", "SEEN"
        }
        && RELATED('Distribution'[Communication_channel]) = "whatsapp"
    )
)

Lógica de cálculo
Conta registros do WhatsApp com status relacionados ao envio, como SENT, DELIVERED, READ, VISITED, BOUNCED, FAILED, REJECTED, UNDELIVERED, UNKNOWN e outros status técnicos de envio.

Sent, %

Descrição do KPI
Mostra a porcentagem de mensagens planejadas do WhatsApp que foram enviadas.

Fórmula DAX

[Whatsapp Sent] / [Whatsapp Planned]

Lógica de cálculo
Divide o número de mensagens do WhatsApp enviadas pelo número de mensagens do WhatsApp planejadas.

Delivered

Descrição do KPI
Mostra o número de mensagens do WhatsApp enviadas que foram entregues aos destinatários.

Fórmula DAX

CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]),
    FILTER(
        'Distribution Status',
        'Distribution Status'[Distribution_Sending_Status] IN {
            "DELIVERED", "READ", "VISITED", "SEEN"
        }
        && RELATED('Distribution'[Communication_channel]) = "whatsapp"
    )
)

Lógica de cálculo
Conta mensagens do WhatsApp que chegaram à etapa de entrega. Mensagens com status de engajamento posterior, como READ, VISITED ou SEEN, também são contadas como entregues.

Delivered, %

Descrição do KPI
Mostra a porcentagem de mensagens do WhatsApp enviadas que foram entregues aos destinatários.

Fórmula DAX

[Whatsapp Delivered] / [Whatsapp Sent]

Lógica de cálculo
Divide o número de mensagens do WhatsApp entregues pelo número de mensagens do WhatsApp enviadas.

Read

Descrição do KPI
Mostra o número de mensagens do WhatsApp entregues que foram lidas pelos destinatários.

Fórmula DAX

CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]),
    FILTER(
        'Distribution Status',
        'Distribution Status'[Distribution_Sending_Status] IN {
            "READ", "VISITED", "SEEN"
        }
        && RELATED('Distribution'[Communication_channel]) = "whatsapp"
    )
)

Lógica de cálculo
Conta mensagens do WhatsApp que foram lidas ou tiveram engajamento adicional após a entrega.

Read, %

Descrição do KPI
Mostra a porcentagem de mensagens do WhatsApp entregues que foram lidas pelos destinatários.

Fórmula DAX

[Whatsapp Read] / [Whatsapp Delivered]

Lógica de cálculo
Divide o número de mensagens do WhatsApp lidas pelo número de mensagens do WhatsApp entregues.

Visited

Descrição do KPI
Mostra o número de mensagens do WhatsApp em que os destinatários visitaram um link.

Fórmula DAX

CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]),
    FILTER(
        'Distribution Status',
        'Distribution Status'[Distribution_Sending_Status] IN {
            "VISITED"
        }
        && RELATED('Distribution'[Communication_channel]) = "whatsapp"
    )
)

Lógica de cálculo
Conta registros do WhatsApp com o status VISITED, o que significa que o destinatário visitou um link da mensagem do WhatsApp.

Visited, %

Descrição do KPI
Mostra a porcentagem de mensagens do WhatsApp lidas que resultaram em uma visita ao link.

Fórmula DAX

[Whatsapp Visited] / [Whatsapp Read]

Lógica de cálculo
Divide o número de mensagens do WhatsApp com visita ao link pelo número de mensagens do WhatsApp lidas.

Unsubscribed

Descrição do KPI
Mostra o número de destinatários que cancelaram a inscrição nas comunicações do WhatsApp.

Fórmula DAX

CALCULATE(
    COUNT('Unsubscribed'[ID_Unsubscribed]),
    'Distribution'[Communication_channel] = "whatsapp"
)

Lógica de cálculo
Conta registros de cancelamento de inscrição em que o canal de comunicação é whatsapp.

Unsubscribed, %

Descrição do KPI
Mostra a porcentagem de mensagens do WhatsApp entregues que resultaram em uma ação de cancelamento de inscrição.

Fórmula DAX

[Whatsapp Unsubscribed] / [Whatsapp Delivered]

Lógica de cálculo
Divide o número de destinatários que cancelaram a inscrição pelo número de mensagens do WhatsApp entregues.

Undelivered

Descrição do KPI
Mostra o número de mensagens do WhatsApp enviadas que não foram entregues aos destinatários e têm um motivo de não entrega especificado.

Fórmula DAX

CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]),
    FILTER(
        'Distribution Status',
        'Distribution Status'[Distribution_Sending_Status] IN {
            "UNDELIVERED", "UNDELIVERABLE",
            "RESENDING_SMS_UNDELIVERED",
            "RESENDING_SMS_UNDELIVERABLE",
            "EXPIRED", "OLD", "BOUNCED",
            "DEFERRED", "UNKNOWN"
        }
        && RELATED('Distribution'[Communication_channel]) = "whatsapp"
        && TRIM('Distribution Status'[Reason_Undelivered_Whatsapp]) <> ""
        && 'Distribution Status'[Reason_Undelivered_Whatsapp] <> "Пусто"
        && NOT ISBLANK('Distribution Status'[Reason_Undelivered_Whatsapp])
    )
)

Lógica de cálculo
Conta registros do WhatsApp com status de entrega não realizada e um motivo de não entrega não vazio. Este KPI ajuda a identificar mensagens que foram enviadas, mas não chegaram aos destinatários.

Undelivered, %

Descrição do KPI
Mostra a porcentagem de mensagens do WhatsApp enviadas que não foram entregues.

Fórmula DAX

[Whatsapp Undelivered] / [Whatsapp Sent]

Lógica de cálculo
Divide o número de mensagens do WhatsApp não entregues pelo número de mensagens do WhatsApp enviadas.

Unsent

Descrição do KPI
Mostra o número de mensagens planejadas do WhatsApp que não foram enviadas.

Fórmula DAX

CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]),
    FILTER(
        'Distribution Status',
        'Distribution Status'[Distribution_Sending_Status] IN {
            "DUPLICATE", "INVALID_EMAIL", "EMPTY_RECIPIENT",
            "EMPTY_CONTENT", "MESSAGE_LIMIT", "EXCLUDED",
            "UNSUBSCRIBED", "FAILED", "DECLINED", "UNVERIFIED"
        }
        && RELATED('Distribution'[Communication_channel]) = "whatsapp"
    )
)

Lógica de cálculo
Conta registros planejados do WhatsApp que não foram enviados devido a problemas de dados, configuração, destinatário, conteúdo, limite ou validação.

Unsent, %

Descrição do KPI
Mostra a porcentagem de mensagens planejadas do WhatsApp que não foram enviadas.

Fórmula DAX

[Whatsapp Unsent] / [Whatsapp Planned]

Lógica de cálculo
Divide o número de mensagens do WhatsApp não enviadas pelo número de mensagens do WhatsApp planejadas.

Reason Undelivered

Descrição do KPI
Mostra o número de registros do WhatsApp com um motivo de não entrega. Esta medida é usada no gráfico Reasons for undelivered messages para analisar por que as mensagens do WhatsApp não foram entregues.

Fórmula DAX

CALCULATE(
    COUNT('Distribution Status'[Reason_Undelivered_Emails_Flag]),
    'Distribution'[Communication_channel] = "whatsapp"
)

Lógica de cálculo
Conta registros em que uma flag de motivo de não entrega está disponível para o canal de comunicação whatsapp.

WhatsApp Devices

Descrição do KPI
Mostra o número de registros de visitas a links por dispositivo para comunicações do WhatsApp. Esta medida é usada no gráfico Type of devices from which the link was visited.

Fórmula DAX

CALCULATE(
    COUNT('Devices'[ID_Linkstats]),
    'Distribution'[Communication_channel] = "whatsapp"
)

Lógica de cálculo
Conta registros da tabela Devices em que o canal de comunicação é whatsapp.

WhatsApp Delivered to Read

Descrição do KPI
Mostra o número de mensagens do WhatsApp para as quais o tempo entre a entrega e a leitura está disponível. Esta medida é usada na visualização Delivered vs Read.

Fórmula DAX

CALCULATE(
    COUNT('Distribution Status'[Time from delivered to read]),
    'Distribution'[Communication_channel] = "whatsapp"
)

Lógica de cálculo
Conta registros do WhatsApp que contêm um valor no campo Time from delivered to read.

WhatsApp AVG Delivered to Read

Descrição do KPI
Mostra o tempo médio entre a entrega da mensagem do WhatsApp e sua leitura. O resultado é exibido no formato HH:MM:SS.

Fórmula DAX

VAR TotalSeconds =
    AVERAGEX(
        FILTER(
            'Distribution Status',
            CALCULATE(
                COUNT('Distribution'[ID_Distribution]),
                'Distribution'[Communication_channel] = "whatsapp"
            ) > 0
            && NOT(ISBLANK('Distribution Status'[Difference in seconds 1]))
        ),
        'Distribution Status'[Difference in seconds 1]
    )
VAR Hours = INT(TotalSeconds / 3600)
VAR Minutes = INT(MOD(TotalSeconds, 3600) / 60)
VAR Seconds = MOD(TotalSeconds, 60)
RETURN
    FORMAT(Hours, "00") & ":" &
    FORMAT(Minutes, "00") & ":" &
    FORMAT(Seconds, "00")

Lógica de cálculo
Calcula o valor médio de Difference in seconds 1 para registros do WhatsApp e depois converte o resultado em horas, minutos e segundos.

WhatsApp Delivered to Visited

Descrição do KPI
Mostra o número de mensagens do WhatsApp para as quais o tempo entre a entrega e a visita ao link está disponível. Esta medida é usada na visualização Delivered vs Visited.

Fórmula DAX

CALCULATE(
    COUNT('Distribution Status'[Time from delivered to visited]),
    'Distribution'[Communication_channel] = "whatsapp"
)

Lógica de cálculo
Conta registros do WhatsApp que contêm um valor no campo Time from delivered to visited.

WhatsApp AVG Delivered to Visited

Descrição do KPI
Mostra o tempo médio entre a entrega da mensagem do WhatsApp e a visita ao link. O resultado é exibido no formato HH:MM:SS.

Fórmula DAX

VAR TotalSeconds =
    AVERAGEX(
        FILTER(
            'Distribution Status',
            CALCULATE(
                COUNT('Distribution'[ID_Distribution]),
                'Distribution'[Communication_channel] = "whatsapp"
            ) > 0
            && NOT(ISBLANK('Distribution Status'[Difference in seconds 2]))
        ),
        'Distribution Status'[Difference in seconds 2]
    )
VAR Hours = INT(TotalSeconds / 3600)
VAR Minutes = INT(MOD(TotalSeconds, 3600) / 60)
VAR Seconds = MOD(TotalSeconds, 60)
RETURN
    FORMAT(Hours, "00") & ":" &
    FORMAT(Minutes, "00") & ":" &
    FORMAT(Seconds, "00")

Lógica de cálculo
Calcula o valor médio de Difference in seconds 2 para registros do WhatsApp e depois converte o resultado em horas, minutos e segundos.

WhatsApp Delivered Dynamic

Descrição do KPI
Mostra o número de mensagens do WhatsApp entregues para o intervalo de dias ou meses selecionado no gráfico Message Delivery & Engagement Trends.

Fórmula DAX

VAR N = [DaysToShow Whatsapp]
VAR MaxDate =
    CALCULATE(
        MAX('Distribution Status'[Send_DateOnly]),
        ALL('Distribution Status')
    )
VAR Mode = SELECTEDVALUE(PeriodMode[Mode], "Day")

VAR StartDate_Day = MaxDate - (N - 1)
VAR StartDate_Month =
    DATE(
        YEAR(EOMONTH(MaxDate, -N + 1)),
        MONTH(EOMONTH(MaxDate, -N + 1)),
        1
    )

VAR StartDate = IF(Mode = "Month", StartDate_Month, StartDate_Day)

RETURN
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]),
    FILTER(
        ALL('Distribution Status'[Send_DateOnly]),
        'Distribution Status'[Send_DateOnly] >= StartDate
            && 'Distribution Status'[Send_DateOnly] <= MaxDate
    ),
    KEEPFILTERS(
        'Distribution Status'[Distribution_Sending_Status] IN {
            "DELIVERED", "READ", "VISITED", "SEEN"
        }
    ),
    KEEPFILTERS('Distribution'[Communication_channel] = "whatsapp"),
    REMOVEFILTERS('Calendar'),
    REMOVEFILTERS('PeriodsFilter')
)

Lógica de cálculo
Calcula as mensagens do WhatsApp entregues dentro do intervalo dinâmico de datas selecionado. O intervalo depende do modo de período selecionado: Day ou Month.

WhatsApp Read Dynamic

Descrição do KPI
Mostra o número de mensagens do WhatsApp lidas para o intervalo de dias ou meses selecionado no gráfico Message Delivery & Engagement Trends.

Fórmula DAX

VAR N = [DaysToShow whatsapp]
VAR MaxDate =
    CALCULATE(
        MAX('Distribution Status'[Send_DateOnly]),
        ALL('Distribution Status')
    )
VAR Mode = SELECTEDVALUE(PeriodMode[Mode], "Day")

VAR StartDate_Day = MaxDate - (N - 1)
VAR StartDate_Month =
    DATE(
        YEAR(EOMONTH(MaxDate, -N + 1)),
        MONTH(EOMONTH(MaxDate, -N + 1)),
        1
    )

VAR StartDate = IF(Mode = "Month", StartDate_Month, StartDate_Day)

RETURN
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]),
    FILTER(
        ALL('Distribution Status'[Send_DateOnly]),
        'Distribution Status'[Send_DateOnly] >= StartDate
            && 'Distribution Status'[Send_DateOnly] <= MaxDate
    ),
    KEEPFILTERS(
        'Distribution Status'[Distribution_Sending_Status] IN {
            "READ", "VISITED", "SEEN"
        }
    ),
    KEEPFILTERS('Distribution'[Communication_channel] = "whatsapp"),
    REMOVEFILTERS('Calendar'),
    REMOVEFILTERS('PeriodsFilter')
)

Lógica de cálculo
Calcula as mensagens do WhatsApp lidas dentro do intervalo dinâmico de datas selecionado. Mensagens com status de engajamento posterior, como VISITED ou SEEN, são incluídas.

WhatsApp Visited Dynamic

Descrição do KPI
Mostra o número de mensagens do WhatsApp com visitas a links para o intervalo de dias ou meses selecionado no gráfico Message Delivery & Engagement Trends.

Fórmula DAX

VAR N = [DaysToShow Whatsapp]
VAR MaxDate =
    CALCULATE(
        MAX('Distribution Status'[Send_DateOnly]),
        ALL('Distribution Status')
    )
VAR Mode = SELECTEDVALUE(PeriodMode[Mode], "Day")
VAR StartDate =
    SWITCH(
        TRUE(),
        Mode = "Day", MaxDate - (N - 1),
        Mode = "Month", EOMONTH(MaxDate, -N + 1) + 1,
        MaxDate - N
    )
RETURN
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]),
    FILTER(
        ALL('Distribution Status'[Send_DateOnly]),
        'Distribution Status'[Send_DateOnly] >= StartDate
            && 'Distribution Status'[Send_DateOnly] <= MaxDate
    ),
    KEEPFILTERS(
        'Distribution Status'[Distribution_Sending_Status] IN {
            "VISITED"
        }
    ),
    KEEPFILTERS('Distribution'[Communication_channel] = "whatsapp"),
    REMOVEFILTERS('Calendar'),
    REMOVEFILTERS('PeriodsFilter')
)

Lógica de cálculo
Calcula as visitas a links do WhatsApp dentro do intervalo dinâmico de datas selecionado.

WhatsApp Undelivered Dynamic

Descrição do KPI
Mostra o número de mensagens do WhatsApp não entregues para o intervalo de dias ou meses selecionado no gráfico Message Delivery & Engagement Trends.

Fórmula DAX

VAR N = [DaysToShow Whatsapp]
VAR MaxDate =
    CALCULATE(
        MAX('Distribution Status'[Send_DateOnly]),
        ALL('Distribution Status')
    )
VAR Mode = SELECTEDVALUE(PeriodMode[Mode], "Day")
VAR StartDate =
    SWITCH(
        TRUE(),
        Mode = "Day", MaxDate - (N - 1),
        Mode = "Month", EOMONTH(MaxDate, -N + 1) + 1,
        MaxDate - N
    )
RETURN
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]),
    FILTER(
        ALL('Distribution Status'[Send_DateOnly]),
        'Distribution Status'[Send_DateOnly] >= StartDate
            && 'Distribution Status'[Send_DateOnly] <= MaxDate
    ),
    KEEPFILTERS(
        'Distribution Status'[Distribution_Sending_Status] IN {
            "UNDELIVERED", "UNDELIVERABLE",
            "RESENDING_SMS_UNDELIVERED",
            "RESENDING_SMS_UNDELIVERABLE",
            "EXPIRED", "OLD", "BOUNCED",
            "DEFERRED", "UNKNOWN"
        }
    ),
    KEEPFILTERS('Distribution'[Communication_channel] = "whatsapp"),
    REMOVEFILTERS('Calendar'),
    REMOVEFILTERS('PeriodsFilter')
)

Lógica de cálculo
Calcula as mensagens do WhatsApp não entregues dentro do intervalo dinâmico de datas selecionado. O nome da medida no arquivo de origem está escrito como Whatsapp Undelivred Dynamic.