Saltar al contenido principal

Búsqueda

Lógica de Cálculo de KPI en el Panel de Viber

El panel de Viber muestra tarjetas KPI, gráficos y métricas detalladas en tablas sobre el rendimiento de la comunicación en Viber.

viberkpi.jpg

Viber Planificado

Muestra el número total de mensajes de Viber planificados para enviar durante el período de reporte seleccionado.

Fórmula DAX

Viber Planned =
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]), 
    'Distribution'[Communication_channel] = "viber"
)

Lógica de Cálculo

La medida cuenta todos los registros de distribución donde el canal de comunicación es viber.

Representa el número total de mensajes de Viber planificados para el período de reporte y filtros seleccionados.

Viber Enviado

Muestra el número de mensajes de Viber que ingresaron al proceso de envío, independientemente del resultado final de la entrega.

Fórmula DAX

Viber Sent =
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]), 
    FILTER(
        'Distribution Status',
        'Distribution Status'[Distribution_Sending_Status] IN {
            "DELIVERED", "BOUNCED", "DECLINED", "DEFERRED", "EXPIRED",
            "FAILED", "OLD", "REJECTED", "UNDELIVERABLE", "UNDELIVERED",
            "UNKNOWN", "ENQUEUED", "QUEUED", "SENT", "VISITED", "READ", "SEEN"
        }
        && RELATED('Distribution'[Communication_channel]) = "viber"
    )
)

Lógica de Cálculo

La medida cuenta los mensajes de Viber con estados de envío que indican que el mensaje ingresó al proceso de envío.

Incluye mensajes que fueron entregados con éxito, leídos, visitados o vistos, así como mensajes con estados de entrega fallida como rebotados, fallidos, rechazados, no entregables o desconocidos.

Porcentaje Enviado en Viber

Muestra el porcentaje de mensajes de Viber planificados que fueron enviados.

Fórmula DAX

Viber Sent % =
[Viber Sent] / [Viber Planned]

Lógica de Cálculo

La medida calcula la proporción de mensajes de Viber planificados que fueron enviados.

En el ejemplo de la tarjeta KPI, se enviaron 1,149,942 mensajes de un total de 1,616,922 mensajes planificados, lo que equivale a 71.12%.

Viber Entregado

Muestra el número de mensajes de Viber entregados con éxito a los destinatarios.

Fórmula DAX

Viber Delivered =
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]), 
    FILTER(
        'Distribution Status',
        'Distribution Status'[Distribution_Sending_Status] IN {
            "DELIVERED", "READ", "VISITED", "SEEN"
        }
        && RELATED('Distribution'[Communication_channel]) = "viber"
    )
)

Lógica de Cálculo

La medida cuenta los mensajes de Viber que fueron entregados con éxito a los destinatarios.

También se incluyen mensajes con estados READ, VISITED y SEEN porque estas acciones solo pueden ocurrir después de una entrega exitosa.

Porcentaje Entregado en Viber

Muestra el porcentaje de mensajes de Viber enviados que fueron entregados con éxito.

Fórmula DAX

Viber Delivered % =
[Viber Delivered] / [Viber Sent]

Lógica de Cálculo

La medida calcula la proporción de mensajes de Viber enviados que fueron entregados.

En el ejemplo de la tarjeta KPI, se entregaron 914,006 mensajes de un total de 1,149,942 mensajes enviados, lo que equivale a 79.48%.

Viber Leído

Muestra el número de mensajes de Viber entregados que fueron leídos o vistos por los destinatarios.

Fórmula DAX

Viber Read =
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]), 
    FILTER(
        'Distribution Status',
        'Distribution Status'[Distribution_Sending_Status] IN {
            "READ", "VISITED", "SEEN"
        }
        && RELATED('Distribution'[Communication_channel]) = "viber"
    )
)

Lógica de Cálculo

La medida cuenta los mensajes de Viber que fueron leídos por los destinatarios.

También se incluyen mensajes con estados VISITED y SEEN porque indican la participación del destinatario después de que el mensaje fue leído o visto.

Porcentaje Leído en Viber

Muestra el porcentaje de mensajes de Viber entregados que fueron leídos por los destinatarios.

Fórmula DAX

Viber Read % =
[Viber Read] / [Viber Delivered]

Lógica de Cálculo

