Pular para o conteúdo principal

Pesquisa

SMS Dashboard KPI Calculation Logic

smskpi.jpg

 

Planejado

Mostra o número total de mensagens SMS planejadas para envio durante o período de relatório selecionado.

Fórmula DAX

SMS Planned =
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]), 
    'Distribution'[Communication_channel] = "sms"
)

Lógica de Cálculo

A medida conta todos os registros de distribuição onde o canal de comunicação é sms. Representa o número total de mensagens SMS planejadas para o período e filtros selecionados.

Enviado

Mostra o número de mensagens SMS que entraram no processo de envio.

Fórmula DAX

SMS Sent =
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]), 
    FILTER(
        'Distribution Status',
        'Distribution Status'[Distribution_Sending_Status] IN {
            "DELIVERED", "BOUNCED", "DECLINED", "DEFERRED", "EXPIRED",
            "FAILED", "OLD", "REJECTED", "UNDELIVERABLE", "UNDELIVERED",
            "UNKNOWN", "ENQUEUED", "QUEUED", "SENT", "VISITED", "READ", "SEEN"
        }
        && RELATED('Distribution'[Communication_channel]) = "sms"
    )
)

Lógica de Cálculo

A medida conta mensagens SMS com status que indicam que a mensagem entrou no processo de envio. Inclui mensagens processadas com sucesso, bem como mensagens com status de entrega malsucedida.

% Enviado

Mostra a porcentagem de mensagens SMS planejadas que foram enviadas.

Fórmula DAX

SMS Sent % =
[SMS Sent] / [SMS Planned]

Lógica de Cálculo

A medida divide o número de mensagens SMS enviadas pelo número de mensagens SMS planejadas.

Entregue

Mostra o número de mensagens SMS entregues com sucesso aos destinatários.

Fórmula DAX

SMS Delivered =
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]), 
    FILTER(
        'Distribution Status',
        'Distribution Status'[Distribution_Sending_Status] IN {
            "DELIVERED", "READ", "VISITED", "SEEN"
        }
        && RELATED('Distribution'[Communication_channel]) = "sms"
    )
)

Lógica de Cálculo

A medida conta mensagens SMS com status relacionados à entrega. Status como READ, VISITED e SEEN são incluídos porque essas ações só podem ocorrer após a entrega bem-sucedida.

% Entregue

Mostra a porcentagem de mensagens SMS enviadas que foram entregues com sucesso.

Fórmula DAX

SMS Delivered % =
[SMS Delivered] / [SMS Sent]

Lógica de Cálculo

A medida divide o número de mensagens SMS entregues pelo número de mensagens SMS enviadas.

Lido

Mostra o número de mensagens SMS lidas ou visualizadas pelos destinatários.

Fórmula DAX

SMS Read =
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]), 
    FILTER(
        'Distribution Status',
        'Distribution Status'[Distribution_Sending_Status] IN {
            "READ", "VISITED", "SEEN"
        }
        && RELATED('Distribution'[Communication_channel]) = "sms"
    )
)

Lógica de Cálculo

A medida conta mensagens SMS com status que indicam atividade de leitura ou visualização pelo destinatário.

Visitado

Mostra o número de mensagens SMS onde os destinatários visitaram um link.

Fórmula DAX

SMS Visited =
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]), 
    FILTER(
        'Distribution Status',
        'Distribution Status'[Distribution_Sending_Status] IN { "VISITED" }
        && RELATED('Distribution'[Communication_channel]) = "sms"
    )
)

Lógica de Cálculo

A medida conta mensagens SMS com status VISITED. Mostra quantas comunicações SMS geraram interação com links.

% Visitado

Mostra a porcentagem de mensagens SMS entregues que resultaram em uma visita a link.

Fórmula DAX

SMS Visited % =
[SMS Visited] / [SMS Delivered]

Lógica de Cálculo

A medida divide o número de mensagens SMS com visitas a links pelo número de mensagens SMS entregues.

Cancelado

Mostra o número de destinatários que cancelaram a assinatura das comunicações SMS.

Fórmula DAX

SMS Unsubscribed =
CALCULATE(
    COUNT('Unsubscribed'[ID_Unsubscribed]), 
    'Distribution'[Communication_channel] = "sms"
)

Lógica de Cálculo

A medida conta registros de cancelamento para o canal de comunicação sms.

% Cancelado

Mostra a porcentagem de mensagens SMS entregues que resultaram em uma ação de cancelamento de assinatura.

Fórmula DAX

SMS Unsubscribed % =
[SMS Unsubscribed] / [SMS Delivered]

Lógica de Cálculo

A medida divide o número de registros de cancelamento de SMS pelo número de mensagens SMS entregues.

