Перейти к основному контенту

Поиск

WhatsApp Dashboard - Логика расчета KPI

kpiwhatsapp1.jpg

Дашборд WhatsApp отображает KPI-карточки, диаграммы и метрики подробной таблицы для анализа эффективности WhatsApp-коммуникаций.

Planned

Описание KPI

Показывает общее количество запланированных WhatsApp-коммуникаций за выбранный отчетный период.

Формула DAX

CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]),
    'Distribution'[Communication_channel] = "whatsapp"
)

Логика расчета

Считает все записи дистрибуций, у которых канал коммуникации — whatsapp.

Sent

Описание KPI

Показывает количество сообщений WhatsApp, которые были отправлены или достигли любого статуса, связанного с отправкой.

Формула DAX

CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]),
    FILTER(
        'Distribution Status',
        'Distribution Status'[Distribution_Sending_Status] IN {
            "DELIVERED", "BOUNCED", "DECLINED", "DEFERRED", "EXPIRED",
            "FAILED", "OLD", "REJECTED", "UNDELIVERABLE", "UNDELIVERED",
            "UNKNOWN", "ENQUEUED", "QUEUED", "SENT", "VISITED", "READ", "SEEN"
        }
        && RELATED('Distribution'[Communication_channel]) = "whatsapp"
    )
)

Логика расчета

Считает записи WhatsApp со статусами отправки, такими как SENT, DELIVERED, READ, VISITED, BOUNCED, FAILED, REJECTED, UNDELIVERED, UNKNOWN, а также другими техническими статусами отправки.

Sent, %

Описание KPI

Показывает процент запланированных сообщений WhatsApp, которые были отправлены.

Формула DAX

Whatsapp Sent % =
[Whatsapp Sent] / [Whatsapp Planned]

Логика расчета

Делит количество отправленных сообщений WhatsApp на количество запланированных сообщений WhatsApp.

Delivered

Описание KPI

Показывает количество отправленных сообщений WhatsApp, доставленных получателям.

Формула DAX

Whatsapp Delivered =
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]),
    FILTER(
        'Distribution Status',
        'Distribution Status'[Distribution_Sending_Status] IN {
            "DELIVERED", "READ", "VISITED", "SEEN"
        }
        && RELATED('Distribution'[Communication_channel]) = "whatsapp"
    )
)

Логика расчета

Считает сообщения WhatsApp, которые достигли этапа доставки. Сообщения с последующими статусами вовлеченности, такими как READ, VISITED или SEEN, также считаются доставленными.

Delivered, %

Описание KPI

Показывает процент отправленных сообщений WhatsApp, которые были доставлены получателям.

Формула DAX

Whatsapp Delivered % =
[Whatsapp Delivered] / [Whatsapp Sent]

Логика расчета

Делит количество доставленных сообщений WhatsApp на количество отправленных сообщений WhatsApp.

Read

Описание KPI

Показывает количество доставленных сообщений WhatsApp, прочитанных получателями.

Формула DAX

CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]),
    FILTER(
        'Distribution Status',
        'Distribution Status'[Distribution_Sending_Status] IN {
            "READ", "VISITED", "SEEN"
        }
        && RELATED('Distribution'[Communication_channel]) = "whatsapp"
    )
)

Логика расчета

Считает сообщения WhatsApp, которые были прочитаны или имели дальнейшее взаимодействие после доставки.

Read, %

Описание KPI

Показывает процент доставленных сообщений WhatsApp, которые были прочитаны получателями.

Формула DAX

[Whatsapp Read] / [Whatsapp Delivered]

Логика расчета

Делит количество прочитанных сообщений WhatsApp на количество доставленных сообщений WhatsApp.

Visited

Описание KPI

Показывает количество сообщений WhatsApp, по которым получатели перешли по ссылке.

Формула DAX

CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]),
    FILTER(
        'Distribution Status',
        'Distribution Status'[Distribution_Sending_Status] IN {
            "VISITED"
        }
        && RELATED('Distribution'[Communication_channel]) = "whatsapp"
    )
)

Логика расчета

Считает записи WhatsApp со статусом VISITED, который означает, что получатель перешел по ссылке из сообщения WhatsApp.

Visited, %

Описание KPI

Показывает процент прочитанных сообщений WhatsApp, которые привели к переходу по ссылке.

Формула DAX

[Whatsapp Visited] / [Whatsapp Read]

Логика расчета

Делит количество сообщений WhatsApp с переходом по ссылке на количество прочитанных сообщений WhatsApp.

Unsubscribed

Описание KPI

Показывает количество получателей, которые отписались от WhatsApp-коммуникаций.