La medida calcula la proporción de mensajes de Viber entregados que fueron leídos por los destinatarios.

En el ejemplo de la tarjeta KPI, se leyeron 613,848 mensajes de un total de 914,006 mensajes entregados, lo que equivale a 67.16%.

Viber Visitado

Muestra el número de mensajes de Viber que resultaron en que un destinatario visitara un enlace.

Fórmula DAX

Viber Visited =
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]), 
    FILTER(
        'Distribution Status',
        'Distribution Status'[Distribution_Sending_Status] IN { "VISITED" }
        && RELATED('Distribution'[Communication_channel]) = "viber"
    )
)

Lógica de Cálculo

La medida cuenta los mensajes de Viber donde los destinatarios visitaron un enlace desde el mensaje.

Muestra cuántas comunicaciones de Viber generaron interacción con enlaces.

Porcentaje Visitado en Viber

Muestra el porcentaje de mensajes de Viber leídos que generaron una visita a un enlace.

Fórmula DAX

Viber Visited % =
[Viber Visited] / [Viber Read]

Lógica de Cálculo

La medida calcula la proporción de mensajes de Viber leídos que resultaron en una visita a un enlace.

En el ejemplo de la tarjeta KPI, 12,047 mensajes resultaron en visitas a enlaces de un total de 613,848 mensajes leídos, lo que equivale a 1.96%.

Viber Dado de Baja

Muestra el número de destinatarios que se dieron de baja de las comunicaciones de Viber.

Fórmula DAX

Viber Unsubscribed =
CALCULATE(
    COUNT('Unsubscribed'[ID_Unsubscribed]), 
    'Distribution'[Communication_channel] = "viber"
)

Lógica de Cálculo

La medida cuenta los registros de bajas para el canal de comunicación viber.

Muestra cuántos destinatarios se dieron de baja de las comunicaciones de Viber durante el período de reporte seleccionado.

Porcentaje de Baja en Viber

Muestra el porcentaje de mensajes de Viber entregados que resultaron en una acción de baja.

Fórmula DAX

Viber Unsubscribe % =
[Viber Unsubscribed] / [Viber Delivered]

Lógica de Cálculo

La medida calcula la proporción de mensajes de Viber entregados que resultaron en una acción de baja.

En el ejemplo de la tarjeta KPI, se muestran 556 registros de baja. El porcentaje mostrado en la tarjeta KPI es 0.06%.

Viber No Entregado

Muestra el número de mensajes de Viber enviados que no fueron entregados y tienen una razón de no entrega especificada.

Fórmula DAX

Viber Undelivered =
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]),
    FILTER(
        'Distribution Status',
        'Distribution Status'[Distribution_Sending_Status] IN {
            "UNDELIVERED", "UNDELIVERABLE",
            "RESENDING_SMS_UNDELIVERED",
            "RESENDING_SMS_UNDELIVERABLE",
            "EXPIRED", "OLD", "BOUNCED",
            "DEFERRED", "UNKNOWN"
        }
        && RELATED('Distribution'[Communication_channel]) = "viber"
        && TRIM('Distribution Status'[Reason_Undelivered_Viber]) <> ""
        && 'Distribution Status'[Reason_Undelivered_Viber] <> "Пусто"
        && NOT ISBLANK('Distribution Status'[Reason_Undelivered_Viber])
    )
)

Lógica de Cálculo

La medida cuenta los mensajes de Viber enviados que no fueron entregados y tienen una razón de no entrega especificada.

Se utiliza para analizar fallas de entrega e identificar mensajes que requieren investigación por razón.

Porcentaje No Entregado en Viber

Muestra el porcentaje de mensajes de Viber enviados que no fueron entregados.

Fórmula DAX

Viber Undelivered % =
[Viber Undelivered] / [Viber Sent]

Lógica de Cálculo

La medida calcula el porcentaje de mensajes de Viber enviados que no fueron entregados.

Ayuda a los usuarios a evaluar la proporción de fallas de entrega entre todas las comunicaciones de Viber enviadas.

Viber No Enviado

Muestra el número de mensajes de Viber planificados que no fueron enviados debido a restricciones, datos inválidos, duplicados, estado de baja u otros problemas de envío.

Fórmula DAX

