Перейти до основного контенту

Пошук

WhatsApp Dashboard - Логіка розрахунку KPI

kpiwhatsapp1.jpg

Дашборд WhatsApp відображає KPI-картки, діаграми та метрики детальної таблиці для аналізу ефективності WhatsApp-комунікацій.

Planned

Опис KPI

Показує загальну кількість запланованих WhatsApp-комунікацій за вибраний звітний період.

Формула DAX

CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]),
    'Distribution'[Communication_channel] = "whatsapp"
)

Логіка розрахунку

Підраховує всі записи дистрибуцій, у яких канал комунікації — whatsapp.

Sent

Опис KPI

Показує кількість WhatsApp-повідомлень, які були надіслані або досягли будь-якого статусу, пов’язаного з надсиланням.

Формула DAX

CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]),
    FILTER(
        'Distribution Status',
        'Distribution Status'[Distribution_Sending_Status] IN {
            "DELIVERED", "BOUNCED", "DECLINED", "DEFERRED", "EXPIRED",
            "FAILED", "OLD", "REJECTED", "UNDELIVERABLE", "UNDELIVERED",
            "UNKNOWN", "ENQUEUED", "QUEUED", "SENT", "VISITED", "READ", "SEEN"
        }
        && RELATED('Distribution'[Communication_channel]) = "whatsapp"
    )
)

Логіка розрахунку

Підраховує записи WhatsApp зі статусами надсилання, такими як SENT, DELIVERED, READ, VISITED, BOUNCED, FAILED, REJECTED, UNDELIVERED, UNKNOWN та іншими технічними статусами надсилання.

Sent, %

Опис KPI

Показує відсоток запланованих WhatsApp-повідомлень, які були надіслані.

Формула DAX

Whatsapp Sent % =
[Whatsapp Sent] / [Whatsapp Planned]

Логіка розрахунку

Ділить кількість надісланих WhatsApp-повідомлень на кількість запланованих WhatsApp-повідомлень.

Delivered

Опис KPI

Показує кількість надісланих WhatsApp-повідомлень, доставлених отримувачам.

Формула DAX

Whatsapp Delivered =
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]),
    FILTER(
        'Distribution Status',
        'Distribution Status'[Distribution_Sending_Status] IN {
            "DELIVERED", "READ", "VISITED", "SEEN"
        }
        && RELATED('Distribution'[Communication_channel]) = "whatsapp"
    )
)

Логіка розрахунку

Підраховує WhatsApp-повідомлення, які досягли етапу доставки. Повідомлення з подальшими статусами залучення, такими як READ, VISITED або SEEN, також вважаються доставленими.

Delivered, %

Опис KPI

Показує відсоток надісланих WhatsApp-повідомлень, які були доставлені отримувачам.

Формула DAX

Whatsapp Delivered % =
[Whatsapp Delivered] / [Whatsapp Sent]

Логіка розрахунку

Ділить кількість доставлених WhatsApp-повідомлень на кількість надісланих WhatsApp-повідомлень.

Read

Опис KPI

Показує кількість доставлених WhatsApp-повідомлень, прочитаних отримувачами.

Формула DAX

CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]),
    FILTER(
        'Distribution Status',
        'Distribution Status'[Distribution_Sending_Status] IN {
            "READ", "VISITED", "SEEN"
        }
        && RELATED('Distribution'[Communication_channel]) = "whatsapp"
    )
)

Логіка розрахунку

Підраховує WhatsApp-повідомлення, які були прочитані або мали подальшу взаємодію після доставки.

Read, %

Опис KPI

Показує відсоток доставлених WhatsApp-повідомлень, які були прочитані отримувачами.

Формула DAX

[Whatsapp Read] / [Whatsapp Delivered]

Логіка розрахунку

Ділить кількість прочитаних WhatsApp-повідомлень на кількість доставлених WhatsApp-повідомлень.

Visited

Опис KPI

Показує кількість WhatsApp-повідомлень, у яких отримувачі перейшли за посиланням.

Формула DAX

CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]),
    FILTER(
        'Distribution Status',
        'Distribution Status'[Distribution_Sending_Status] IN {
            "VISITED"
        }
        && RELATED('Distribution'[Communication_channel]) = "whatsapp"
    )
)

Логіка розрахунку

Підраховує записи WhatsApp зі статусом VISITED, що означає, що отримувач перейшов за посиланням із WhatsApp-повідомлення.

Visited, %

Опис KPI

Показує відсоток прочитаних WhatsApp-повідомлень, які призвели до переходу за посиланням.

Формула DAX

[Whatsapp Visited] / [Whatsapp Read]

Логіка розрахунку

Ділить кількість WhatsApp-повідомлень із переходом за посиланням на кількість прочитаних WhatsApp-повідомлень.