Формула DAX

CALCULATE(
    COUNT('Unsubscribed'[ID_Unsubscribed]),
    'Distribution'[Communication_channel] = "whatsapp"
)

Логика расчета

Считает записи отписки, у которых канал коммуникации — whatsapp.

Unsubscribed, %

Описание KPI

Показывает процент доставленных сообщений WhatsApp, которые привели к отписке.

Формула DAX

[Whatsapp Unsubscribed] / [Whatsapp Delivered]

Логика расчета

Делит количество отписавшихся получателей на количество доставленных сообщений WhatsApp.

Undelivered

Описание KPI

Показывает количество отправленных сообщений WhatsApp, которые не были доставлены получателям и имеют указанную причину недоставки.

Формула DAX

CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]),
    FILTER(
        'Distribution Status',
        'Distribution Status'[Distribution_Sending_Status] IN {
            "UNDELIVERED", "UNDELIVERABLE",
            "RESENDING_SMS_UNDELIVERED",
            "RESENDING_SMS_UNDELIVERABLE",
            "EXPIRED", "OLD", "BOUNCED",
            "DEFERRED", "UNKNOWN"
        }
        && RELATED('Distribution'[Communication_channel]) = "whatsapp"
        && TRIM('Distribution Status'[Reason_Undelivered_Whatsapp]) <> ""
        && 'Distribution Status'[Reason_Undelivered_Whatsapp] <> "Пусто"
        && NOT ISBLANK('Distribution Status'[Reason_Undelivered_Whatsapp])
    )
)

Логика расчета

Считает записи WhatsApp со статусами недоставки и непустой причиной недоставки. Этот KPI помогает определить сообщения, которые были отправлены, но не дошли до получателей.

Undelivered, %

Описание KPI

Показывает процент отправленных сообщений WhatsApp, которые не были доставлены.

Формула DAX

[Whatsapp Undelivered] / [Whatsapp Sent]

Логика расчета

Делит количество недоставленных сообщений WhatsApp на количество отправленных сообщений WhatsApp.

Unsent

Описание KPI

Показывает количество запланированных сообщений WhatsApp, которые не были отправлены.

Формула DAX

CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]),
    FILTER(
        'Distribution Status',
        'Distribution Status'[Distribution_Sending_Status] IN {
            "DUPLICATE", "INVALID_EMAIL", "EMPTY_RECIPIENT",
            "EMPTY_CONTENT", "MESSAGE_LIMIT", "EXCLUDED",
            "UNSUBSCRIBED", "FAILED", "DECLINED", "UNVERIFIED"
        }
        && RELATED('Distribution'[Communication_channel]) = "whatsapp"
    )
)

Логика расчета

Считает запланированные записи WhatsApp, которые не были отправлены из-за проблем с данными, настройками, получателем, контентом, лимитом или валидацией.

Unsent, %

Описание KPI

Показывает процент запланированных сообщений WhatsApp, которые не были отправлены.

Формула DAX

[Whatsapp Unsent] / [Whatsapp Planned]

Логика расчета

Делит количество неотправленных сообщений WhatsApp на количество запланированных сообщений WhatsApp.

Reason Undelivered

Описание KPI

Показывает количество записей WhatsApp с причиной недоставки. Эта мера используется в диаграмме Reasons for undelivered messages для анализа причин недоставки сообщений WhatsApp.

Формула DAX

CALCULATE(
    COUNT('Distribution Status'[Reason_Undelivered_Emails_Flag]),
    'Distribution'[Communication_channel] = "whatsapp"
)

Логика расчета

Считает записи, в которых доступен флаг причины недоставки для канала коммуникации whatsapp.

WhatsApp Devices

Описание KPI

Показывает количество записей переходов по ссылкам по устройствам для WhatsApp-коммуникаций. Эта мера используется в диаграмме Type of devices from which the link was visited.

Формула DAX

CALCULATE(
    COUNT('Devices'[ID_Linkstats]),
    'Distribution'[Communication_channel] = "whatsapp"
)

Логика расчета

Считает записи из таблицы Devices, у которых канал коммуникации — whatsapp.

WhatsApp Delivered to Read

Описание KPI

Показывает количество сообщений WhatsApp, для которых доступно время от доставки до прочтения. Эта мера используется в визуализации Delivered vs Read.

Формула DAX

CALCULATE(
    COUNT('Distribution Status'[Time from delivered to read]),
    'Distribution'[Communication_channel] = "whatsapp"
)

Логика расчета

Считает записи WhatsApp, содержащие значение в поле Time from delivered to read.

WhatsApp AVG Delivered to Read