Viber Unsent =
CALCULATE(
    COUNT('Distribution Status'[ID_Distribution]), 
    FILTER(
        'Distribution Status',
        'Distribution Status'[Distribution_Sending_Status] IN {
            "DUPLICATE", "INVALID_EMAIL", "EMPTY_RECIPIENT",
            "EMPTY_CONTENT", "MESSAGE_LIMIT", "EXCLUDED",
            "UNSUBSCRIBED", "FAILED", "DECLINED", "UNVERIFIED"
        }
        && RELATED('Distribution'[Communication_channel]) = "viber"
    )
)

Lógica de Cálculo

La medida cuenta los mensajes de Viber planificados que no fueron enviados debido a restricciones de envío, datos de destinatario inválidos o faltantes, estado de baja, duplicados, procesamiento fallido u otras condiciones del sistema.

Porcentaje No Enviado en Viber

Muestra el porcentaje de mensajes de Viber planificados que no fueron enviados.

Fórmula DAX

Viber Unsent % =
[Viber Unsent] / [Viber Planned]

Lógica de Cálculo

La medida calcula la proporción de mensajes de Viber planificados que no fueron enviados.

Ayuda a los usuarios a evaluar cuántas comunicaciones planificadas de Viber no ingresaron al proceso de envío.

Viber Entregado Dinámico

Muestra el número de mensajes de Viber entregados a lo largo del tiempo para el período dinámico seleccionado.

Fórmula DAX

Viber Delivered Dynamic =
VAR N = [DaysToShow Viber]
VAR MaxDate =
    CALCULATE (
        MAX ( 'Distribution Status'[Send_DateOnly] ),
        ALL ( 'Distribution Status' )
    )
VAR Mode = SELECTEDVALUE(PeriodMode[Mode], "Day")
VAR StartDate_Day = MaxDate - (N - 1)
VAR StartDate_Month =
    DATE(
        YEAR ( EOMONTH ( MaxDate, -N + 1 ) ),
        MONTH( EOMONTH ( MaxDate, -N + 1 ) ),
        1
    )
VAR StartDate = IF(Mode = "Month", StartDate_Month, StartDate_Day)
RETURN
CALCULATE (
    COUNT ( 'Distribution Status'[ID_Distribution] ),
    FILTER (
        ALL ( 'Distribution Status'[Send_DateOnly] ),
        'Distribution Status'[Send_DateOnly] >= StartDate
            && 'Distribution Status'[Send_DateOnly] <= MaxDate
    ),
    KEEPFILTERS (
        'Distribution Status'[Distribution_Sending_Status] IN {
            "DELIVERED", "READ", "VISITED", "SEEN"
        }
    ),
    KEEPFILTERS ( 'Distribution'[Communication_channel] = "viber" ),
    REMOVEFILTERS ( 'Calendar' ),
    REMOVEFILTERS ( 'PeriodsFilter' )
)

Lógica de Cálculo

La medida calcula el número de mensajes de Viber entregados para el período dinámico seleccionado.

Utiliza el valor DaysToShow Viber y el modo de período seleccionado, como Día o Mes, para definir el rango de fechas mostrado en el gráfico de tendencias.

Viber Leído Dinámico

Muestra el número de mensajes de Viber leídos a lo largo del tiempo para el período dinámico seleccionado.

Fórmula DAX

Viber Read Dynamic =
VAR N = [DaysToShow Viber]
VAR MaxDate =
    CALCULATE (
        MAX ( 'Distribution Status'[Send_DateOnly] ),
        ALL ( 'Distribution Status' )
    )
VAR Mode = SELECTEDVALUE(PeriodMode[Mode], "Day")
VAR StartDate_Day = MaxDate - (N - 1)
VAR StartDate_Month =
    DATE(
        YEAR ( EOMONTH ( MaxDate, -N + 1 ) ),
        MONTH( EOMONTH ( MaxDate, -N + 1 ) ),
        1
    )
VAR StartDate = IF(Mode = "Month", StartDate_Month, StartDate_Day)
RETURN
CALCULATE (
    COUNT ( 'Distribution Status'[ID_Distribution] ),
    FILTER (
        ALL ( 'Distribution Status'[Send_DateOnly] ),
        'Distribution Status'[Send_DateOnly] >= StartDate
            && 'Distribution Status'[Send_DateOnly] <= MaxDate
    ),
    KEEPFILTERS (
        'Distribution Status'[Distribution_Sending_Status] IN {
            "READ", "VISITED", "SEEN"
        }
    ),
    KEEPFILTERS ( 'Distribution'[Communication_channel] = "viber" ),
    REMOVEFILTERS ( 'Calendar' ),
    REMOVEFILTERS ( 'PeriodsFilter' )
)