Unsubscribed

Опис KPI

Показує кількість отримувачів, які відписалися від WhatsApp-комунікацій.

Формула DAX

CALCULATE(
    COUNT('Unsubscribed'[ID_Unsubscribed]),
    'Distribution'[Communication_channel] = "whatsapp"
)

Логіка розрахунку

Підраховує записи відписки, у яких канал комунікації — whatsapp.

Unsubscribed, %

Опис KPI

Показує відсоток доставлених WhatsApp-повідомлень, які призвели до відписки.

Формула DAX

[Whatsapp Unsubscribed] / [Whatsapp Delivered]

Логіка розрахунку

Ділить кількість отримувачів, які відписалися, на кількість доставлених WhatsApp-повідомлень.

Undelivered

Опис KPI

Показує кількість надісланих WhatsApp-повідомлень, які не були доставлені отримувачам і мають зазначену причину недоставки.

Формула DAX

CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]),
    FILTER(
        'Distribution Status',
        'Distribution Status'[Distribution_Sending_Status] IN {
            "UNDELIVERED", "UNDELIVERABLE",
            "RESENDING_SMS_UNDELIVERED",
            "RESENDING_SMS_UNDELIVERABLE",
            "EXPIRED", "OLD", "BOUNCED",
            "DEFERRED", "UNKNOWN"
        }
        && RELATED('Distribution'[Communication_channel]) = "whatsapp"
        && TRIM('Distribution Status'[Reason_Undelivered_Whatsapp]) <> ""
        && 'Distribution Status'[Reason_Undelivered_Whatsapp] <> "Пусто"
        && NOT ISBLANK('Distribution Status'[Reason_Undelivered_Whatsapp])
    )
)

Логіка розрахунку

Підраховує записи WhatsApp зі статусами недоставки та непорожньою причиною недоставки. Цей KPI допомагає визначити повідомлення, які були надіслані, але не дійшли до отримувачів.

Undelivered, %

Опис KPI

Показує відсоток надісланих WhatsApp-повідомлень, які не були доставлені.

Формула DAX

[Whatsapp Undelivered] / [Whatsapp Sent]

Логіка розрахунку

Ділить кількість недоставлених WhatsApp-повідомлень на кількість надісланих WhatsApp-повідомлень.

Unsent

Опис KPI

Показує кількість запланованих WhatsApp-повідомлень, які не були надіслані.

Формула DAX

CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]),
    FILTER(
        'Distribution Status',
        'Distribution Status'[Distribution_Sending_Status] IN {
            "DUPLICATE", "INVALID_EMAIL", "EMPTY_RECIPIENT",
            "EMPTY_CONTENT", "MESSAGE_LIMIT", "EXCLUDED",
            "UNSUBSCRIBED", "FAILED", "DECLINED", "UNVERIFIED"
        }
        && RELATED('Distribution'[Communication_channel]) = "whatsapp"
    )
)

Логіка розрахунку

Підраховує заплановані записи WhatsApp, які не були надіслані через проблеми з даними, налаштуваннями, отримувачем, контентом, лімітом або валідацією.

Unsent, %

Опис KPI

Показує відсоток запланованих WhatsApp-повідомлень, які не були надіслані.

Формула DAX

[Whatsapp Unsent] / [Whatsapp Planned]

Логіка розрахунку

Ділить кількість ненадісланих WhatsApp-повідомлень на кількість запланованих WhatsApp-повідомлень.

Reason Undelivered

Опис KPI

Показує кількість записів WhatsApp із причиною недоставки. Ця міра використовується в діаграмі Reasons for undelivered messages для аналізу причин, чому WhatsApp-повідомлення не були доставлені.

Формула DAX

CALCULATE(
    COUNT('Distribution Status'[Reason_Undelivered_Emails_Flag]),
    'Distribution'[Communication_channel] = "whatsapp"
)

Логіка розрахунку

Підраховує записи, у яких доступний прапорець причини недоставки для каналу комунікації whatsapp.

WhatsApp Devices

Опис KPI

Показує кількість записів переходів за посиланнями за пристроєм для WhatsApp-комунікацій. Ця міра використовується в діаграмі Type of devices from which the link was visited.

Формула DAX

CALCULATE(
    COUNT('Devices'[ID_Linkstats]),
    'Distribution'[Communication_channel] = "whatsapp"
)

Логіка розрахунку

Підраховує записи з таблиці Devices, у яких канал комунікації — whatsapp.

WhatsApp Delivered to Read

Опис KPI

Показує кількість WhatsApp-повідомлень, для яких доступний час від доставки до прочитання. Ця міра використовується у візуалізації Delivered vs Read.

Формула DAX

CALCULATE(
    COUNT('Distribution Status'[Time from delivered to read]),
    'Distribution'[Communication_channel] = "whatsapp"
)