Описание KPI

Показывает среднее время между доставкой сообщения WhatsApp и его прочтением. Результат отображается в формате HH:MM:SS.

Формула DAX

VAR TotalSeconds =
    AVERAGEX(
        FILTER(
            'Distribution Status',
            CALCULATE(
                COUNT('Distribution'[ID_Distribution]),
                'Distribution'[Communication_channel] = "whatsapp"
            ) > 0
            && NOT(ISBLANK('Distribution Status'[Difference in seconds 1]))
        ),
        'Distribution Status'[Difference in seconds 1]
    )
VAR Hours = INT(TotalSeconds / 3600)
VAR Minutes = INT(MOD(TotalSeconds, 3600) / 60)
VAR Seconds = MOD(TotalSeconds, 60)
RETURN
    FORMAT(Hours, "00") & ":" &
    FORMAT(Minutes, "00") & ":" &
    FORMAT(Seconds, "00")

Логика расчета

Вычисляет среднее значение Difference in seconds 1 для записей WhatsApp, затем преобразует результат в часы, минуты и секунды.

WhatsApp Delivered to Visited

Описание KPI

Показывает количество сообщений WhatsApp, для которых доступно время от доставки до перехода по ссылке. Эта мера используется в визуализации Delivered vs Visited.

Формула DAX

CALCULATE(
    COUNT('Distribution Status'[Time from delivered to visited]),
    'Distribution'[Communication_channel] = "whatsapp"
)

Логика расчета

Считает записи WhatsApp, содержащие значение в поле Time from delivered to visited.

WhatsApp AVG Delivered to Visited

Описание KPI

Показывает среднее время между доставкой сообщения WhatsApp и переходом по ссылке. Результат отображается в формате HH:MM:SS.

Формула DAX

VAR TotalSeconds =
    AVERAGEX(
        FILTER(
            'Distribution Status',
            CALCULATE(
                COUNT('Distribution'[ID_Distribution]),
                'Distribution'[Communication_channel] = "whatsapp"
            ) > 0
            && NOT(ISBLANK('Distribution Status'[Difference in seconds 2]))
        ),
        'Distribution Status'[Difference in seconds 2]
    )
VAR Hours = INT(TotalSeconds / 3600)
VAR Minutes = INT(MOD(TotalSeconds, 3600) / 60)
VAR Seconds = MOD(TotalSeconds, 60)
RETURN
    FORMAT(Hours, "00") & ":" &
    FORMAT(Minutes, "00") & ":" &
    FORMAT(Seconds, "00")

Логика расчета

Вычисляет среднее значение Difference in seconds 2 для записей WhatsApp, затем преобразует результат в часы, минуты и секунды.

WhatsApp Delivered Dynamic

Описание KPI

Показывает количество доставленных сообщений WhatsApp для выбранного диапазона дней или месяцев в диаграмме Message Delivery & Engagement Trends.

Формула DAX

VAR N = [DaysToShow Whatsapp]
VAR MaxDate =
    CALCULATE(
        MAX('Distribution Status'[Send_DateOnly]),
        ALL('Distribution Status')
    )
VAR Mode = SELECTEDVALUE(PeriodMode[Mode], "Day")

VAR StartDate_Day = MaxDate - (N - 1)
VAR StartDate_Month =
    DATE(
        YEAR(EOMONTH(MaxDate, -N + 1)),
        MONTH(EOMONTH(MaxDate, -N + 1)),
        1
    )

VAR StartDate = IF(Mode = "Month", StartDate_Month, StartDate_Day)

RETURN
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]),
    FILTER(
        ALL('Distribution Status'[Send_DateOnly]),
        'Distribution Status'[Send_DateOnly] >= StartDate
            && 'Distribution Status'[Send_DateOnly] <= MaxDate
    ),
    KEEPFILTERS(
        'Distribution Status'[Distribution_Sending_Status] IN {
            "DELIVERED", "READ", "VISITED", "SEEN"
        }
    ),
    KEEPFILTERS('Distribution'[Communication_channel] = "whatsapp"),
    REMOVEFILTERS('Calendar'),
    REMOVEFILTERS('PeriodsFilter')
)

Логика расчета

Вычисляет доставленные сообщения WhatsApp в выбранном динамическом диапазоне дат. Диапазон зависит от выбранного режима периода: Day или Month.

WhatsApp Read Dynamic

Описание KPI

Показывает количество прочитанных сообщений WhatsApp для выбранного диапазона дней или месяцев в диаграмме Message Delivery & Engagement Trends.

Формула DAX