Não Entregue

Mostra o número de mensagens SMS enviadas que não foram entregues.

Fórmula DAX

SMS Undelivered =
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]), 
    FILTER(
        'Distribution Status',
        'Distribution Status'[Distribution_Sending_Status] IN {
            "UNDELIVERED", "UNDELIVERABLE",
            "RESENDING_SMS_UNDELIVERED",
            "RESENDING_SMS_UNDELIVERABLE",
            "EXPIRED", "OLD", "BOUNCED",
            "DEFERRED", "UNKNOWN"
        }
        && RELATED('Distribution'[Communication_channel]) = "sms"
    )
)

Lógica de Cálculo

A medida conta mensagens SMS com status que indicam falha na entrega.

% Não Entregue

Mostra a porcentagem de mensagens SMS enviadas que não foram entregues.

Fórmula DAX

SMS Undelivered % =
[SMS Undelivered] / [SMS Sent]

Lógica de Cálculo

A medida divide o número de mensagens SMS não entregues pelo número de mensagens SMS enviadas.

Não Enviado

Mostra o número de mensagens SMS planejadas que não foram enviadas.

Fórmula DAX

SMS Unsent =
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]), 
    FILTER(
        'Distribution Status',
        'Distribution Status'[Distribution_Sending_Status] IN {
            "DUPLICATE", "INVALID_EMAIL", "EMPTY_RECIPIENT",
            "EMPTY_CONTENT", "MESSAGE_LIMIT", "EXCLUDED",
            "UNSUBSCRIBED", "FAILED", "DECLINED", "UNVERIFIED"
        }
        && RELATED('Distribution'[Communication_channel]) = "sms"
    )
)

Lógica de Cálculo

A medida conta mensagens SMS planejadas que não foram enviadas devido a restrições, registros duplicados, dados de destinatário ausentes, falha no processamento ou outros problemas de envio.

% Não Enviado

Mostra a porcentagem de mensagens SMS planejadas que não foram enviadas.

Fórmula DAX

SMS Unsent % =
[SMS Unsent] / [SMS Planned]

Lógica de Cálculo

A medida divide o número de mensagens SMS não enviadas pelo número de mensagens SMS planejadas.

SMS Entregue Dinâmico

Mostra o número de mensagens SMS entregues ao longo do tempo para o período dinâmico selecionado.

Fórmula DAX

SMS Delivered Dynamic =
VAR N = [DaysToShow SMS]
VAR MaxDate =
    CALCULATE (
        MAX ( 'Distribution Status'[Send_DateOnly] ),
        ALL ( 'Distribution Status' )
    )
VAR Mode = SELECTEDVALUE(PeriodMode[Mode], "Day")
VAR StartDate_Day = MaxDate - (N - 1)
VAR StartDate_Month =
    DATE(
        YEAR ( EOMONTH ( MaxDate, -N + 1 ) ),
        MONTH( EOMONTH ( MaxDate, -N + 1 ) ),
        1
    )
VAR StartDate = IF(Mode = "Month", StartDate_Month, StartDate_Day)
RETURN
CALCULATE (
    COUNT ( 'Distribution Status'[ID_Distribution] ),
    FILTER (
        ALL ( 'Distribution Status'[Send_DateOnly] ),
        'Distribution Status'[Send_DateOnly] >= StartDate
            && 'Distribution Status'[Send_DateOnly] <= MaxDate
    ),
    KEEPFILTERS (
        'Distribution Status'[Distribution_Sending_Status] IN {
            "DELIVERED", "READ", "VISITED", "SEEN"
        }
    ),
    KEEPFILTERS ( 'Distribution'[Communication_channel] = "sms" ),
    REMOVEFILTERS ( 'Calendar' ),
    REMOVEFILTERS ( 'PeriodsFilter' )
)

Lógica de Cálculo

A medida calcula o número de mensagens SMS entregues para o período dinâmico selecionado. Utiliza DaysToShow SMS e o modo de período selecionado, como Dia ou Mês, para definir o intervalo de datas exibido.

SMS Lido Dinâmico

Mostra o número de mensagens SMS lidas ao longo do tempo para o período dinâmico selecionado.

Fórmula DAX

SMS Read Dynamic =
VAR N = [DaysToShow SMS]
VAR MaxDate =
    CALCULATE (
        MAX ( 'Distribution Status'[Send_DateOnly] ),
        ALL ( 'Distribution Status' )
    )
VAR Mode = SELECTEDVALUE(PeriodMode[Mode], "Day")
VAR StartDate_Day = MaxDate - (N - 1)
VAR StartDate_Month =
    DATE(
        YEAR ( EOMONTH ( MaxDate, -N + 1 ) ),
        MONTH( EOMONTH ( MaxDate, -N + 1 ) ),
        1
    )