Логіка розрахунку

Підраховує записи WhatsApp, які містять значення в полі Time from delivered to read.

WhatsApp AVG Delivered to Read

Опис KPI

Показує середній час між доставкою WhatsApp-повідомлення та його прочитанням. Результат відображається у форматі HH:MM:SS.

Формула DAX

VAR TotalSeconds =
    AVERAGEX(
        FILTER(
            'Distribution Status',
            CALCULATE(
                COUNT('Distribution'[ID_Distribution]),
                'Distribution'[Communication_channel] = "whatsapp"
            ) > 0
            && NOT(ISBLANK('Distribution Status'[Difference in seconds 1]))
        ),
        'Distribution Status'[Difference in seconds 1]
    )
VAR Hours = INT(TotalSeconds / 3600)
VAR Minutes = INT(MOD(TotalSeconds, 3600) / 60)
VAR Seconds = MOD(TotalSeconds, 60)
RETURN
    FORMAT(Hours, "00") & ":" &
    FORMAT(Minutes, "00") & ":" &
    FORMAT(Seconds, "00")

Логіка розрахунку

Обчислює середнє значення Difference in seconds 1 для записів WhatsApp, а потім перетворює результат у години, хвилини та секунди.

WhatsApp Delivered to Visited

Опис KPI

Показує кількість WhatsApp-повідомлень, для яких доступний час від доставки до переходу за посиланням. Ця міра використовується у візуалізації Delivered vs Visited.

Формула DAX

CALCULATE(
    COUNT('Distribution Status'[Time from delivered to visited]),
    'Distribution'[Communication_channel] = "whatsapp"
)

Логіка розрахунку

Підраховує записи WhatsApp, які містять значення в полі Time from delivered to visited.

WhatsApp AVG Delivered to Visited

Опис KPI

Показує середній час між доставкою WhatsApp-повідомлення та переходом за посиланням. Результат відображається у форматі HH:MM:SS.

Формула DAX

VAR TotalSeconds =
    AVERAGEX(
        FILTER(
            'Distribution Status',
            CALCULATE(
                COUNT('Distribution'[ID_Distribution]),
                'Distribution'[Communication_channel] = "whatsapp"
            ) > 0
            && NOT(ISBLANK('Distribution Status'[Difference in seconds 2]))
        ),
        'Distribution Status'[Difference in seconds 2]
    )
VAR Hours = INT(TotalSeconds / 3600)
VAR Minutes = INT(MOD(TotalSeconds, 3600) / 60)
VAR Seconds = MOD(TotalSeconds, 60)
RETURN
    FORMAT(Hours, "00") & ":" &
    FORMAT(Minutes, "00") & ":" &
    FORMAT(Seconds, "00")

Логіка розрахунку

Обчислює середнє значення Difference in seconds 2 для записів WhatsApp, а потім перетворює результат у години, хвилини та секунди.

WhatsApp Delivered Dynamic

Опис KPI

Показує кількість доставлених WhatsApp-повідомлень для вибраного діапазону днів або місяців у діаграмі Message Delivery & Engagement Trends.

Формула DAX

VAR N = [DaysToShow Whatsapp]
VAR MaxDate =
    CALCULATE(
        MAX('Distribution Status'[Send_DateOnly]),
        ALL('Distribution Status')
    )
VAR Mode = SELECTEDVALUE(PeriodMode[Mode], "Day")

VAR StartDate_Day = MaxDate - (N - 1)
VAR StartDate_Month =
    DATE(
        YEAR(EOMONTH(MaxDate, -N + 1)),
        MONTH(EOMONTH(MaxDate, -N + 1)),
        1
    )

VAR StartDate = IF(Mode = "Month", StartDate_Month, StartDate_Day)

RETURN
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]),
    FILTER(
        ALL('Distribution Status'[Send_DateOnly]),
        'Distribution Status'[Send_DateOnly] >= StartDate
            && 'Distribution Status'[Send_DateOnly] <= MaxDate
    ),
    KEEPFILTERS(
        'Distribution Status'[Distribution_Sending_Status] IN {
            "DELIVERED", "READ", "VISITED", "SEEN"
        }
    ),
    KEEPFILTERS('Distribution'[Communication_channel] = "whatsapp"),
    REMOVEFILTERS('Calendar'),
    REMOVEFILTERS('PeriodsFilter')
)

Логіка розрахунку

Обчислює доставлені WhatsApp-повідомлення у вибраному динамічному діапазоні дат. Діапазон залежить від вибраного режиму періоду: Day або Month.

WhatsApp Read Dynamic

Опис KPI

Показує кількість прочитаних WhatsApp-повідомлень для вибраного діапазону днів або місяців у діаграмі Message Delivery & Engagement Trends.