VAR N = [DaysToShow whatsapp]
VAR MaxDate =
    CALCULATE(
        MAX('Distribution Status'[Send_DateOnly]),
        ALL('Distribution Status')
    )
VAR Mode = SELECTEDVALUE(PeriodMode[Mode], "Day")

VAR StartDate_Day = MaxDate - (N - 1)
VAR StartDate_Month =
    DATE(
        YEAR(EOMONTH(MaxDate, -N + 1)),
        MONTH(EOMONTH(MaxDate, -N + 1)),
        1
    )

VAR StartDate = IF(Mode = "Month", StartDate_Month, StartDate_Day)

RETURN
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]),
    FILTER(
        ALL('Distribution Status'[Send_DateOnly]),
        'Distribution Status'[Send_DateOnly] >= StartDate
            && 'Distribution Status'[Send_DateOnly] <= MaxDate
    ),
    KEEPFILTERS(
        'Distribution Status'[Distribution_Sending_Status] IN {
            "READ", "VISITED", "SEEN"
        }
    ),
    KEEPFILTERS('Distribution'[Communication_channel] = "whatsapp"),
    REMOVEFILTERS('Calendar'),
    REMOVEFILTERS('PeriodsFilter')
)

Логика расчета

Вычисляет прочитанные сообщения WhatsApp в выбранном динамическом диапазоне дат. Сообщения с последующими статусами вовлеченности, такими как VISITED или SEEN, также включаются.

WhatsApp Visited Dynamic

Описание KPI

Показывает количество сообщений WhatsApp с переходами по ссылкам для выбранного диапазона дней или месяцев в диаграмме Message Delivery & Engagement Trends.

Формула DAX

VAR N = [DaysToShow Whatsapp]
VAR MaxDate =
    CALCULATE(
        MAX('Distribution Status'[Send_DateOnly]),
        ALL('Distribution Status')
    )
VAR Mode = SELECTEDVALUE(PeriodMode[Mode], "Day")
VAR StartDate =
    SWITCH(
        TRUE(),
        Mode = "Day", MaxDate - (N - 1),
        Mode = "Month", EOMONTH(MaxDate, -N + 1) + 1,
        MaxDate - N
    )
RETURN
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]),
    FILTER(
        ALL('Distribution Status'[Send_DateOnly]),
        'Distribution Status'[Send_DateOnly] >= StartDate
            && 'Distribution Status'[Send_DateOnly] <= MaxDate
    ),
    KEEPFILTERS(
        'Distribution Status'[Distribution_Sending_Status] IN {
            "VISITED"
        }
    ),
    KEEPFILTERS('Distribution'[Communication_channel] = "whatsapp"),
    REMOVEFILTERS('Calendar'),
    REMOVEFILTERS('PeriodsFilter')
)

Логика расчета

Вычисляет переходы по ссылкам WhatsApp в выбранном динамическом диапазоне дат.

WhatsApp Undelivered Dynamic

Описание KPI

Показывает количество недоставленных сообщений WhatsApp для выбранного диапазона дней или месяцев в диаграмме Message Delivery & Engagement Trends.

Формула DAX

VAR N = [DaysToShow Whatsapp]
VAR MaxDate =
    CALCULATE(
        MAX('Distribution Status'[Send_DateOnly]),
        ALL('Distribution Status')
    )
VAR Mode = SELECTEDVALUE(PeriodMode[Mode], "Day")
VAR StartDate =
    SWITCH(
        TRUE(),
        Mode = "Day", MaxDate - (N - 1),
        Mode = "Month", EOMONTH(MaxDate, -N + 1) + 1,
        MaxDate - N
    )
RETURN
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]),
    FILTER(
        ALL('Distribution Status'[Send_DateOnly]),
        'Distribution Status'[Send_DateOnly] >= StartDate
            && 'Distribution Status'[Send_DateOnly] <= MaxDate
    ),
    KEEPFILTERS(
        'Distribution Status'[Distribution_Sending_Status] IN {
            "UNDELIVERED", "UNDELIVERABLE",
            "RESENDING_SMS_UNDELIVERED",
            "RESENDING_SMS_UNDELIVERABLE",
            "EXPIRED", "OLD", "BOUNCED",
            "DEFERRED", "UNKNOWN"
        }
    ),
    KEEPFILTERS('Distribution'[Communication_channel] = "whatsapp"),
    REMOVEFILTERS('Calendar'),
    REMOVEFILTERS('PeriodsFilter')
)

Логика расчета

Вычисляет недоставленные сообщения WhatsApp в выбранном динамическом диапазоне дат. Название меры в исходном файле написано как Whatsapp Undelivred Dynamic.