Lógica de Cálculo

La medida calcula el número de mensajes de Viber leídos para el período dinámico seleccionado.

Se usa en el gráfico de Tendencias de Entrega y Participación de Mensajes para mostrar cómo cambia la actividad de lectura a lo largo del tiempo.

Viber No Entregado Dinámico

Muestra el número de mensajes de Viber no entregados a lo largo del tiempo para el período dinámico seleccionado.

Fórmula DAX

Viber Undelivred Dynamic =
VAR N = [DaysToShow Viber]
VAR MaxDate =
    CALCULATE (
        MAX ( 'Distribution Status'[Send_DateOnly] ),
        ALL ( 'Distribution Status' )
    )
VAR Mode = SELECTEDVALUE(PeriodMode[Mode], "Day")
VAR StartDate =
    SWITCH (
        TRUE(),
        Mode = "Day", MaxDate - (N - 1),
        Mode = "Month", EOMONTH(MaxDate, -N + 1) + 1,
        MaxDate - N
    )
RETURN
CALCULATE (
    COUNT ( 'Distribution Status'[ID_Distribution] ),
    FILTER (
        ALL ( 'Distribution Status'[Send_DateOnly] ),
        'Distribution Status'[Send_DateOnly] >= StartDate
            && 'Distribution Status'[Send_DateOnly] <= MaxDate
    ),
    KEEPFILTERS (
        'Distribution Status'[Distribution_Sending_Status] IN {
            "UNDELIVERED", "UNDELIVERABLE",
            "RESENDING_SMS_UNDELIVERED",
            "RESENDING_SMS_UNDELIVERABLE",
            "EXPIRED", "OLD", "BOUNCED",
            "DEFERRED", "UNKNOWN"
        }
    ),
    KEEPFILTERS ( 'Distribution'[Communication_channel] = "viber" ),
    REMOVEFILTERS ( 'Calendar' ),
    REMOVEFILTERS ( 'PeriodsFilter' )
)

Lógica de Cálculo

La medida calcula el número de mensajes de Viber no entregados para el período dinámico seleccionado.

Se usa en el gráfico de tendencias para mostrar la dinámica de fallas de entrega a lo largo del tiempo.

Viber Visitado Dinámico

Muestra el número de mensajes de Viber con visitas a enlaces a lo largo del tiempo para el período dinámico seleccionado.

Fórmula DAX

Viber Visited Dynamic =
VAR N = [DaysToShow Viber]
VAR MaxDate =
    CALCULATE (
        MAX ( 'Distribution Status'[Send_DateOnly] ),
        ALL ( 'Distribution Status' )
    )
VAR Mode = SELECTEDVALUE(PeriodMode[Mode], "Day")
VAR StartDate =
    SWITCH (
        TRUE(),
        Mode = "Day", MaxDate - (N - 1),
        Mode = "Month", EOMONTH(MaxDate, -N + 1) + 1,
        MaxDate - N
    )
RETURN
CALCULATE (
    COUNT ( 'Distribution Status'[ID_Distribution] ),
    FILTER (
        ALL ( 'Distribution Status'[Send_DateOnly] ),
        'Distribution Status'[Send_DateOnly] >= StartDate
            && 'Distribution Status'[Send_DateOnly] <= MaxDate
    ),
    KEEPFILTERS (
        'Distribution Status'[Distribution_Sending_Status] IN { "VISITED" }
    ),
    KEEPFILTERS ( 'Distribution'[Communication_channel] = "viber" ),
    REMOVEFILTERS ( 'Calendar' ),
    REMOVEFILTERS ( 'PeriodsFilter' )
)

Lógica de Cálculo

La medida calcula el número de mensajes de Viber en los que los destinatarios visitaron un enlace durante el período dinámico seleccionado.

Se usa en el gráfico de tendencias para mostrar cómo cambia la actividad de visitas a enlaces en Viber a lo largo del tiempo.