VAR StartDate = IF(Mode = "Month", StartDate_Month, StartDate_Day)
RETURN
CALCULATE (
    COUNT ( 'Distribution Status'[ID_Distribution] ),
    FILTER (
        ALL ( 'Distribution Status'[Send_DateOnly] ),
        'Distribution Status'[Send_DateOnly] >= StartDate
            && 'Distribution Status'[Send_DateOnly] <= MaxDate
    ),
    KEEPFILTERS (
        'Distribution Status'[Distribution_Sending_Status] IN {
            "READ", "VISITED", "SEEN"
        }
    ),
    KEEPFILTERS ( 'Distribution'[Communication_channel] = "sms" ),
    REMOVEFILTERS ( 'Calendar' ),
    REMOVEFILTERS ( 'PeriodsFilter' )
)

Lógica de Cálculo

A medida calcula o número de mensagens SMS lidas pelos destinatários dentro do período dinâmico selecionado. É usada no gráfico Tendências de Entrega e Engajamento de Mensagens.

SMS Não Entregue Dinâmico

Mostra o número de mensagens SMS não entregues ao longo do tempo para o período dinâmico selecionado.

Fórmula DAX

SMS Undelivred Dynamic =
VAR N = [DaysToShow SMS]
VAR MaxDate =
    CALCULATE (
        MAX ( 'Distribution Status'[Send_DateOnly] ),
        ALL ( 'Distribution Status' )
    )
VAR Mode = SELECTEDVALUE(PeriodMode[Mode], "Day")
VAR StartDate =
    SWITCH (
        TRUE(),
        Mode = "Day", MaxDate - (N - 1),
        Mode = "Month", EOMONTH(MaxDate, -N + 1) + 1,
        MaxDate - N
    )
RETURN
CALCULATE (
    COUNT ( 'Distribution Status'[ID_Distribution] ),
    FILTER (
        ALL ( 'Distribution Status'[Send_DateOnly] ),
        'Distribution Status'[Send_DateOnly] >= StartDate
            && 'Distribution Status'[Send_DateOnly] <= MaxDate
    ),
    KEEPFILTERS (
        'Distribution Status'[Distribution_Sending_Status] IN {
            "UNDELIVERED", "UNDELIVERABLE",
            "RESENDING_SMS_UNDELIVERED",
            "RESENDING_SMS_UNDELIVERABLE",
            "EXPIRED", "OLD", "BOUNCED",
            "DEFERRED", "UNKNOWN"
        }
    ),
    KEEPFILTERS ( 'Distribution'[Communication_channel] = "sms" ),
    REMOVEFILTERS ( 'Calendar' ),
    REMOVEFILTERS ( 'PeriodsFilter' )
)

Lógica de Cálculo

A medida calcula o número de mensagens SMS não entregues dentro do período dinâmico selecionado. É usada para mostrar a dinâmica de falha na entrega ao longo do tempo.

SMS Visitado Dinâmico

Mostra o número de mensagens SMS com visitas a links ao longo do tempo para o período dinâmico selecionado.

Fórmula DAX

SMS Visited Dynamic =
VAR N = [DaysToShow SMS]
VAR MaxDate =
    CALCULATE (
        MAX ( 'Distribution Status'[Send_DateOnly] ),
        ALL ( 'Distribution Status' )
    )
VAR Mode = SELECTEDVALUE(PeriodMode[Mode], "Day")
VAR StartDate =
    SWITCH (
        TRUE(),
        Mode = "Day", MaxDate - (N - 1),
        Mode = "Month", EOMONTH(MaxDate, -N + 1) + 1,
        MaxDate - N
    )
RETURN
CALCULATE (
    COUNT ( 'Distribution Status'[ID_Distribution] ),
    FILTER (
        ALL ( 'Distribution Status'[Send_DateOnly] ),
        'Distribution Status'[Send_DateOnly] >= StartDate
            && 'Distribution Status'[Send_DateOnly] <= MaxDate
    ),
    KEEPFILTERS (
        'Distribution Status'[Distribution_Sending_Status] IN { "VISITED" }
    ),
    KEEPFILTERS ( 'Distribution'[Communication_channel] = "sms" ),
    REMOVEFILTERS ( 'Calendar' ),
    REMOVEFILTERS ( 'PeriodsFilter' )
)

Lógica de Cálculo

A medida calcula o número de mensagens SMS onde os destinatários visitaram um link durante o período dinâmico selecionado. É usada no gráfico de tendência para mostrar a atividade de visita a links SMS ao longo do tempo.