Формула DAX

VAR N = [DaysToShow whatsapp]
VAR MaxDate =
    CALCULATE(
        MAX('Distribution Status'[Send_DateOnly]),
        ALL('Distribution Status')
    )
VAR Mode = SELECTEDVALUE(PeriodMode[Mode], "Day")

VAR StartDate_Day = MaxDate - (N - 1)
VAR StartDate_Month =
    DATE(
        YEAR(EOMONTH(MaxDate, -N + 1)),
        MONTH(EOMONTH(MaxDate, -N + 1)),
        1
    )

VAR StartDate = IF(Mode = "Month", StartDate_Month, StartDate_Day)

RETURN
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]),
    FILTER(
        ALL('Distribution Status'[Send_DateOnly]),
        'Distribution Status'[Send_DateOnly] >= StartDate
            && 'Distribution Status'[Send_DateOnly] <= MaxDate
    ),
    KEEPFILTERS(
        'Distribution Status'[Distribution_Sending_Status] IN {
            "READ", "VISITED", "SEEN"
        }
    ),
    KEEPFILTERS('Distribution'[Communication_channel] = "whatsapp"),
    REMOVEFILTERS('Calendar'),
    REMOVEFILTERS('PeriodsFilter')
)

Логіка розрахунку

Обчислює прочитані WhatsApp-повідомлення у вибраному динамічному діапазоні дат. Повідомлення з подальшими статусами залучення, такими як VISITED або SEEN, також включаються.

WhatsApp Visited Dynamic

Опис KPI

Показує кількість WhatsApp-повідомлень із переходами за посиланнями для вибраного діапазону днів або місяців у діаграмі Message Delivery & Engagement Trends.

Формула DAX

VAR N = [DaysToShow Whatsapp]
VAR MaxDate =
    CALCULATE(
        MAX('Distribution Status'[Send_DateOnly]),
        ALL('Distribution Status')
    )
VAR Mode = SELECTEDVALUE(PeriodMode[Mode], "Day")
VAR StartDate =
    SWITCH(
        TRUE(),
        Mode = "Day", MaxDate - (N - 1),
        Mode = "Month", EOMONTH(MaxDate, -N + 1) + 1,
        MaxDate - N
    )
RETURN
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]),
    FILTER(
        ALL('Distribution Status'[Send_DateOnly]),
        'Distribution Status'[Send_DateOnly] >= StartDate
            && 'Distribution Status'[Send_DateOnly] <= MaxDate
    ),
    KEEPFILTERS(
        'Distribution Status'[Distribution_Sending_Status] IN {
            "VISITED"
        }
    ),
    KEEPFILTERS('Distribution'[Communication_channel] = "whatsapp"),
    REMOVEFILTERS('Calendar'),
    REMOVEFILTERS('PeriodsFilter')
)

Логіка розрахунку

Обчислює переходи за посиланнями WhatsApp у вибраному динамічному діапазоні дат.

WhatsApp Undelivered Dynamic

Опис KPI

Показує кількість недоставлених WhatsApp-повідомлень для вибраного діапазону днів або місяців у діаграмі Message Delivery & Engagement Trends.

Формула DAX

VAR N = [DaysToShow Whatsapp]
VAR MaxDate =
    CALCULATE(
        MAX('Distribution Status'[Send_DateOnly]),
        ALL('Distribution Status')
    )
VAR Mode = SELECTEDVALUE(PeriodMode[Mode], "Day")
VAR StartDate =
    SWITCH(
        TRUE(),
        Mode = "Day", MaxDate - (N - 1),
        Mode = "Month", EOMONTH(MaxDate, -N + 1) + 1,
        MaxDate - N
    )
RETURN
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]),
    FILTER(
        ALL('Distribution Status'[Send_DateOnly]),
        'Distribution Status'[Send_DateOnly] >= StartDate
            && 'Distribution Status'[Send_DateOnly] <= MaxDate
    ),
    KEEPFILTERS(
        'Distribution Status'[Distribution_Sending_Status] IN {
            "UNDELIVERED", "UNDELIVERABLE",
            "RESENDING_SMS_UNDELIVERED",
            "RESENDING_SMS_UNDELIVERABLE",
            "EXPIRED", "OLD", "BOUNCED",
            "DEFERRED", "UNKNOWN"
        }
    ),
    KEEPFILTERS('Distribution'[Communication_channel] = "whatsapp"),
    REMOVEFILTERS('Calendar'),
    REMOVEFILTERS('PeriodsFilter')
)

Логіка розрахунку

Обчислює недоставлені WhatsApp-повідомлення у вибраному динамічному діапазоні дат. Назва міри в початковому файлі написана як Whatsapp Undelivred Dynamic.